label chapter_1:
    stop music fadeout 3.0
    play ambient1 amb_metro_loop fadein 3.0
    pause 2.5

    "September fourth."

    "Year? 201M2023 B.C."

    "Amid the arid heat of the morning sun of Volcaldera Bluff, I can't help but miss living in the more temperate weather of the midwest."

    "{i}'Summer sleeves are in style this year!'{/i}"

    "That Jackets Aroma blog better be right. This suede thing is killing me."

    pause .5

    "Well, at least it's guaranteed to start getting chillier in a few weeks."

    "Besides, I'm sure to make an impression with this. Ambercrobie & Flint is all the rage these days."
    window auto hide
    pause .5

    call l_metro_day_sound from _call_l_metro_day_sound
    # Immensely retarded, but we have to have this camera statement out here so the sound can function properly
    camera:
        perspective True
        parallel:
            tf_metro_cameramove
        parallel:
            tf_metro_soundplayer
    with Dissolve(2)
    pause 1

    "I sigh and lean back in the hard plastic seating of the metro."
    pause .5

    "I'm on my way to my first day in a new school."

    "Ordinarily I'd just be glued to my phone on the trip, but there's just too much on my mind right now."

    "My folks' sitch requires us to move frequently, which gives me little time to fit in."

    "Much like how a rolling stone gathers no moss, I could never make a friend I'd keep for longer than a year."

    "Just a lot of promises to 'keep in touch' that petered off within months."
    pause .5

    "Admittedly, it's my fault in the end."

    "But that's all going to change, starting today!"

    "I'm going into senior year now, it's my very last chance to prepare."

    "Luckily for me, the cards are stacked in my favor."
    pause .5

    "I feel around my backpack for my DSLR, till my fingers can absentmindedly fiddle with the mode dial."

    "St. Hammond High School is extremely well known for their artists' curriculum."

    "In other words, I'll be surrounded by people that share my interests."

    "Even if it's a bit of a ride away."
    pause .5

    "Speaking of rides, I was hoping that my parents could drive me there today."

    "By the time I was up, though, they already left for work."

    "No big deal, I like the hustle and bustle of public transportation."

    "I imagine I'm going to have to get used to this, anyway."
    pause .5

    "As time passes, my mind wanders to memories of previous schools."
    pause .5

    "{cps=5}...{/cps}"
    window auto hide
    pause .5

    scene black
    camera at resetcamera
    with Dissolve(1)
    pause .5

    "They all sucked."
    pause .5

    "{cps=5}...{/cps}"
    stop ambient1 fadeout 4
    play sound amb_metro_stop volume 0.8
    play ambient2 amb_crowd_far_loop volume 0.5 fadein 4
    pause .5

    "The train car gradually comes to a stop, and the sign indicates that this is where I get off."
    window auto hide
    pause .5

    show bg_city with Dissolve(1)
    pause .5

    "I step off the metro, climbing out of the station as I follow a few other students heading towards the school."

    "Oddly enough, I'm only seeing dinosaur students. Not another human to be seen anywhere."

    "Must be one of those dino-heavy regions."
    play ambient3 amb_outdoor_nature_loop fadein 5
    stop sound fadeout 3
    pause .5

    "There's a lot of greenery here as well, you'd almost forget how close we are to a major city."

    "The pathway leads to a stone bridge that goes over a small creek."
    pause .5

    "As I walk across, I notice other students meet in pairs and walk with each other."

    "The air begins to fill with the sounds of laughter and stories of their summer break."
    pause .5

    "{cps=5}...{/cps}"
    window auto hide
    stop ambient2 fadeout 10
    pause .5

    scene black with dissolve
    pause .5

    "Ah, there it is."

    "The school peeks out over the trees ahead of me, as though inspecting and welcoming me inside."

    "St. Hammond High, my new home away from home for the next year."

    "I stop to take a deep breath."
    pause .5

    "The air here is crisp, reminding me of an old campground I went to back in elementary school."
    pause .5

    "{cps=5}...{/cps}"
    pause .5

    "Once again I'm handed an opportunity to make something of myself."

    "I'm apprehensive, but hopeful."

    "It's my last shot at this. There's no going back."
    pause .5

    "I take my first step onwards."

    "Here we go again."
    window auto hide
    pause .5

    play music mus_happy2 fadein 5
    stop ambient3 fadeout 5
    scene anim_incointro with Dissolve(1)
    pause 6.4
    scene bg_school_day with Dissolve(1)
    pause .5

    # BN: Inco walking into frame and looking up, scanning the building

    "Students mill about the front yard."

    "St. Hammond is known for its heavily prioritized art programs." 

    "Over two-thirds of the graduates end up pursuing a career in the arts."

    "And while half of them regret it from what I've read, there's still plenty that made it, right?"

    "It's also the management's claim to fame, with the facade on the front entrance being dominated by a vibrant mural."

    "I got a good feeling about this place."
    pause .5

    "A few students eyeball me as I continue walking in."

    "Some friends whisper to each other."

    "I just knew this jacket would pay off!"
    pause .5

    "The front doors are propped wide open, and I already feel the cool breeze inviting me in."

    "Inside, it's a familiar yet brand new sight."
    window auto hide
    pause .25

    show black with dissolve
    pause 1

    show cg_panorama with Dissolve(1):
        xalign 0.5
    pause .5

    "I hadn't mentioned it yet, but this school is also unique for its student body."

    "It's composed almost entirely of dinosaurs; all manner of saurian herbivores and otherwise."
    window auto hide

    show cg_panorama:
        ease_quad 1.2 xalign 0.0
    pause 1.2

    "Scales, feathers, tails... is that a tether?"

    "Wings, talons and webbed hands."

    "Not to even mention the colors."

    "All vibrant enough to challenge the bright murals on the school outside."
    window auto hide

    show cg_panorama:
        ease_quad 1.5 xalign 1.0
    pause 1.5

    "Dozens of students march about, reconnecting with past friends and meeting new ones."

    "Some anxiously glance at their schedules, checking every door as though they were numbered at random."
    pause 0.5

    "I probably shouldn't be standing here stari-"

    stop music fadeout 1
    show cg_panorama:
        xalign 1.0
        nudgeupinv()

    unknown "WHOA, IS THAT A HUMAN?!"
    window auto hide

    hide cg_panorama with dissolve
    pause .25

    "Whoa-oh."
    window auto hide
    pause .5

    play music mus_happy1

    # TODO: Make the crowd people turn-arounds use transitions if possible, to avoid snapping

    scene bg_school_hallway:
        zzoom True
        zpos 0 -300

    #show black:
    #    alpha 0.5

    show spr_crowdbackdrop_left:
        align (0.5, 0.5) zoom 1.04 zpos -100 blur 20 subpixel True
    show spr_crowdbackdrop_right:
        align (0.5, 0.5) zoom 1.04 zpos -100 blur 20 subpixel True

    show spr_crowdperson_phone1:
        xanchor 0.5 xpos 0.12 zpos -50
        matrixcolor ColorizeMatrix("#922121", "#ffffff")

    show spr_crowdperson_chilling2:
        xanchor 0.5 xpos 0.75 ypos 0.05 xzoom -1 zpos -50
        matrixcolor ColorizeMatrix("#c5c340", "#ffffff")

    show spr_crowdperson_phone2:
        xanchor 0.5 xpos 0.8 xzoom -1 zpos -50
        matrixcolor ColorizeMatrix("#271d7a", "#ffffff")

    show spr_crowdperson_phone3:
        xanchor 0.5 xpos 0.1 zpos -50
        matrixcolor ColorizeMatrix("#2f4883", "#ffffff")

    show spr_crowdperson_idle3:
        xanchor 0.5 xpos 0.9 xzoom -1 zpos -50
        matrixcolor ColorizeMatrix("#42aa79", "#ffffff")

    show spr_crowdperson_watching1:
        xanchor 0.5 xpos 0.85 xzoom -1 zpos -50
        matrixcolor ColorizeMatrix("#832e71", "#ffffff")

    show spr_crowdperson_watching2:
        xanchor 0.5 xpos 0.15 zpos -50
        matrixcolor ColorizeMatrix("#9e5931", "#ffffff")

    show inco shocked at setx(0.5)
    show spr_inco_shocked_closeup at setx(0.5):
        xanchor 0.5
        zoom 0.22935779816513761467889908256881

    show spr_vignette:
        alpha 1.0

    camera:
        perspective True
        xpos 9
        zpos -963
        ypos -279

    pause .6

    play ambient1 amb_crowd_far_loop fadein 0.25 volume 0.5
    hide spr_inco_shocked_closeup

    camera:
        perspective True
        easein_quad .25:
            zpos -189
            xpos 0
            ypos -45

    show spr_crowdbackdrop_left:
        easein_quad .25 blur 0
        block:
            ease_quad 0.6 xpos 0.49 ypos 0.51
            pause 0.4
            ease_quad 0.5 xpos 0.515 ypos 0.503
            pause 0.1
            ease_quad 0.7 xpos 0.495 ypos 0.497
            pause 0.25
            ease_quad 0.4 xpos 0.485 ypos 0.503
            pause 0.5
            ease_quad 0.8 xpos 0.505 ypos 0.495
            pause 0.3
            ease_quad 0.5 xpos 0.515 ypos 0.515
            pause 0.15
            repeat

    show spr_crowdbackdrop_right:
        easein_quad .25 blur 0
        block:
            ease_quad 0.7 xpos 0.495 ypos 0.497
            pause 0.3
            ease_quad 0.8 xpos 0.505 ypos 0.495
            pause 0.4
            ease_quad 0.6 xpos 0.49 ypos 0.51
            pause 0.4
            ease_quad 0.5 xpos 0.515 ypos 0.503
            pause 0.05
            ease_quad 0.4 xpos 0.485 ypos 0.503
            pause 0.1
            ease_quad 0.5 xpos 0.515 ypos 0.515
            pause 0.4
            repeat

    show spr_crowdperson_phone1:
        ease_quad 0.5 xpos 0.175
        ease_quad 0.5 xpos 0.225
        ease_quad 0.5 xpos 0.175
        ease_quad 0.5 xpos 0.225
        hop(0.0, 2)
        movex(0.15)
        nudgeup()
        ease_quad 0.5 xpos 0.175
        ease_quad 0.5 xpos 0.125
        ease_quad 0.5 xpos 0.175
        ease_quad 0.5 xpos 0.125

        parallel:
            easemovex(0.8, 2)
        parallel:
            pause 1
            xzoom -1.0

        hop()
        pause 0.5
        jumping()
        pause 1
        backmovex(0.75)
        hit(0.75)

        parallel:
            easemovex(0.2, 2)
        parallel:
            pause 1
            xzoom 1.0
        repeat


    show spr_crowdperson_phone2:
        pause 0.5
        movex(0.7)
        pause .25
        movex(0.75)
        nudgeup()
        parallel:
            easemovex(0.35, 1.5)
        parallel:
            hop(0.0, 3)
        parallel:
            pause .75
            xzoom 1
        
        pause .25
        movex(0.33)
        movex(0.3)

        ease_quad 0.5 ypos 0.025
        ease_quad 0.5 ypos -0.025
        ease_quad 0.5 ypos 0.025
        ease_quad 0.5 ypos -0.025

        movex(0.4)
        parallel:
            easemovex(0.8, 1.5)
        parallel:
            pause .75
            xzoom -1
        movex(0.9)
        backmovex(0.85)
        hop()
        pause .5
        movex(0.8)
        repeat

    show spr_crowdperson_phone3:
        pause 1.0
        nudgeup()
        movex(0.13)
        backmovex(0.1)
        hity()
        easemovex(0.2)
        hop(0.0, 2)
        pause 0.5
        movex(0.1)
        repeat

    show spr_crowdperson_idle3:
        pause 0.5
        movex(0.87)
        nudgeup()
        backmovex(0.9)
        hop(0.0, 2)
        easemovex(0.8)
        movex(0.9)

        ease_quad 0.5 xpos 0.875
        ease_quad 0.5 xpos 0.925
        ease_quad 0.5 xpos 0.875
        ease_quad 0.5 xpos 0.925

        repeat

    show spr_crowdperson_watching1:
        movex(0.87)
        pause .5
        easemovex(0.83)
        movex(0.81)
        movey(-0.05)
        pause 0.5
        movexy(0.85, 0.0)
        repeat

    show spr_crowdperson_chilling2:
        movexy(0.65, 0.0, 0.25)

        block:
            nudgeup()
            nudgeup()

            backmovex(0.63)

            pause 1

            ease_quad 0.5 xpos 0.67
            ease_quad 0.5 xpos 0.65
            ease_quad 0.5 xpos 0.67
            ease_quad 0.5 xpos 0.63

            pause 1

            parallel:
                easemovex(0.35, 1.5)
            parallel:
                pause 0.75
                xzoom 1

            movey(0.05)
            hit(0.35)
            backmovey(0.0)
            backmovex(0.32)
            parallel:
                easemovex(0.6, 1.5)
            parallel:
                pause 0.75
                xzoom -1
            repeat

    show spr_crowdperson_watching2:
        pause 0.5
        movex(0.1)
        movex(0.15)
        hop()
        easemovex(0.17)
        pause .5
        hit(0.17, 0.7)
        movex(0.15)
        repeat

    show spr_crowdperson_watching3 behind spr_vignette:
        xanchor 0.5 xpos -0.2 zpos 50
        matrixcolor ColorizeMatrix("#52bd7b", "#ffffff")

        pause 5

        block:
            pause 1.5
            easemovex(1.2, 4)
            xzoom -1
            pause 16
            parallel:
                hop(0.0, 8)
            parallel:
                easemovex(-0.2, 4)
            pause 12
            xzoom 1
            easemovex(0.2, 1)
            hit(0.2)
            easemovex(-0.2)
            repeat

    show spr_crowdperson_chilling3 behind spr_vignette:
        xanchor 0.5 xpos 1.1 xzoom 1 zpos 50
        matrixcolor ColorizeMatrix("#fd557a", "#ffffff")

        block:
            movex(0.8)
            xzoom -1
            pause 0.75
            xzoom 1
            pause .5
            easemovex(0.6, 1.5)
            easemovex(-0.1, 2)
            pause 13
            xzoom -1
            movex(0.2)
            easemovex(1.1, 2.5)
            pause 14
            repeat

    "I'm soon surrounded and overrun by a crowd of neon-colored teenagers."

    show inco happy with eidissolve_nd

    "Clearly, my jacket is working like a charm."

    unknown "Wow, he's like a life-size mannequin!"

    unknown "Hey, new kid!"

    show inco surprised left with eidissolve

    "I'm instantly swarmed by the crowd."
    pause .5

    "{cps=15}Is...{/cps}{w=.5} is this what it's like to be popular?"

    "I really wasn't expecting it to happen this quickly..."
    pause .5

    "A few students are taking pictures with their phones."

    "I even see some with sketchbook and pens in hand, rapidly scribbling on pages."

    unknown "Wow, a Human!" 

    unknown "Are you like, a foreign exchange student?"

    "In the chaos, I feel a few people touch my hands."

    show inco at hity(0.0, 0.5)

    unknown "Whoa, human skin feels {i}weiiiird{/i}."

    show inco at movex(0.48)
    show inco concerned right with eidissolve_nd

    "Jeez, a bit uncalled for."

    "But I guess I don't want to be a party pooper."

    show inco surprised with eidissolve_nd

    "A few more people shout at me to get my attention."

    unknown "Hey, could you look over there for a side profile?"

    unknown "Oh man, yeah, this'll be good reference material!"

    unknown "Wait wait, I need to get a better look at his skin texture!"
    pause .5

    "I once again find myself frozen, only muttering quietly as I hastily try to follow their instructions."

    show spr_crowdperson_chilling3:
        on hide:
            easemovex(-0.2, 4)
    show spr_crowdperson_watching3:
        on hide:
            easemovex(1.2, 5)
    show spr_crowdperson_watching2:
        on hide:
            easemovex(1.3, 3)
    show spr_crowdperson_watching1:
        on hide:
            easemovex(-0.3, 5)
    show spr_crowdperson_idle3:
        on hide:
            easemovex(1.3, 3)
    show spr_crowdperson_phone3:
        on hide:
            easemovex(-0.3, 3)
    show spr_crowdperson_phone2:
        on hide:
            easemovex(-0.35, 5)
    show spr_crowdperson_chilling2:
        on hide:
            easemovex(1.3, 3)
    show spr_crowdperson_phone1:
        on hide:
            easemovex(-0.37, 3)
    show spr_crowdbackdrop_left:
        on hide:
            easeout_quad 5 xanchor 1.0 xpos 0.0
    show spr_crowdbackdrop_right:
        on hide:
            easeout_quad 5 xanchor 0.0 xpos 1.0

    hide spr_crowdperson_chilling3
    hide spr_crowdperson_watching3
    hide spr_crowdperson_watching2
    hide spr_crowdperson_watching1
    hide spr_crowdperson_idle3
    hide spr_crowdperson_phone3
    hide spr_crowdperson_phone2
    hide spr_crowdperson_phone1
    hide spr_crowdperson_chilling2
    hide spr_crowdbackdrop_left
    hide spr_crowdbackdrop_right

    show spr_vignette:
        on hide:
            linear 5 alpha 0.0
    hide spr_vignette

    $ renpy.music.set_volume(0.0, 5, 'music')
    stop ambient1 fadeout 5

    pause 0.5

    "Eventually, the saurians take all their photos and talk themselves out before dispersing back to their own friend groups."

    "By the time I recover from the shock of the situation, the last one breaks off and I find myself seemingly all alone again."

    show inco neutral with eidissolve
    pause 0.5

    "Oh.{w=.75} That was my chance to socialize..."
    window auto hide

    camera:
        subpixel True
        ease_cubic 2.5:
            zpos 0
            ypos 0
    pause 3

    show inco verysad with eidissolve_nd

    "I blew it."

    camera:
        zpos 0
        ypos 0
    pause 0.5

    show kiara left at moveinleft(0.75) with eidissolve

    unknown "Umm, you're a human, right?"

    #camera:
    #    perspective True
    #    easein_cubic 1.0:
    #        zpos -100
    #        xpos 0
    #        ypos -20

    $ renpy.music.set_volume(1.0, 2, 'music')
    show inco neutral with eidissolve

    "A triceratops girl leans forward, scanning me up and down."

    "This is it. Time to seal the deal and get a new {i}friend{/i}."
    pause 0.5

    I "Uhh,{w=.5}{nw}"
    
    show inco at nudgeup(0.0, 0.4, 0.5)

    extend " ye-A-h."

    "Close enough."
    pause 0.5

    unknown "Heyy, can I, like, get a selfie with you?"

    unknown "It'd be {i}great{/i} for one of my classes."

    show inco happy with eidissolve

    I "Yeah, definitely."

    #camera:
    #    easein_cubic 1:
    #        xpos 115
    #        ypos -119
    #        zpos -289

    show kiara at movex(0.6) behind inco
    show kiara right with eidissolve

    "She puts an arm around my back for a shoulder hug while she poses dramatically."

    "{cps=5}...{/cps}Maybe a bit too friendly?"
    pause .5

    unknown "Big smile now!"

    show kiara at setx(0.6), nudgeup()

    "She takes the picture and checks it enthusiastically."

    show kiara at movex(0.65)
    pause .5

    I "Soo, uh, I'm Inco."

    unknown "Huh? Oh, cool, yea, yea."

    unknown "Anyway, I gotta go."

    stop music fadeout 4
    show inco neutral with eidissolve
    pause .5

    "Oh."
    pause .5

    I "{cps=5}...{/cps}What's the photo's for, by the way?"

    show kiara at movex(0.7)
    show kiara left with eidissolve

    "She pauses, aloofly chewing some gum."

    unknown "My fashion design class. That jacket is {i}ballin'{/i}."
    pause .5

    I "Ah..."
    pause .5

    show kiara at setx(0.7), hop()

    unknown "Thanks for the pic, hun!"
    window auto hide

    show kiara at moveoutright_cs(0.75)
    show kiara right with eodissolve
    hide kiara

    #pause 1

    #camera:
    #    ease_cubic 1:
    #        ypos 0
    #        xpos 0
    #        zpos 0

    pause 1.5

    "{cps=5}...{/cps}"
    pause 0.5

    "Well."

    play music mus_chill2
    show inco verysad with eidissolve

    "I feel my shoulders sag as I take in the now sparse hallway around me."

    "That must've been my 'fifteen minutes of fame'."
    pause 0.5

    "I don't think it even lasted fifteen minutes."

    "But there's no way I've already blown it!"

    #turn inco sprite left and right a couple times
    # NOTE: I would rather a headshake

    show inco neutral with eidissolve

    "I try to shake away the negative thoughts."

    "Focus on the positive."

    "For a brief moment, I was the talk of the school!"
    pause 0.5

    "Yeah."
    pause 0.5

    show inco at nudgeup()
    show inco surprised

    stop music fadeout 2

    play sound snd_camera_mult
    "{i}*clickclickclick*{/i}"
    # DN: Camera clicking
    pause 0.5

    "The familiar sound draws my attention."

    "I know what that is."
    window auto hide
    pause 0.5

    show anim_benintro1 with Dissolve(1)
    pause 0.5

    "At the end of the hall, there's someone kneeling."

    "And with one of the latest camera models, if I'm not mistaken."
    pause 0.5

    I "Hey!"

    show anim_benintro2 with dissolve

    "The guy flinches."

    "I flinch too."

    "I hadn't meant to shout at him."

    "The few students around me don't bat an eye at it, though."
    window auto hide
    play music mus_school2
    pause 0.25

    show anim_benintro3
    pause 3.26

    # BN: Ben standing up and looking at Inco

    scene bg_school_hallway
    show inco neutral at setx(0.35)
    with Dissolve(1)

    show ben neutral left at moveinleft(0.65) with eidissolve
    pause 0.5

    I "Sorry about the yell."

    unknown "No, it's fine. I managed to get the shot I wanted."
    pause 0.5

    "The bespectacled boy, I think he's a parasaur, double checks the camera's display and smiles."

    show ben happy left with eidissolve

    unknown "Yep, perfect. This'll be a fine print for the yearbook."

    I "Can I see?"
    pause 0.5

    "His grin seems to widen at my interest."

    unknown "Of course, here."

    show ben at movex(0.6)

    "He turns the display toward me, showing a shot of the hallway."

    "And me as the focal point."
    pause 0.5

    unknown "Pretty good, right?"
    show inco at movex(0.37)
    pause 0.5

    "I look a little closer, and notice that-"

    I "I think it's a little out of focus..."

    I "{cps=5}...{/cps}And dark."
    show inco at movex(0.35)

    I "What do you have your f-stop set at?"

    show ben unimpressed left with eidissolve

    #Ben unimpressed

    unknown "Ah, sh-"

    show ben surprised left with eidissolve
    #Ben surprised
    "He stops and glances up at me, pleasantly surprised to get a real answer."

    show inco happy with eidissolve
    #Inco happy

    I "Yeah, I'm a bit of a photographer myself. I'm taking it as an elective too."

    unknown "With Mr. Iadakan?"
    pause 0.5

    "Thinking back to my memorized class schedule, the name does sound familiar."

    I "Yep."

    show ben at setx(0.6), hop()
    show ben happy left with eidissolve

    unknown "Oh snap, cool. We'll be classmates."

    unknown "Mr. Iadakan's busy, so he just teaches it for one period."
    
    show ben at sety(), movex(0.57)
    pause 0.5

    "He offers his hand out for a handshake."

    B "I'm Ben."

    show inco:
        movex(0.38, 0.75)
        nudgeup(0.0, 0.7)

    show ben:
        pause .75
        nudgeup(0.0, 0.7)

    pause 1.0

    I "Inco."

    "Friend achieved."

    show inco:
        sety()
        movex(0.35)
    show ben:
        sety()
        movex(0.6)

    show inco neutral with eidissolve

    I "I'm actually new here."

    B "Kinda figured, being the only human student this year and all."

    B "St. Hammond isn't one of the more popular schools, but the staff put a lot of effort into the Arts programs."

    B "Even the campus itself is designed like a 'living art piece', so if you ever need help..."
    pause 0.5

    "From the pause I'm guessing he's offering some help."

    show inco happy with eidissolve

    I "I wouldn't say no to a tour."

    B "A tour, you say..."

    B "Well, I'm only going back to the principals' office, but I can point out some neat stuff along the way."

    show ben considering left with eidissolve

    "He raises an eyebrow to himself in contemplation."

    B "Might be a good idea to meet the principal, too."

    "He waves for me to follow him."
    window auto hide

    show ben at moveoutright_cs(0.6)
    show ben neutral right with eidissolve
    hide ben

    show inco at moveoutright(0.35, m=.25, t=1)
    hide inco

    pause .5
    scene black with Dissolve(1)
    pause .5

    "{cps=5}...{/cps}"
    pause .5

    "Turns out he wasn't just an avid photographer like me, but also the school council president."

    "And one of his priorities was taking photos for St. Hammond's yearbook, for the 'first day' page."

    "Every few minutes we'd pause so Ben could take a couple of shots, mainly of the students talking with each other."

    "And while I would watch, I had considered helping him in some way."

    "I mean, that camera looks amazing, and then there's all his extra lenses in the bag."

    "I feel absolute elation to finally know someone that's into photography."

    "And I really want to broach it, but Ben fills the air between us talking more about the school."
    window auto hide
    pause .5

    show bg_school_hallway with dissolve
    pause .5

    show inco at moveinright(0.4)
    show ben explaining at moveinright(0.6)
    with eidissolve

    B "-which is why we still go by the Feather Tails, even though I think it's a tad distasteful."

    I "Dang, you're pretty good at this. Do you give these tours to all the new students?"

    show ben happy with eidissolve_nd

    B "Ha, not really. Although it is something I've thought about a lot."

    B "Oh, hold that thought. Hey, Lunara!"

    show inco at movex(0.2)
    show ben at movex(0.5)
    show lunara happy at moveinleft(0.875) with eidissolve

    "Ben goes to greet a student putting up some intricate wall banners."

    show lunara at movex(0.75)
    show lunara happy left with eidissolve

    Lu "Oh, hey Ben!"

    Lu "You have a good summer vacation?"

    B "I did! Great work on the decorations, they look even better than last years!"

    show lunara at setx(0.75), hop()

    Lu "Aw, thank you!"
    pause 0.5

    I "What's all this for?"

    show lunara at movex(0.7)
    pause 0.5

    "She steps aside so I can fully view the banner she'd just finished with."

    show lunara at nudgeup()

    Lu "The cultural arts club! We meet every Thursday after school and look at antique artwork!"
    pause 0.5

    "She'd initially looked past me to talk with Ben, but she gasps once she realizes-"

    show lunara at hop()
    show lunara surprised with eidissolve

    Lu "Hey, you're a human, right?"

    show lunara at sety(), slideinplace1(0.7)
    show lunara cheerful with eidissolve_nd

    Lu "Oh, that's a silly question. You should totally join!"

    Lu "I just love human culture, there's this amazing set of ancient masks at my place from ancient Europe, I just adore them!"

    show lunara at movex(0.7)
    show lunara happy with eidissolve

    I "Wow, that's impressive. Think you'd make a good curator."

    Lu "You know what, I probably would!"
    pause 0.5

    B "After that club display during Spirit Week last year, I gotta agree."
    pause 0.5

    Lu "We took weeks studying that tribe and weeks more practicing those dances."

    Lu "We also study and paint with those styles, like we're learning the techniques of the old masters!"

    Lu "Hopefully soon we can even get into sculpting, like those old venus statues!"

    Lu "We plan on getting one to look at sometime this year! What do you think, it'd be great if you could come!"

    show ben left with eidissolve

    B "Hey, that'd be neat. What say you, Inco?"
    pause 0.5

    I "{cps=10}Hmm...{/cps}{w=.5} Maybe, I do love culture."

    show lunara at hop(0.0, 2)
    show lunara cheerful with eidissolve

    Lu "Oh, that's great! Oh, oh, listen, we have this old chieftain's dress we've had for ages, we just HAVE to see what it looks like on the real thing!"

    I "Uhh... I'll think about it."

    "No way, I'd sooner endure a second impact event than wear something like that."

    show lunara happy
    show ben right
    with eidissolve

    show ben at nudgeup()

    B "Well hey, nice to catch up, Lunara. We got places to be, take care!"

    show lunara at hop()

    Lu "Bye!"
    pause 0.5

    "She waves us off and Ben continues leading me to the principal's office."
    window auto hide

    show ben at sety(), moveoutright(0.5)
    show inco at moveoutright(0.2)
    hide inco
    hide ben
    pause 0.5

    scene black with dissolve

    pause 0.5

    unknown "Hey, Ben!"

    B "Oh, hey, Michael! Listen, can't talk now, but I'd love to catch up later, yeah?"
    pause 0.5

    "I'm floored."

    "This guy seems to know just about everyone in school as much as they know him. Talk about being on top of things."

    "He points out a few more minor landmarks in the school, and stops to greet a number of students happy to see him after the summer break."
    pause 0.5

    B "Man, sorry for having to stop so much."

    I "No way, I think it's cool you know everyone."

    B "If only it could be cool without making us late!"
    pause 0.5

    "He points out a few more minor landmarks in the school, eventually leading me to its biggest draw."
    window auto hide
    pause 0.5
    scene bg_school_hallway with Dissolve(1)
    pause 1.0

    "I already knew St. Hammond's was known for art, but wow."

    "Just outside the administrative offices, the hallway is filled with wonderful pieces of work."

    "Paintings line the walls, with name placards beneath detailing who the artists were."

    "All alumni from the school."
    pause 0.25

    show inco surprised at moveinright(0.37)
    show ben explaining at moveinright(0.62)
    with eidissolve
    pause 0.25

    B "-And this is the gala. All of these pieces have been featured in all kinds of articles and presentations."
    pause 0.5

    I "Whoa."

    show ben happy left with eidissolve

    B "I know, right?"

    B "One moment."

    show ben at movex(0.65) with None
    show ben happy right
    show inco neutral
    with eidissolve

    "Ben turns to the nearest door and gives it a polite knock."
    pause 0.5

    unknown "Who is it?"

    B "It's me, Principal Scaler."
    pause 0.5

    "An oviraptor no older than her mid thirties exits the room, holding a steaming mug and sporting a tired smile."
    window auto hide

    show inco at movex(0.2)
    show ben at movex(0.35) behind inco
    show scaler neutral left at moveinleft(0.7) with eidissolve
    pause 0.5

    Scal "Good morning, Benjamin."

    B "Good morning." 

    show ben happy left with eidissolve
    #Ben sprite turning back to Inco
    B "Inco, this is our esteemed principal."
    pause 0.5

    I "Good morning, ma'am."

    show scaler shocked at setx(0.7), hity()
    show ben happy right with eidissolve

    "Her eyes shoot wide mid sip of her coffee."
    pause 0.5

    Scal "Oh,{w=.5} I hadn't noticed."

    Scal "You would be Mr. Guh Neato, yes?"

    show inco skeptical with eidissolve

    I "Uh...{w=.5} Yes?{w=.5} But my name-"

    show scaler at hop()
    show scaler happy left with eidissolve_nd

    Scal "How wonderful!"

    "Gone is the exhaustion on her face, instead replaced with a very wide smile."

    Scal "I am so happy that you've chosen our school for your last year, Mr. Neetu."

    Scal "Ben, be sure to give him a thorough St. Hammond welcome, okay?"

    show ben skeptical with eidissolve

    B "Er, I already was-"

    Scal "If you ever need any assistance my office is always open, Mr. Nehtoo."

    Scal "Not to mention, the Student Council is also available for help."

    Scal "Isn't that right, Ben?"

    show ben unimpressed with eidissolve

    B "Y-{w=.5}yes, Principal Scaler."

    show inco neutral with eidissolve

    I "Thank you, Principal Scaler."
    pause .5
    show scaler at sety(), movex(0.67)

    Scal "Oh, and Ben? A moment please."

    show ben sad with eidissolve_nd

    B "But-"

    show scaler at movex(0.5, 0.75) behind ben
    pause .75
    show ben at moveoutright(0.35)
    show scaler at moveoutright(0.5)
    hide ben
    hide scaler

    "The parasaur is dragged into the office, leaving me alone in the school gala."

    "Whatever they're saying, I can't hear over the ambient noise of the student body."

    "Either way, it's probably not something I'm meant to hear."

    pause .5

    "I move a few feet away, out of earshot of the discussion inside."
    pause .25
    show inco left with eidissolve
    show inco surprised at nudgeup()
    pause .5
    show inco at sety(), movex(0.25)
    pause .25

    "On the wall beside me is a framed panoramic landscape of the city, painted by hand."
    window auto hide
    pause .5

    show cg_painting with Dissolve(1)
    pause 1.0

    "{cps=5}...{/cps}"
    pause .5

    "Wow.{w=.5} I could practically use this thing as a map with how detailed it is."

    "No wonder it's hanging so predominantly by the principals' office."

    "The gentle brush strokes."
    
    "The vibrant colors."

    "The evening sun bouncing off each of the windows, and the majestic scarlet sky enveloping the horizon."

    "All of which combine together to give it a dreamscape feeling like it's an idealized vision of the city."
    pause .5

    "{cps=10}It's...{/cps}{w=.5} beautiful."

    "I've never been a big admirer of paintings, but I can't deny that this is a masterpiece."

    "Only a teacher could've been able to express the scenic beauty of the city with this level of skill and passion."
    window auto hide
    pause .5

    scene bg_school_hallway
    show inco surprised left at setx(0.25)
    with dissolve
    pause .25

    show inco at movex(0.3)
    show inco thinking with eidissolve

    "I withdraw my Cavon Stone60 from my bag, and with the compact lens I keep I barely fit the entirety of the painting in frame for the shot."
    pause .5

    "Checking the copy on my display, I realize I left out the title and artist of the piece."

    "The tag says..."
    pause .5

    "Dreamscape. Artist: O. Halford - 9th Grade."
    pause .5

    "{cps=5}...{/cps}1st place, 202M2018."
    pause .5

    "A freshman did this... Jeez."
    pause .5

    "Now that I look at the rest of the paintings, this is insane."

    "It's all... so much better than what I've made."

    "Almost all of the pieces are beautifully drawn."

    "Acrylic, charcoal, pastel..."
    pause .5

    "And yet not even one photo."

    show inco at movex(0.25)
    show ben neutral left at moveinleft(0.6) with eidissolve

    B "Hey Inco, I'm back."

    "I'm a senior, how on {i}earth{/i} am I meant to even {i}start{/i} measuring up here?"
    show ben skeptical with eidissolve

    B "Inco?"

    #increasing sounds of crowd annoyance and wheelchair racing
    pause .5

    play ambient1 amb_crowd_rowdy_loop fadein 7
    stop music fadeout 7

    "{cps=5}...{/cps}What's that sound?"

    show ben shocked left at nudgeup()
    pause .5
    show ben at sety(), movex(0.35, 1.5) behind inco
    with None

    show inco neutral right
    show ben angry
    with eidissolve

    show anim_oliviaintro1 with dissolve

    "Ben nudges me back with the back of his hand as the commotion gets closer."
    pause .5

    unknown "Hey, watch it jackass!!"

    unknown "Slow your roll, leatherface!"

    unknown "My leg!"
    pause .5

    "I watch as the,{w=.5} er...{w=.5} perpetrator?{w=.5} Aggressor?...{w=.5} Aggrogator?{w=.5} finally rounds the corner and comes barreling down the hallway."

    "I watch as a green dinosaur in a wheelchair speeds towards Ben and I."

    "My instincts kick in, and I stumble to the side to avoid the oncoming collision."
    pause .5

    "...For just a split second, I get a good look at my assailant."

    play sound [ "<silence 0.1>" , snd_animation_oliviaintro]
    stop ambient1 fadeout 2
    scene anim_oliviaintro2
    pause 11
    scene anim_oliviaintro3 # Redundant, but makes rollbacks more convenient

    stop sound fadeout 1
    play music mus_thoughts2

    "Green scales, messy hair, and a faded purple hoodie."

    "She propels herself forward with dexterous hands, spinning the large wheels on her..."

    "I only now notice that she's in a wheelchair. I didn't even know you could go that fast in one of those."
    pause .5

    "She glances my way, and her pupils lock onto mine."

    "Her gray and gold eyes are marred by bags, like she hasn't slept in days."
    pause .5

    "{cps=25}The girl's entire presence is ghost-like.{/cps}"
    pause .5

    "And that expression{cps=5}...{/cps} It's like she's looking straight through me."

    "I'm sure she barely registers my existence, but I don't think I'll ever forget that face."
    pause .5

    "Just as fast as she came, however..."
    stop music fadeout 4
    window auto hide
    pause .5

    scene black with dissolve
    pause .5

    "She's gone."
    pause .5

    "As she leaves, I feel like a weight is lifted from my shoulders."
    pause .5

    "{cps=5}...{/cps}at least until I trip directly into a glass case behind me."
    window auto hide
    pause .25

    play sound snd_slapstick_glassthud
    play ambient1 amb_school_loop fadein 1

    scene bg_school_hallway
    show inco neutral at setx(0.2), hity()
    show ben shocked left at setx(0.5)
    pause 1

    # DN: conk

    I "Oof."

    show ben angry left with eidissolve

    B "Hey, watch it!"

    I "Whups."

    show ben:
        movex(0.25)
        block:
            pause 0.5
            easemovey(0.04)
            pause 0.5
            easemovey(0.03)
            pause 0.5
            easemovey(-0.02)
            pause 0.5
            easemovey(0.0)
            pause 0.5
            easemovey(0.02)
            pause 0.5
            easemovey(0.0)
            repeat

    show inco at sety(), movex(0.5)
    show inco neutral left with eidissolve

    "The parasaur's hand roves over the display carefully, his eyes filled with worry."
    pause .5

    I "{cps=5}...{/cps}You looking for something?"
    pause .5

    B "Cracks."

    B "Usually when another student falls into them there's some kind of crack or scratch."

    show ben neutral with eidissolve

    B "Guess it's just a dino thing. You humans are lucky you don't gotta sweat over this kind of stuff."

    I "That happen often?"

    show ben at setx(0.25), movey(0.0)
    show ben neutral right with eidissolve

    B "Often enough to drain school funds in repairs."

    I "That can't be good."

    show ben explaining with eidissolve

    B "Well, not to brag but I make do-"

    play sound snd_school_bell

    #Bell sound effect
    show ben neutral at nudgeup()
    show inco at setx(0.5), nudgeup()

    pause 1

    "A vibrato chime echoes through the now empty hall."
    pause .5

    "I freeze. Tardy on the first day."

    show ben sheepish with eidissolve

    B "Ha, whups."

    B "Sorry to run on like that, you should get going to your first class."

    I "Won't I need a tardy slip or something?"

    show ben neutral with eidissolve_nd

    B "Nah, it's the first day, teachers are lenient."

    B "I'm fine either way, since, y'know."

    "One of the benefits of being class prez."
    pause .5

    B "What's your first period?"

    I "Physical Education."

    stop ambient1 fadeout 3
    show ben nervous with eidissolve
    # Should probably have the crowd fade out here

    "Ben sucks the air in through his teeth in a prolonged wince."
    pause .5

    B "{cps=5}...{/cps}"
    pause .5

    I "{cps=5}...{/cps}"
    pause .5

    show ben neutral with eidissolve

    B "...You'll be fine."

    B "Gymnasiums' down thataway."
    pause .5

    B "Don't,{w=.4} uh,{w=.4} keep him waiting too long.{w=.5} I need to get going, too."

    show inco skeptical left with eidissolve

    I "Keep who waitin-"

    show ben cheerful with eidissolve_nd

    B "Igottagotoo,byeee..."

    show ben at moveoutleft(0.25)
    hide ben
    pause 1

    "Whoa, he walks fast when he has somewhere to be."

    pause .5
    show inco concerned left with eidissolve

    "{cps=5}...{/cps}That reaction doesn't exactly instill confidence in me."
    window auto hide
    pause .5

    stop sound fadeout 2

    scene black with Dissolve(1)
    pause .5

    "{cps=5}...{/cps}"
    pause .5

    play music mus_general

    "I follow Ben's directions towards the school gymnasium."

    "After all the earlier commotion, it's the first quiet moment to myself."

    "Might as well take it to finally sort my thoughts."
    pause .5

    "Let's see, what do I think of this place so far?"

    #"There are worms under your skin. There are worms under your skin. Get them out rip them out"

    "It's certainly livelier than any of the other schools I've been to."

    "Ever since I've stepped foot in here everything has been so lively, and everyone seems so... exuberant!"

    "It makes me feel a little out of my depth, since I'm so used to the opposite."

    "Here, people like that girl earlier are eager to share their hobbies almost without being prompted."

    "Everywhere else I've been, people just kept to themselves, like they're only there because they have to be."
    pause .5

    "{cps=5}...{/cps}It hits me."

    "This school's art program attracts people, the students here don't {i}have{/i} to be here."

    "They're {i}choosing{/i} to be here, that's why it's so active!"
    pause .5

    "Well, alright. What can I do with this information?"
    pause .5

    "...It means I can probably be friends with anyone I want, right?"

    "Weird to say, but with everyone here sort of working with each other there's bound to be an insane level of camaraderie, too."

    "Maybe I won't even have to try?"
    pause .5

    "I'm almost at the gymnasium now, though, so I'll hold this thought for later."
    pause .5

    "{cps=5}...{/cps}"
    pause .5

    "Ah, gym class. Where the boys are separated from the men and where people with herculean physiques are able to show off their sculpted bodies."
    pause .5

    "{cps=5}...{/cps}"
    pause .5

    "I begin to remember how much I dreaded going to PE."

    "The innumerable bad experiences from past schools pale in comparison to the many skidded knees and broken glasses..."

    "Hopefully this school's PE is a lot less grueling."
    window auto hide
    pause .5

    # we ought to have a double doors CG similar to the auditorium for stuff like this

    scene bg_gym with dissolve:
        zzoom True
        zpos -2400
    pause .5

    "As I stand before the wooden double doors leading into the gym, I'm struck with how empty the area looks."

    "That's followed by me catching the sound of physical activity coming from within the gym itself."

    "Shoot, I really am late."

    "Ben's earlier warning echoes in my head like a foreboding spirit."
    pause .5

    "I peer through the small windows on the doors and see students standing shoulder to shoulder."

    "Towering over them is a primate who I can only guess is our gym teacher, with his arms crossed and a scowl on his face."

    "I hope I can get away with being tardy..."
    pause .25

    show inco neutral left at moveinleft(0.5) with eidissolve
    pause .25

    "As I walk into th-"
    window auto hide Dissolve(0.0)

    play sound snd_slapstick_fastthrow
    stop music fadeout 0.1
    show spr_dodgeball:
        xpos -0.2
        ypos 0.3
        linear 0.2 xpos 1.2

    pause 0.05

    camera at gym_shaker_hit()
    show inco shocked at setx(0.5), hity()

    pause 0.75
    play sound snd_dodgeball_impact_wall
    show inco with xpunch
    hide spr_dodgeball

    pause 3.0
    show inco terrified right with eidissolve

    pause 0.5

    #Sprite of Inco flinching, shocked expression, as a dodgeball whizzes by his head, have the "MISS!" text appear above him + dodgeball sfx from the wall behind him

    "My first thought is how lucky I am to be alive."

    "I don't even know what was thrown at me, but it might as well have been a cannon ball."

    show inco surprised left with eidissolve

    "I spot the gym teacher, and even through his baseball cap I can feel his stare of rage pierce my soul."

    "Such intensity, and that ideal throwing form..."

    "It only missed by centimeters."
    pause 0.5
    show black behind inco with dissolve:
        alpha 0.4
    show inco concerned left with eidissolve

    "That was a warning shot."
    window auto hide
    hide black with dissolve
    pause .5

    camera:
        linear 2 xpos -0.25
    show solly neutral:
        xpos -0.15
        easein_cubic 2 xpos -0.05
    pause 3

    play music mus_intense
    #show inco at movex(0.7)
    #show solly neutral at moveinright(0.3) with eidissolve

    camera at setx(-0.25)
    show solly yelling at setx(-0.05), nudgeup()

    Coach "{atl_heavy=sh}KNOW THIS AND KNOW IT WELL, SON.{/atl_heavy}" 

    Coach "{atl_heavy=sh}I HAVE A POLICY.{/atl_heavy}"

    Coach "{atl_heavy=sh}EACH OF MY PLATOONS GETS ONE FREE MISS FROM ME {i}A YEAR.{/i}{/atl_heavy}"

    show solly at sety(), backmovex(-0.03)

    Coach "{atl_heavy=sh}AND YOU JUST SPENT IT.{/atl_heavy}"

    show solly neutral with eidissolve

    "I shift my eyes to the students lined up next to him, and they're so stiff with fear that I can't tell what they're feeling."
    pause .5

    show solly yelling at nudgeup()

    Coach "{atl_heavy=sh}YOU GOT THREE SECONDS TO LAY IT ON THE FRONT OF YOUR SQUADRON WHY IN \nTHE GREAT NAME OF CAVY DROCKETT YOU ARE LATE??{/atl_heavy}"

    show solly neutral with eidissolve

    I "{cps=10}Well I-{/cps}"

    play sound snd_slapstick_bonecrack
    show solly at hity()
    pause 1

    #Inco scared and shaking

    "He didn't even move-"

    "Hint taken. I shut my mouth."
    pause .5

    "The simian scholar starts marching back and forth like a drill sergeant."

    camera:
        setx(-0.25)
        movex(-0.55)
    show inco:
        easeout 0.5 alpha 0.0

    show solly left with eidissolve
    show solly yelling at sety(), nudgeup()

    Coach "{atl_heavy=sh}LISTEN UP, BECAUSE I'M ONLY SAYING THIS ONCE.{/atl_heavy}" with xpunch

    Coach "{atl_heavy=sh}IN THIS CLASS WE OPERATE ON 'TOUGH LOVE'.{/atl_heavy}"

    Coach "{atl_heavy=sh}WE LEARN FROM OUR MISTAKES, SO YOU BETTER PRAY TO RAPTOR JESUS YOU \nDON'T FORGET THEM.{/atl_heavy}"

    Coach "{atl_heavy=sh}BECAUSE IF YOU DO...{/atl_heavy}"

    camera:
        setx(-0.55)
        movex(-0.1)

    show inco:
        alpha 0.0
        easein 0.5 alpha 1
    show solly at sety(), movex(0.25)
    show solly neutral right with eidissolve
    show inco shocked:
        alpha 1.0
        nudgeup()

    "With three monstrous steps the couch closed the distance of ten yards to tower over me."

    show solly yelling at nudgeup()

    Coach "{atl_heavy=sh}I WILL BE {i}VERY{/i} UPSET.{/atl_heavy}"

    Coach "{atl_heavy=sh}IT REFLECTS POORLY ON ALL OF US, AND THAT IS {i}NOT{/i} SOMETHING I WILL \nACCEPT.{/atl_heavy}"

    Coach "{atl_heavy=sh}SO I WOULD {i}LOVE{/i} TO SEE YOU MAGGOTS SUCCEED, BUT IF YOU DON'T, I'LL MAKE \nIT UNFORGETTABLE.{/atl_heavy}"

    Coach "{atl_heavy=sh}AM I UNDERSTOOD?!{/atl_heavy}"
    
    show solly neutral with eidissolve

    show inco at rotate_funny(0.05)

    "I nod my head in fear."

    show solly yelling at hop()
    Coach "{atl_heavy=sh}FAN-FREAKIN'-TASTIC!!{/atl_heavy}" with xpunch

    Coach "{atl_heavy=sh}NOW THEN, JOIN THE REST OF YOUR RANKS AND STIFFEN UP!{/atl_heavy}"

    show solly at sety(), moveoutleft_cs(0.25)
    show solly neutral left with eidissolve
    hide solly

    pause 0.5
    show inco at standup(0.0, 1.0, 0.5)
    camera:
        setx(-0.1)
        movex(0.0)

    "Once I confirm my bladder is intact, I shuffle over to where my colleagues stand."

    "I feel them staring at me with anger, like I'm responsible for the coach's... teaching style."

    "What an appalling first impression to make. I should just quit and start over somewhere else while I still can."
    pause 0.5

    "The teacher takes a second to glance over us, reminding himself of where he was before I had interrupted."
    window auto hide

    camera:
        setx(0.0)
        easemovex(-0.65)
    show solly neutral at setx(-0.15)
    pause 1.0
    show solly yelling at hity()

    window auto show Dissolve(0.0)

    Coach "{atl_heavy=sh}{b}{i}ATTENT-HUT MAGGOTS!!{/b}{/i}{/atl_heavy}" with xpunch

    Coach "{atl_heavy=sh}YOU WILL {b}{i}ALL{/b}{/i} DROP AND GIVE ME {b}{i}TWENTY OF THE FINEST PUSH-UPS!{/atl_heavy}"

    Coach "{atl_heavy=sh}THOSE GUTS BEST BE AN ANT'S FART OFF THAT PRISTINE GYM FLOOR OR ELSE!{/atl_heavy}"
    pause 0.25
    
    play sound snd_whistle
    show solly neutral at nudgeup()

    Coach "*Whistle*"
    show solly at moveoutdown()
    hide solly
    pause 0.5

    "With a violently loud blow of his whistle the couch also takes his position to show the proper technique."

    show inco concerned

    camera:
        setx(-0.65)
        movex(0.0)
    pause 1.0

    show inco:
        resetrotate
        moveoutdown()
    hide inco
    pause 0.5

    "I hide my wince as my knees impact roughly on the ground."

    "The real pain starts as I try to keep pace with everyone around me." 

    "My biceps and forearms threaten to splinter from the weight of my body and the speed of my jerky movements"
    pause 0.5

    "...I never realized just how badly out of shape I was."
    pause 0.5

    play sound snd_whistle
    Coach "*Blows Whistle*"

    Coach "{atl_heavy=sh}ON YOUR FEET YOU BIPEDAL SLUGS!{/atl_heavy}"
    pause 0.5

    "Ha{cps=5}...{/cps}ha{cps=5}...{/cps}{w=.3} this guy{cps=5}...{/cps}{w=.3} he ain't human!"

    "Some kind of primate, maybe? A close relative."

    show inco concerned sweat left at moveinup() with eidissolve

    "I can feel my muscles hollering in pure agony as I force myself up from the gymnasium floor."

    "By the time I'm back on my feet, my breathing is heavy and coming out in whistles."
    pause 0.5

    Coach "{atl_heavy=sh}NOW THEN, SINCE IT'S ONLY THE FIRST DAY OF SCHOOL, HOW ABOUT WE HAVE \nOURSELVES A GOOD OLD GAME OF DODGEBALL!?{/atl_heavy}"

    stop music fadeout 0.02
    show inco shocked left at hity()
    pause 0.5

    show black behind inco with dissolve:
        alpha 0.4
    "D-did he say... dodgeball!?"
    pause 0.5

    unknown "Oh yeah! Dodgeball time!"

    play music mus_damien

    camera:
        setx(0.0)
        movex(-0.15)
    show black at movex(-0.15)
    hide black with dissolve_nd

    show damien happy gym left at setx(0.2) behind inco with eidissolve
    show inco concerned with eidissolve

    "I shoot a glance towards the overly enthusiastic dino next to me, who is absolutely elated by the prospect of the upcoming game."

    "We only finished the warm-up and my muscles are already screaming." 

    "My knees shake, my lungs burn, and I'm so drenched in sweat that I'm sure I might need a shower after this."

    "I really don't want to play dodgeball..."

    show damien happy right with eidissolve
    show damien at hop()
    #Show Damien sprite facing Inco

    unknown "Aren't we lucky!? First day of school and we get to play a game!"
    pause 0.5

    I "{cps=15}I...{/cps}{w=.4} {cps=15}I don't...{/cps}{w=.4} I don't do dodgeball..."

    show damien skeptical with eidissolve

    unknown "Why not?"
    pause 0.5

    I "{cps=15}I...{/cps}{w=.4} {cps=15}uh...{/cps}{w=.4} I'm not exactly..."

    show damien neutral at hop()
    show inco surprised at hop()

    Coach "{atl_heavy=sh}ALRIGHT MAGGOTS! PICK A SIDE AND KEEP THE NUMBERS EVEN!{/atl_heavy}" with xpunch

    Coach "{atl_heavy=sh}THIS IS A SUICIDE MATCH!{/atl_heavy}"

    show damien at hop()
    show damien happy left with eidissolve

    unknown "And free for all too!"

    Coach "{atl_heavy=sh}DAMIEN! WHY DON'T YOU SOCIALIZE BY PICKING YOUR TEAMMATES?{/atl_heavy}"

    Coach "{atl_heavy=sh}SHADES, YOU'RE ON BLUE TEAM.{/atl_heavy}"
    
    pause 0.5

    "Didn't he say we could pick teams?"

    D "Alright! I'm going with the human dude!"

    camera:
        setx(-0.15)
        easemovex(0.3, 1.5)

    show damien at sety(), easemovex(0.9, 2)
    show damien neutral right with eidissolve
    pause 0.5

    show inco at sety(), movex(0.75)
    show inco right with eidissolve

    "Before I can even say a word, the dilophosaurus wraps an arm around my neck and brings me to his side of the field."    
    pause 0.5

    Coach "Oh, and one last thing."

    stop music fadeout 3
    show inco at setx(0.75), nudgeup() with None

    show inco surprised
    show damien considering
    with eidissolve

    "His leer and tone freeze me to the spot."
    pause 0.5

    Coach "{atl_heavy=sh}WHAT'S THE FIRST RULE! WE ONLY ONLY GOT ONE.{/atl_heavy}"

    show inco concerned left
    show damien neutralconsidering
    with eidissolve

    I "Have f-{w=.4}fun...?"

    play sound snd_crowd_yell
    show damien at hop()

    Everyone "GANG UP ON THE WEAKEST ONE!"

    show inco shocked with eidissolve_nd

    I "Wait, wha-"

    play audio snd_whistle
    Coach "*BLOWS WHISTLE*"

    play music mus_angry volume 1.0
    play ambient1 amb_crowd_rowdy_loop fadein 3 volume 0.35

    show spr_dodgeball:
        rotate -9 xpos -1.34 ypos 0.9
        block:
            #function temp_sound_for_dodgeball
            linear 0.3 xpos 1.34 ypos 0.3
            pause 0.9
            linear 0.3 xpos -1.34 ypos 0.9
            pause 0.9
            repeat
    show spr_dodgeball as spr_dodgeball2:
        rotate 9 xpos 1.23 ypos 0.54 zpos 333
        pause 0.2
        block:
            linear 0.5 xpos -2.21 ypos 0.04
            pause .7
            #function temp_sound_for_dodgeball
            linear 0.5 xpos 1.23 ypos 0.54
            pause .7 
            repeat
    show spr_dodgeball as spr_dodgeball3 behind inco:
        rotate -12 xpos -3.06 ypos 1.0 zpos -270
        pause 0.4
        block:
            #function temp_sound_for_dodgeball
            linear 0.45 xpos 1.43 ypos -0.00
            pause 0.75
            linear 0.45 xpos -3.06 ypos 1.0
            pause 0.75
            repeat
    show spr_dodgeball as spr_dodgeball4:
        rotate 9 xpos 1.0 ypos 0.41 zpos 800
        pause 0.6
        block:
            linear 0.4 xpos -1.51 ypos 0.0
            pause 0.8
            #function temp_sound_for_dodgeball
            linear 0.4 xpos 1.0 ypos 0.41
            pause 0.8
            repeat
    show spr_dodgeball as spr_dodgeball5 behind inco:
        rotate 9 xpos -1.31 ypos -0.33 zpos -27
        pause 0.8
        block:
            #function temp_sound_for_dodgeball
            linear 0.3 xpos 1.31 ypos 0.33
            pause 0.9
            linear 0.3 xpos -1.31 ypos -0.33
            pause 0.9
            repeat

    show damien at sety(), moveoutright(0.9)
    hide damien   

    "In a matter of seconds, the gymnasium becomes a full-blown battleground."

    "I do my best to dodge the oncoming flurry of red rubber spheres coming my way like bullets."

    show inco at moveoutdown()
    hide inco

    "I dive to the ground, avoiding the oncoming projectiles as they soar overhead and pelt my comrades."

    "I hear the blows, and the guttural groans of those who've already succumbed to the onslaught of inflated orbs."

    camera:
        setx(0.3)
        movey(0.3)

    show inco concerned left at moveinup(0.75, 0.6) behind spr_dodgeball, spr_dodgeball2, spr_dodgeball4 with eidissolve

    "Combat crawling away from the fierce front, I entrench myself along the edge of the field in the hopes of being ignored."

    "I cast my gaze to the rest of my allies, and oh god it's a full rout, so many bod-"

    D "So, how's the first day of school treating you, bro?"

    camera:
        movexy(0.35, 0.0)
    show inco at movey(0.38) with None
    show inco right
    show damien gym neutral left at setx(1.0) behind spr_dodgeball, spr_dodgeball2, spr_dodgeball4
    with eidissolve

    "I look up to see the finned dino, the same pink dilophosaurus who had dragged me to his side of the court, staring down at me and smiling."
    pause .5
    show inco at nudgeup(0.38)

    I "What do you think?!"
    #Inco (low) angry sprite

    show damien:
        movex(1.03)
        backmovex(1.0)

    "I watch as he casually dodges an incoming ball before throwing his own."

    show damien at setx(1.0), hop()

    D "Name's Damien by the way!"

    show inco at hity(0.38)

    I "I-Inco!"

    D "Nice to meet you!"

    show inco left at nudgeup(0.38)

    Coach "{atl_heavy=sh}YOU TWO! CHROMEDOME AND FRILLS!{/atl_heavy}" with xpunch

    Coach "{atl_heavy=sh}WHO SAID THAT YOU TWO HAD TIME TO TALK?!{/atl_heavy}"

    Coach "{atl_heavy=sh}DOES MY GYMNASIUM LOOK LIKE A DEBATE STAGE?!{/atl_heavy}"

    show damien considering with eidissolve

    #Damien sprite of him standing casually, even though there's dodgeballs being thrown at him
    D "I mean, maybe if we got some of those stands from the auditorium, maybe!"

    show damien neutral with eidissolve_nd

    D "I know a guy's uncle that could make a really classy podium!"

    show inco right with eidissolve

    #Inco sprite of absolute confusion and possibly horror
    "I look up at Damien with absolute bewilderment."

    "What is this guy thinking?! The coach looks like he's about to explode!"

    Coach "{atl_heavy=sh}DO NOT PLAY SMART WITH ME, SON! KEEP YOUR TRAP SHUT AND EYES FOCUSED \nON THE ENEMY!{/atl_heavy}"

    show damien cheerful left with eidissolve

    "Damien just smiles and gives the coach a thumbs up, as if we aren't in the middle of an active warzone."

    D "You got it, Mr. Solly!"

    So "{atl_heavy=sh}THAT'S COACH SOLLY TO YOU.{/atl_heavy}"

    So "{atl_heavy=sh}AND WHAT'S THE HOLD UP, SHADES?! YOU'RE JUST MAKING YOURSELF AN EASY \nTARGET ON THE FLOOR.{/atl_heavy}"

    So "{atl_heavy=sh}GET UP AND PLAY TO WIN!{/atl_heavy}"

    show inco concerned left with eidissolve

    "Alright... guess it's my time to do something of worth."

    camera:
        setxy(0.35, 0.0)
        movex(0.25)
    show damien at moveoutright(1.0)
    hide damien
    pause 0.5

    "But... I'm not exactly good at dodgeball..."

    "{cps=5}...{/cps}"
    pause .5

    show inco surprised left at nudgeup(0.38)

    "Oh! Maybe I can do the whole blocking thing for everyone."

    "That should {i}hopefully{/i} make it so that everyone isn't peeved at me for wasting the warning shot."

    "But, here's where things change!"

    "I can totally turn this around. All is equal in the court!"
    show inco neutral with eidissolve

    "A ball aimlessly rolls on the floor in front of me, calling out to be my ammunition."

    pause .25
    show inco at backmovey(0.0)
    pause 1
    show inco at sety(0.0), slideinplace2(0.75)

    "I somehow weave through two shots at me and pick up the ball."

    show inco smug left with eidissolve

    "Oh, yeah! I'm feeling it now!"

    "I'm on fire, there's no way I'm losing now!"

    "I grab onto the ball and start blocking any shot that so much as crosses our side of the field."

    "Yeah! I'm doing great!"
    pause .5

    "Block one."

    "Block two."

    "Block three!"

    "Now I'm REALLY feeling it!"

    "I bet everyone's looking at me now!"

    "Any thought of playing the game suddenly left my mind like it was never there."

    "Who cares!"

    "Doing this is more than enough!"

    "I can be the sta-"

    unknown "Hey, new guy!"

    show inco at movex(0.75)
    show inco surprised with eidissolve

    "A new voice catches my attention. A crimson parasaurus."
    window auto hide

    show mia gym neutral behind spr_dodgeball, spr_dodgeball2, spr_dodgeball4:
        matrixcolor BrightnessMatrix(-1)
        setx(-0.7)
    camera:
        easemovex(-1.0, 1.5)
    pause 1.2

    show mia at nudgeup()

    unknown "Thinkfast!"

    camera:
        setx(-1.0)
        easemovex(0.3, 1)
    pause 1

    I "Wha-"
    window auto hide

    show inco shocked with None:
        parallel:
            hity()
        parallel:
            pause .2
            easemovex(0.8, 1.2)

    hide spr_dodgeball
    hide spr_dodgeball1
    hide spr_dodgeball2
    hide spr_dodgeball3
    hide spr_dodgeball4
    hide spr_dodgeball5
    with dissolve

    play sound snd_impact

    pause .2
    show spr_dodgeball as spr_dodgeball6:
        xpos -0.1
        ypos 0.18
        linear 0.1 xpos 0.6
    pause .1

    stop ambient1 fadeout 0.02
    stop music fadeout 0.02
    camera:
        setx(0.0)
    scene black

    pause 0.5

    play sound snd_bodyslam

    pause 2.0

    #insert *BONK* graphic

    "{cps=5}...{/cps}"
    pause 0.5

    "{cps=5}...{/cps}"
    pause 0.5

    "{cps=15}The floor is cold.{/cps}"
    pause 0.5

    "{cps=5}...{/cps}Maybe I shouldn't have come here at all."
    pause 0.5

    "{cps=5}...{/cps}"
    pause 0.5

    "A pair of extremely dirty sneakers enter my field of view."
    pause 0.5

    So "You gonna get up, Shades?"
    pause 0.5

    "{cps=5}...{/cps}"
    pause 0.5

    I "{cps=10}No... I give up...{/cps}"
    pause 0.5

    So "*sigh*"
    window hide
    pause 0.5

    #Solly dunks inco with a second ball.
    #Insert *CRITICAL HIT* sound and graphic

    play sound snd_impact
    pause 0.3
    window auto show Dissolve(0.0)
    "*BONK*" with xpunch
    pause 0.5
    

    "{cps=5}...{/cps}"
    pause 0.5

    play music mus_awkward

    "{cps=15}Ohh... man... That hurts.{/cps}"
    pause 0.5

    "How long was I out?"

    "I'm laying down on something soft, where am I?"
    window auto hide
    pause 0.5

    scene bg_nurse with Dissolve(1)
    pause 0.5

    #fade into nurses' room
    "My vision clears, and I sit up from the plastic bed."
    pause 0.25
    show inco blank at moveinup(0.3) with eidissolve
    pause 0.25

    "Sure is bright in here."
    pause 0.5

    show inco at nudgeup()

    "Oh, shit!"

    "They broke my sunglasses!"
    pause 0.5

    "Lucky I brought my reserve pair."
    window auto hide
    pause 0.25

    show spr_inco_glasses_down:
        xanchor 0.5 xpos 0.3 ypos -0.3
        linear 1 ypos 0.0

    pause 1.75

    show spr_inco_glasses_down:
        on hide:
            parallel:
                easein_cubic 0.5 ypos -0.02
            parallel:
                linear 0.5 alpha 0.0

    show spr_inco_glasses_up:
        xanchor 0.5 xpos 0.3 ypos 0.02
        easein_cubic 0.5 ypos 0.0
    hide spr_inco_glasses_down

    pause 0.5

    show inco neutral
    hide spr_inco_glasses_up
    hide spr_inco_glasses_down

    show inco smug with eidissolve

    "Much better."

    show inco neutral with eidissolve

    "I stand from the rubber mattress, taking in the tiny room finally."

    "All alone? Not even a school nurse or anything?"

    show inco neutral left with eidissolve

    #Inco turn left and right

    "Oh, there she is."

    "Looks like she's attending to another student who... has his snout stuck in a cone."

    "Huh."

    show inco neutral with eidissolve

    "Looking at the clock on the wall, it's already noon."

    "That would explain the pounding headache."

    So "Finally awake, shades?"

    show inco shocked right at hity()
    show solly neutral left at moveinleft(0.7) behind inco with eidissolve

    "I sit ramrod straight, the fear of God stricken into me once more."
    pause 0.5

    So "Calm yourself, cadet."

    So "You ate dirt pretty hard back there."

    show inco verysad with eidissolve

    I "Oh, man... Yeah."

    show inco skeptical with eidissolve

    I "Wait... You did that."

    So "I did. Pelted you right in the back. Do you know why?"
    pause 0.5

    I "{cps=15}Because I messed up...?{/cps}"

    So "Be more specific, kid."

    show inco concerned with eidissolve

    I "{cps=5}...{/cps}"
    pause 0.5

    I "{cps=5}...{/cps}Because I couldn't be a good teammate and got hit in the face?"

    show solly at nudgeup()

    So "{i}RRRT{/i}, wrong."

    So "It was after that."
    pause 0.5

    I "{cps=10}I don't...{/cps}{w=.4} nothing happened after that."

    So "No. You gave up."
    pause 0.5

    I "But... I was doing well..."

    So "You think so?"
    
    I "I was blocking the balls and all..."
    
    So "You weren't blocking anything. You were showing off."
    
    So "You found a single thing you could do and started dancing around like a clown."

    So "You focused on the easy thing, and gave up the real thing."

    So "You were so focused that you forgot to look around for a moment."

    So "...And here you are."
    pause 0.5

    So "I know a defeated man when I see one, and there's no way in hell I'm letting a student of mine give up so easily."

    So "It's the first period of the first day, and you're already giving up."

    So "Either way, that's a pretty bad lump you ended up with."

    So "You gotta watch around {b}some{/b} students, if you know what I mean."

    show inco verysad with eidissolve

    "I blink a few times and recall the chick that yelled at me to 'catch', followed by pounding me in the face."
    pause 0.5

    So "That one, she's, eh..."

    show solly happy with eidissolve
    
    "He chuckles to himself a bit."

    So "She's something, alright."

    I "Yeah. Looked like the devil herself."

    show solly neutral with eidissolve

    So "Anyways, take the rest of the day off, kid."

    show inco at nudgeup()
    show inco surprised with eidissolve_nd

    I "What?"

    So "I'm telling you to go home."

    So "The principal gave the okay."
    pause 0.5

    "I feel my head again. Another stab of pain."

    "Am I really not good to go back to class?"

    "Wasn't I getting lectured about this just a few moments ago?"

    show inco neutral with eidissolve

    I "{cps=10}Well...{/cps}{w=.4} I don't want to give up so easy."

    So "No. You should go home to your folks."
    pause 0.5
    show solly at movey(0.03)

    "He scratches the back of his head, slightly embarrassed."
    pause 0.5

    So "Er,{w=.5} right,{w=.5} about that..."

    show solly at movey(0.0)
    pause 0.5

    So "We tried calling them earlier."

    So "Couldn't reach 'em."
    pause 0.5

    "I give a sad half-smile." 

    "Yeah. Sounds about right."
    pause 0.5

    I "I can make it home fine on my own."

    "He nods."
    pause 0.5

    So "When you get back, don't give up so easily."

    show solly at movex(0.8)
    show solly neutral with eidissolve

    "He holds the door to the nurses' office open."

    "I nod and exit the office, Coach Solly closing and locking the door."
    window auto hide

    show inco:
        sety()
        easeout_cubic 1 xpos 0.55
    pause 0.5
    scene black with dissolve
    pause 0.5

    #Hallway bg

    scene bg_school_hallway with dissolve
    pause 0.25
    show inco neutral left at moveinleft(0.5) with eidissolve
    show solly neutral left at moveinleft(0.8) with eidissolve
    pause 0.25

    So "Oh, and here's for tomorrow."

    show inco right with eidissolve
    show inco at backmovex(0.47)

    "A brown paper bag is shoved into my arms, along with my backpack."

    "Peaking in, I see something blue and gold wrapped in plastic."
    pause 0.5

    So "If you hadn't been late, you could've changed into those."

    I "{cps=10}I uh...{/cps} thank you, sir."

    So "Next time, Shades, think faster. Got it?"

    I "Yes sir!"

    show solly happy with eidissolve

    "His smile is positively unnerving."

    show solly at nudgeup()

    So "Now scram, cadet!"
    window auto hide

    show inco at moveoutleft_cs(0.5)
    show inco neutral left with eidissolve
    hide inco

    pause 1
    stop music fadeout 2
    scene black with dissolve
    pause 2

    #Inco turns and leaves the scene
    #Fade out
    #Fade in to the gala

    play music mus_introspective_night
    scene bg_school_hallway with Dissolve(1)
    pause 0.5

    "Welp, this is officially the worst first day I've ever had."
    pause 0.5

    "As my feet drag along the linoleum floor I can't help but painfully think of all the failures of the past few hours."

    "No thanks to a very prominent bump on the back of my head. Ow."

    "I'm worse than everyone here both on a creative {i}and{/i} physical level."

    "I know I really shouldn't be bothered by it, but I hate seeing just how far behind I am compared to everyone else."

    # typo?
    "And I thought I'd new friends with."

    "What was I thinking?"
    pause 0.5

    "I stop and shake my head a bit."

    "What the heck am I doing sulking like this?" 

    # italicize?
    "It's a bad first day, but it's *just* the first day."

    "There's still all the rest."

    "I still met Ben and Damien, they're pretty cool."

    "I'm not gonna let my optimism be ruined just because of a bad dodgeball match."

    "Just you wait, St. Hammond. Today was a test run."

    "Tomorrow's the real deal."
    window auto hide
    pause 0.5

    stop music fadeout 2
    scene black with Dissolve(1)
    pause 0.5

    "{cps=5}...{/cps}"
    pause 1

    return