add bonus Trish chapter part 1
This commit is contained in:
parent
2bbef6aa79
commit
886c2909ef
|
|
@ -229,7 +229,8 @@ image stella sad flip = im.Flip("stella/stella sad.png", horizontal=True)
|
|||
image stella prom sad flip = im.Flip("stella/stella prom sad.png", horizontal=True)
|
||||
image reed sad flip = im.Flip("reed/reed sad.png", horizontal=True)
|
||||
|
||||
#shocked flips
|
||||
#shocked flip
|
||||
# WHY IS THERE NO CONSISTENCY BETWEEN 'SHOCK' AND 'SHOCKED' I SWEAR TO FUCK
|
||||
image anon shocked flip = im.Flip("anon/emotive set/anon shocked.png", horizontal=True)
|
||||
image anon ohshit flip = im.Flip("anon/base set/anon ohshit.png", horizontal=True)
|
||||
image anon prom shock flip = im.Flip("anon/prom set/anon prom shock.png", horizontal=True)
|
||||
|
|
@ -240,6 +241,7 @@ image naser shocked flip = im.Flip("naser/naser shocked.png", horizontal=True)
|
|||
image naomi shocked flip = im.Flip("naomi/naomi shocked.png", horizontal=True)
|
||||
image stella shock alt flip = im.Flip("stella/stella shock alt.png", horizontal=True)
|
||||
image rosa shocked flip = im.Flip("rosa/rosa shocked.png", horizontal=True)
|
||||
image trish shock flip = im.Flip("trish/trish shock.png", horizontal=True)
|
||||
|
||||
#considering flips
|
||||
image fang considering flip = im.Flip("fang/basic set/fang considering.png", horizontal=True)
|
||||
|
|
|
|||
|
|
@ -0,0 +1,242 @@
|
|||
# Passion of the Trigga part 1
|
||||
|
||||
label chapter_x4:
|
||||
|
||||
stop music fadeout(3)
|
||||
scene black with Dissolve(1)
|
||||
pause 1
|
||||
|
||||
# appreciating the scenery?
|
||||
# to swagger?
|
||||
# west coast kicking?
|
||||
"{cps=*.3}-- February Seventeenth --{/cps}"
|
||||
|
||||
play music 'audio/ost/west_coast_kicking.ogg' fadein 1.0
|
||||
pause .5
|
||||
|
||||
"I lean back against the wall, my freshly polished horns feeling fantastic today."
|
||||
|
||||
"I deserve it after all the shit I deal with at school. Not to mention the tiny terrors at home{cps=*.1}...{/cps}"
|
||||
pause .5
|
||||
|
||||
"A part of me wants to feel bad that I left Fang on her own the other day."
|
||||
|
||||
"Especially with that useless skinnie."
|
||||
|
||||
"But between the nice clean feeling on my scalp and the great news{cps=*.1}...{/cps}"
|
||||
pause .5
|
||||
|
||||
scene bandroom
|
||||
show fang happy:
|
||||
yalign 0.0 xalign 0.1
|
||||
show trish surprised flip:
|
||||
yalign 0.0 xalign 0.7
|
||||
with Dissolve(1)
|
||||
pause .5
|
||||
|
||||
T "Skinnie convinced him? How'd he manage to do that?"
|
||||
|
||||
show fang:
|
||||
easein_cubic 1 xalign 0.05
|
||||
show fang very happy with Dissolve(.25)
|
||||
F "I dunno but it's awesome! A real venue this time!"
|
||||
|
||||
show dimmer_lighter behind trish with dissolve
|
||||
|
||||
"It takes a second to actually register it."
|
||||
|
||||
"An actual venue..?"
|
||||
|
||||
"An actual venue!!"
|
||||
|
||||
"The thoughts and possibilities flare in my head, all one step closer to reality."
|
||||
|
||||
show trish:
|
||||
easein_cubic 1 xalign 0.75
|
||||
with None
|
||||
show trish very happy flip
|
||||
hide dimmer_lighter
|
||||
with dissolve
|
||||
T "Our chance to make VVURM DRAMA the hit it deserves to be!"
|
||||
|
||||
"Our celebration continues until someone, probably one of the teachers passing by, knocks on the music room’s door several times."
|
||||
|
||||
show fang happy
|
||||
show trish considering flip
|
||||
with dissolve
|
||||
|
||||
"Then I remember the person responsible."
|
||||
pause .5
|
||||
|
||||
"Ah, maybe skinnie isn’t so bad."
|
||||
pause .5
|
||||
|
||||
"Pffft, nah. I probably coulda convinced that fucking fossil too."
|
||||
|
||||
show trish neutral flip with dissolve
|
||||
"{cps=*.1}...{/cps}"
|
||||
|
||||
"I look at Fang and notice them with a look on their face I haven’t seen in a very long time."
|
||||
|
||||
"Like they’re daydreaming again."
|
||||
pause .5
|
||||
|
||||
"It’s kinda weird. Like they’re too{cps=*.1}...{/cps}"
|
||||
|
||||
"Embarrassed looking? Hmm?"
|
||||
pause .5
|
||||
|
||||
T "So{cps=*.1}...{/cps} You two do anything else all day?"
|
||||
|
||||
F "Not really. After I told Naser to fuck off, we got free pizza and just hung out."
|
||||
|
||||
T "Exciting."
|
||||
|
||||
"Unremarkably dull, more like. The guy looks duller than dull."
|
||||
|
||||
show fang neutral with Dissolve(.25)
|
||||
F "{cps=*.1}...{/cps}Well{cps=*.1}...{/cps} there is something else I wanted to talk about."
|
||||
|
||||
show trish surprised flip with Dissolve(.25)
|
||||
"I sit up and nod, giving them my undivided attention."
|
||||
|
||||
T "Sure, go for it, Fang."
|
||||
|
||||
F "{cps=*.1}...{/cps}Promise you won't tell anyone? Not even Reed."
|
||||
|
||||
show trish smug flip with Dissolve(.25)
|
||||
T "Ooh, Fang has a big secret now, do they?"
|
||||
pause .5
|
||||
|
||||
show fang considering with Dissolve(.25)
|
||||
F "{cps=*.1}...{/cps}I think Anon{cps=*.1}...{/cps} likes me{cps=*.1}...{/cps}"
|
||||
pause .5
|
||||
|
||||
show trish unimpressed flip
|
||||
"What."
|
||||
|
||||
T "{cps=*.1}...{/cps}Gross, Fang."
|
||||
|
||||
show trish neutral flip with Dissolve(.25)
|
||||
T "You sure he's not just trying to get into your pants or something?"
|
||||
|
||||
show fang neutral with Dissolve(.25)
|
||||
"Fang sighs and looks up. Their snout waves back and forth as they stare up at the dirty looking ceiling while thinking."
|
||||
pause .5
|
||||
|
||||
F "I don't know{cps=*.1}...{/cps} he has this thing he does where he mumbles{cps=*.1}...{/cps} I don't think he knows he does it."
|
||||
pause .5
|
||||
|
||||
F "Some of the things he says are{cps=*.1}...{/cps} nice things about me."
|
||||
|
||||
show fang unimpressed with dissolve
|
||||
F "It's{cps=*.1}...{/cps} you know, kind of cute{cps=*.1}...{/cps}"
|
||||
pause .5
|
||||
|
||||
show trish unimpressed flip with Dissolve(.25)
|
||||
"Just what did that skinnie say and do? I swear{cps=*.1}...{/cps}"
|
||||
pause .5
|
||||
|
||||
T "Don't tell me-"
|
||||
|
||||
F "He's still a huge dweeb and all but{cps=*.1}...{/cps}"
|
||||
pause .5
|
||||
|
||||
show fang considering with Dissolve(.25)
|
||||
F "I{cps=*.1}...{/cps} think{cps=*.1}...{/cps} I kinda like him too."
|
||||
|
||||
show trish:
|
||||
easein_back 1 xalign 0.775
|
||||
show trish surprised flip with Dissolve(.25)
|
||||
"What! With Anon! Him!"
|
||||
|
||||
show trish unimpressed flip with Dissolve(.25)
|
||||
T "Fang, are you for real right now?"
|
||||
|
||||
show fang unimpressed with Dissolve(.25)
|
||||
"They huff and cross their arms."
|
||||
|
||||
F "I’m just saying. Anon’s a good friend."
|
||||
pause .5
|
||||
|
||||
show trish considering flip with dissolve
|
||||
"A friend? The way they said it doesn’t sound like friend shit."
|
||||
|
||||
"Not like with me."
|
||||
|
||||
show trish neutral flip with dissolve
|
||||
T "Puhlease, Fang. Anon’s just like every other guy at Volcano High."
|
||||
|
||||
show trish smug flip with Dissolve(.25)
|
||||
T "Only worse because he’s broke and from the boonies."
|
||||
|
||||
show fang neutral with Dissolve(.25)
|
||||
F "C’mon Trish, you’re being harsh on him. You don’t even know Anon."
|
||||
|
||||
show trish neutral flip with Dissolve(.25)
|
||||
T "I don’t need to know him to know he’s just like the rest of them."
|
||||
pause .5
|
||||
|
||||
show fang:
|
||||
easein_back 1.5 xalign -0.05
|
||||
show fang unimpressed with dissolve
|
||||
"I hear Fang sigh and lean back in her chair."
|
||||
|
||||
F "Maybe{cps=*.1}...{/cps}"
|
||||
|
||||
T "No maybes about it, Fang. Their type are all the same. Nothing but loser assholes."
|
||||
|
||||
show fang neutral with Dissolve(.25)
|
||||
F "{cps=*.1}...{/cps}"
|
||||
|
||||
F "Even after he helped us with the venue?"
|
||||
pause .5
|
||||
|
||||
T "A trick probably."
|
||||
pause .5
|
||||
|
||||
show dimmer_light behind trish
|
||||
show trish unimpressed flip
|
||||
with dissolve
|
||||
pause .5
|
||||
"He probably only wants Fang for her body."
|
||||
|
||||
"Fucking sleazy pervert."
|
||||
pause .5
|
||||
|
||||
"I knew I had to keep my eyes on him at all times."
|
||||
pause .5
|
||||
|
||||
"What right does that fucking monkey have to just come into my life and muck things up."
|
||||
pause .5
|
||||
|
||||
show dimmer_light behind fang with dissolve
|
||||
F "Maybe we should get some practice in, Trish."
|
||||
|
||||
hide dimmer_light
|
||||
show trish happy flip
|
||||
with Dissolve(.25)
|
||||
T "Sounds like a plan. We have to prepare for our biggest show yet!"
|
||||
|
||||
show fang happy with Dissolve(.25)
|
||||
pause .5
|
||||
|
||||
"Our biggest show{cps=*.1}...{/cps}"
|
||||
pause .5
|
||||
|
||||
scene black with Dissolve(1)
|
||||
pause .5
|
||||
|
||||
"I hand Fang the blue strat, which they immediately set to tuning just right."
|
||||
|
||||
"Mr.Jingo really needs to get some new gear, these things aren’t maintained at all."
|
||||
|
||||
stop music fadeout 4
|
||||
pause .5
|
||||
"Even this bass, no one ever even uses it."
|
||||
pause .5
|
||||
|
||||
"{cps=*.1}...{/cps}"
|
||||
pause 2
|
||||
|
||||
return
|
||||
Loading…
Reference in New Issue