# Band Practice

label chapter_3:

    # CH 3 SCENE 1 - Weapons of mass distraction

    play music 'audio/OST/Appreciating the Atmosphere.ogg' fadein 1
    scene black with fade

    "{cps=*0.2}-- One Week Later --{/cps}"
    scene classroom with fade
    # TODO: chatter

    "It's math.{w=.5} Bane of retards and lazy intellectuals alike."

    "And teachers too,{w=.4} judging by the lack of a certain coomer teacher."

    "Substitute today,{w=.4} which means busywork.{w=.5} Group problems busywork specifically."

    "Of course,{w=.3} I can't escape this any more than I could have escaped the lab partner assignment."

    "At least here I have the opportunity to just keep to myself for an hour."

    "I don't even bother attempting the assignment,{w=.4} instead pretending my phone is a calculator and spending the first half shitposting about video games I haven’t played online."

    stop music fadeout 2
    "The second half,{w=.4} interrupted by something pointy to the back of the dome."
    pause .5

    "*sshk*"
    pause .5

    "I can feel something stuck between my chair and my back."

    "I fish around and pull out a crumpled paper airplane,{w=.4} a completed set of problems."
    pause .5

    play music 'audio/OST/Fuck You I Like To Shitpost.ogg' fadein 1.0
    "{cps=*.1}...{/cps}this is Reed's.{w=.4} And it's{cps=*.1}...{/cps}"

    "...done?{w=.5} Even the extra problems that I don't even bother with because they take another ten minutes each."

    "I turn around to see that technicolor burnout waving me over.{w=.4} He's sitting next to Trish."

    "She's giving me the evil eye."

    "At least I think it's the evil eye.{w=.5} Whatever that expression is,{w=.4} it clashes with her smile."
    pause .5

    "Might as well see what they want."
    pause .5

    show reed unimpressed:
        yalign 0.1 xalign 0.5
    show trish considering flip at sright
    with Dissolve(1)

    "As I weave through the maze of desks squished together with partners more interested in their phones than the worksheet,{w=.4} I catch a hint of whatever Reed and Trish are talking about."

    Re "{cps=*.1}...{/cps}Honesty is the best policy,{w=.3} eh?"

    Re "{cps=*.1}...{/cps}Bad juju to keep somethin’ bottled up{cps=*.1}...{/cps}"
    pause .5

    show anon neutral:
        yalign 0.1 xalign -0.4
    show anon:
        easein_cubic 1 xalign 0.01
    with dissolve

    show trish neutral flip with Dissolve(.25)
    pause .25

    show reed neutral flip:
        xalign 0.9
    with dissolve
    pause .5

    "Reed grabs hold of another chair and sets it on Trish's other side,{w=.4} nodding in my direction before taking a big pull from whatever he's got in that thermos on his desk."

    "The widening of his pupils suggest its more than just Roarbucks cold brew in it."

    show trish happy flip with Dissolve(.25)
    T "Hey,{w=.2} Anon!"

    A "You guys need something?"

    T "Nah,{w=.3} just wanted to chat a bit since we got the time"
    show trish neutral flip with dissolve

    "There’s something in her tone of voice{cps=*.1}...{/cps}"

    " It’s like she's getting ready to gore me with those nubs she calls horns."
    pause .5

    A "{cps=*.1}...{/cps}Sure"
    pause .5

    show reed explanatory flip
    Re "Imma let you two get to whatever{cps=*.1}...{/cps}{w=.3} gonna go for a refill{cps=*.1}...{/cps}"
    show reed neutral flip

    "He shakes his thermos and heads for the door."


    show reed neutral with Dissolve(.25):
        xalign 0.5
    show reed:
        ease_cubic 1 xalign 1.2
    show trish:
        ease 0.6 xalign 0.85

    "What's in that anyway?"

    pause .5

    show reed considering
    Re "Don't ask{cps=*.1}...{/cps}"
    show reed neutral
    pause .25

    show reed:
        easeout 0.5 xalign 1.5
    hide reed with dissolve
    pause .5

    "Fair enough."
    pause .5

    "{cps=*.1}...{/cps}Wait{cps=*.1}...{/cps}"

    "Fuck it."
    pause .25

    show trish neutral flip:
        ease 1 xalign 0.6
    pause 1.5

    T "So{cps=*.1}...{/cps}{w=.2} Anon{cps=*.1}...{/cps}{w=.4} You and Fang?"
    pause .5

    A "{cps=*.1}...{/cps}You and Fang what?"

    T "They’ve been talkin’ about you."

    A "They?"

    "The tiny triceratops rolled her eyes dramatically."

    show trish unimpressed flip with Dissolve(.25)
    T "Fang.{w=.5} Fang’s been talkin’ bout you."
    pause .5

    A "All good things,{w=.3} I’m sure."

    show dimmer_light behind anon with dissolve

    "Fang’s been talking about me?{w=.5} That’s dumb."

    "Oh yeah.{w=.4} The phones."

    "All we’ve been doing is more labwork in science."

    #[CG of mad scientist Anon with a railgun aimed at Dr. Fernsworth]
    #God I wish we had time for this CG

    "Last Thursday I tried to remember how to make a railgun."

    "To show I could,{w=.4} of course."
    pause .5

    F "{i}Pfft,{w=.4} I could make one too.{/i}"
    pause .5

    "She seemed unimpressed at the time,{w=.4} but{cps=*.1}...{/cps}"

    hide dimmer_light with dissolve

    A "Was it about making a railgun?"

    show trish explanatory flip with Dissolve(.25)
    T "Er{cps=*.1}...{/cps}{w=.2} Yeah,{w=.4} it was."

    show trish unimpressed flip with Dissolve(.15)
    T "What exactly are you talking about with them?"

    A "Just science stuff."

    A "The railgun is just something I happen to know though,{w=.4} picked it up from an old game."

    show trish neutral flip with Dissolve(.25)
    "Trish raises an eyebrow."

    T "{cps=*.1}...{/cps}Right."

    A "Why do you ask?"

    T "You learned to make a deadly weapon from a video game?"

    "Her tone is flat.{w=.5} Unlike her chest."
    pause .5

    A "{cps=*.4}I wouldn’t say deadl-{/cps}{w=.3}{nw}"

    show trish unimpressed flip
    T "Don’t interrupt."

    show trish explanatory flip with Dissolve(.25)
    T "Why would you think that it’s a good idea to make a weapon in class?"

    T "How did you not get in trouble?"
    show trish neutral flip with Dissolve(.25)

    A "Spears actually did talk to me,{w=.4} said something about the 'great equaliser'."
    pause .5

    show trish annoyed flip with Dissolve(.25)
    "Trish grabs the bridge of her snout."

    T "This is why men are useless."

    "She continues to mutter to herself.{w=.4} All of it incoherent."
    pause .5

    A "Is there a point?"

    show trish unimpressed flip with Dissolve(.25)
    "She rounds back on me,{w=.4} anger painted clearly on her face."

    show trish angry flip with dissolve
    T "Look,{w=.4} Anon,{w=.5} YOU may be into that stuff,{w=.4} but leave Fang out of it."

    T "They have better things to do than{cps=*.1}...{/cps}{w=.1} than{cps=*.1}...{/cps}"

    show trish:
        easein_back .25 xalign 0.55
    show anon:
        pause .25
        easein_cubic 0.5 xalign -0.025
    T "Than play with some man-child’s lethal toys!"
    pause .5

    show reed shocked flip:
        yalign 0.1 xalign 1.8
    show reed:
       easein 0.5 xalign 1.6
    with dissolve
    pause .5

    Re "Whoa{cps=*.1}...{/cps}{w=.3} Harsh{cps=*.1}...{/cps}"

    show trish unimpressed flip with Dissolve(.75)
    pause .5

    show reed flip:
        easein_cubic 1.2 xalign 1.15
    show reed neutral flip with Dissolve(.25)

    "Reed slumps into the seat next to Trish,{w=.4} sipping on his thermos of{cps=*.1}...{/cps}"

    show reed considering flip
    Re "Just agua,{w=.2} bro{cps=*.1}...{/cps}"
    show reed neutral flip

    "Thermos of water{cps=*.1}...{/cps}"
    pause .5

    "{cps=*.5}What the-{/cps}{w=.4}{nw}"

    Re "What’d I miss?"

    show trish explanatory flip
    T "I’m just trying to tell Anon here that he shouldn’t be telling Fang how to make a fuckin’ gun in school."
    show trish neutral flip with Dissolve(.25)
    pause .5

    show reed explanatory flip
    Re "Why not?"
    show reed neutral flip
    pause .25

    show trish annoyed flip with Dissolve(.25)
    T "We’ve been over this."

    Re "We have?{w=.4} When?"

    show trish considering flip with Dissolve(.25)
    T "Less than five minutes ago."

    Re "Thought we were talkin’ about Anon?"

    show trish:
        easein_cubic 0.5 xalign 0.425
    show reed behind trish
    show trish indignant with Dissolve(.1)
    T "Yes!"

    T "And specifically!"

    show reed shocked flip:
        easein_cubic 1 xalign 1.2
    show anon:
        easein_cubic 1 xalign -0.055 #-0.025
    play sound 'audio/effects/slapstickPunch.ogg'
    show trish angry:
        easein_elastic 0.5 xalign 0.45 #0.425
    T "We were talking about Anon’s gun!" with vpunch

    show trish unimpressed with dissolve
    pause .25

    "Heads start to turn."
    pause .5

    play sound 'audio/effects/whoosh.ogg'
    show reed happy behind trish with Dissolve(.15):
        xalign 0.8
    pause .5

    "Reed grins at them all"

    Re "Then how bout {i}these{/i} guns?"

    "Reed places his hands on the back of his head and flexes his biceps."
    pause .5

    show trish neutral with Dissolve(.11)
    show trish unimpressed with Dissolve(.11)
    show trish angry with Dissolve(.11)
    show trish considering with Dissolve(.11)
    pause .1
    show trish: #0.45
        linear 0.05 xalign 0.455
        linear 0.05 xalign 0.45
        repeat
    show trish angry with Dissolve(.25)

    show reed neutral flip with dissolve:
        xalign 1.2

    "Trish’s face is a blur of emotions.{w=.5} At first confused,{w=.4} then fucking pissed,{w=.4} then aroused,{w=.4} then back to fucking pissed,{w=.2} all in the space of an attosecond."
    pause .25

    T "Not those!{w=.6} {nw}"
    play sound 'audio/effects/slapstickBigPunch.ogg'
    show reed shocked flip:
        easein_cubic .5 xalign 1.3
    show anon:
        easein_cubic .5 xalign -0.155 #-0.025
    show trish:
        easein_elastic 0.75 xalign 0.425
    extend "The one he made with magnets!" with vpunch
    pause .5

    show reed unimpressed flip with Dissolve(.25)
    Re "But like{cps=*.1}...{/cps}{w=.5}{nw}"
    show reed explanatory flip
    extend "how do magnets work?"
    show reed neutral flip
    pause .5

    stop music fadeout 1
    pause 0.1

    play sound 'audio/effects/schoolBell.ogg'
    I "{cps=*20}{i}DING-{w=0.7}DONG {w=0.65}BING-{w=0.7}BONG{/i}{/cps}"
    pause 0.5
    play music 'audio/OST/Fuck You I Like To Shitpost.ogg' fadein 1.0
    stop sound fadeout 1

    "All at once all the students giving the clock a blank stare stand to attention and file out the door."
    pause .5

    show trish: #0.425
        linear 0.05 xalign 0.430
        linear 0.05 xalign 0.425
        repeat
    T "I{w=.2}-I{cps=*.1}...{/cps} {w=.75}{nw}"
    show trish annoyed:
        xalign 0.425
        easein 1 yalign -0.075
    extend "Damn it,{w=.1} Reed!"

    show trish:
        easein 0.5 yalign 0.0
    show trish unimpressed with dissolve
    pause .5

    show trish behind reed:
        easein_back 0.25 xalign 0.7
    pause .1
    play sound 'audio/effects/slapStickPunch.ogg'
    show reed:
        easein_cubic 0.25 xalign 1.325
        easein 0.5 xalign 1.3
    pause .5
    
    show trish unimpressed flip with Dissolve(.25)

    "Trish punches Reed in the shoulder,{w=.4} gives me another evil stare,{w=.4} and saunters out the room."
    pause .5

    show trish:
        easeout 1 xalign 1.5
    show trish unimpressed with Dissolve(.25)
    pause .25
    hide trish with dissolve
    pause .5

    show reed:
        ease_cubic 1.25 xalign 0.5
    pause .5
    show reed considering flip
    pause .5
    Re "Hey."

    "Reed pats me on the shoulder."
    pause .5

    show anon behind reed
    show reed:
        easein 0.5 xalign 0.55
    show reed happy flip with Dissolve(.25)
    Re "Bruh."

    show reed:
        easeout 1 xalign 1.5
    pause .5
    hide reed with Dissolve(.5)
    pause .5

    "He gives me a thumbs up and exits as well."

    "Leaving only the substitute teacher,{w=.4} looking at me from her desk impatiently for me to leave."
    pause .5

    stop music fadeout 3

    "Guess it’s her lunch period,{w=.2} too."

    show anon:
        easeout 1 xalign -0.9
    show anon neutral flip with Dissolve(.25)
    hide anon with dissolve
    pause .5

    scene black with fade

    "{cps=*.1}...{/cps}"

    # CH 3 SCENE 2 - I can't believe Naser is fucking dead

    play music 'audio/OST/The Top of the Social Ladder.ogg' fadein 2
    scene cafeteria
    show anon neutral at aleft
    show naomi neutral flip at scenter
    show naser unimpressed flip:
        yalign 0.1 xalign 1.1
    with Fade(0,.5,1.5)
    pause .5

    "Naser ended up dragging me to sit with him and the magenta motormouth again."

    "Naomi hovers over Naser,{w=.4} who currently has Gucci under his eyes."
    pause .5

    Nas "So,{w=.3} I uh{cps=*.1}...{/cps}{w=.3} Talked to the soccer team earlier."

    Nas "They’re going to make the first game after all."

    show naomi explanatory flip
    N "Isn’t that great,{w=.2} Anon?"
    show naomi neutral flip with Dissolve(.25)

    A "{cps=*.1}...{/cps}"

    show naser:
        ease 1.5 xalign 1.125
        ease 1.5 xalign 1.075
        repeat

    Nas "I also{cps=*.1}...{/cps}{w=.4} Got the L&L Club to finally take down their christmas decorations{cps=*.1}...{/cps}"

    Nas "So{cps=*.1}...{/cps}{w=.4} The library’s clean again{cps=*.1}...{/cps}"
    pause .5

    show naser:
        easeout_quart 1 yalign -0.15 xalign 1.05
    pause .5

    "Naser’s head lands in his chicken salad,{w=.4} then he jerks wide awake."

    show naomi behind anon:
        easein_cubic 0.5 xalign 0.45
    show naomi shocked with Dissolve(.25)
    pause .5
    show naomi:
        easein_cubic 0.5 xalign 0.55
    N "NASER!"

    show naser behind naomi:
        easein_elastic 0.5 yalign 0.1 xalign 1.2
    play sound 'audio/effects/slapstickBigPunch.ogg'
    show naser shocked flip with Dissolve(.1)
    with vpunch
    Nas "OH GOOD LORD NOT THE WATER-"
    pause .5

    A "{cps=*.1}...{/cps}"

    show naser sad flip with Dissolve(1)
    Nas "Ugh{cps=*.1}...{/cps}{w=.4} Sorry."

    show naomi sad with Dissolve(.25)
    pause .25

    show naser unimpressed flip with Dissolve(.25)
    Nas "{cps=*.1}...{/cps}Did you say something,{w=.2} Anon?"

    A "Naser,{w=.4} you look like you fell into another blender."

    show naomi behind naser:
        easein 0.75 xalign 0.6
    show naomi unimpressed flip with dissolve
    pause .5

    A "What’s going on,{w=.2} big guy?"
    pause .5

    Nas "Don’t worry about it{cps=*.1}...{/cps}"

    Nas "Just some{cps=*.1}...{/cps}{w=.3} Family problems last night{cps=*.1}...{/cps}"

    A "Like what?"
    pause .25

    show naser sad flip with Dissolve(.25)
    Nas "Ugh{cps=*.1}...{/cps}"

    show naomi considering flip with Dissolve(.25)
    N "You don’t have to tell him if you don’t want to,{w=.2} dear."

    show naomi:
        easein 0.5 xalign 0.58
    show naomi happy with Dissolve(.25)
    N "Why don’t you wipe that alfredo sauce off your cute little face."

    "She’s so saccharine she’d give a third world country diabetes"
    pause .5

    Nas "It’s my sister again{cps=*.1}...{/cps}"

    "Why is it always his sister with him?"

    show naomi sad with dissolve
    N "Aww{cps=*.1}...{/cps}"

    Nas "I was going to sleep last night,{w=.3} when I heard something downstairs."

    "{cps=*.1}...{/cps}When did this turn into an interrogation?"

    show naser unimpressed flip with Dissolve(.25)
    Nas "It was about one or two in the morning.{w=.5} I checked what it was,{w=.3} and{cps=*.1}...{/cps}"

    show naser sad flip with Dissolve(.25)
    Nas "Fang was just,{w=.5} standing in front of the microwave."

    show naomi unimpressed with Dissolve(.25)
    Nas "Staring at the dino nuggets rotate inside."
    pause .5

    "At one in the morning?"
    pause .5

    Nas "At one in the morning."

    show naomi sad with Dissolve(.25)
    N "This is a personal issue,{w=.4} isn’t it?"

    show naomi neutral with Dissolve(.25)
    N "Wouldn’t you rather just be {nw}"
    show naomi:
        ease 0.25 yalign 0.05
        ease 0.25 yalign 0.0
    extend "enjoying lunch with us?"
    pause .5

    Nas "I just need advice from someone at this point,{w=.4} Naomi."

    show naomi considering with Dissolve(.25)
    N "But from Anon?"

    A "But from me?"

    "Naser continues."

    Nas "I asked her what she was doing,{w=.4} and she just{cps=*.1}...{/cps}"

    show naser unimpressed flip
    Nas "Just says 'fuck off...',{w=.4} so I think 'maybe dad will help'."

    show naser sad flip
    Nas "{cps=*.1}...{/cps}He didn’t."

    Nas "{cps=*.1}...{/cps}They just got into a shouting match."

    Nas "Screamin’ bout her lack of control an’ dad was pissed an’-"

    show naser behind naomi
    show naomi:
        easein_cubic 1 xalign 0.675
    show naomi sad with Dissolve(.25)
    N "Poor baby."

    "Naomi wraps her arms around Naser’s head,{w=.4} cradling the tired pterosaur in her bosom."

    show naser unimpressed flip with dissolve
    show naser:
        easeout_quart 1 xalign 1.3 yalign -0.3
    pause .5
    hide naser with dissolve
    play sound 'audio/effects/anonHeadbutt.ogg' 
    with vpunch

    "There’s a rumbling snore and it’s clear that Naser has checked out."

    A "{cps=*.1}...{/cps}{cps=*.5}Riiiiiiiight{/cps}{cps=*.1}...{/cps}"
    pause .5

    "Naomi looks distraught."

    N "He’s always like this{cps=*.1}...{/cps}"

    N "But it’s been getting worse recently{cps=*.1}...{/cps}"
    pause .5

    A "Going unconscious?"

    show naomi considering flip with Dissolve(.25)
    N "Trying to help.{w=.5} Wearing himself ragged."

    show naomi unimpressed flip with dissolve
    N "That Fang{cps=*.1}...{/cps}"
    pause .5

    show naomi sad flip with Dissolve(.25)
    N "We should help Naser."

    A "What,{w=.4} by talking to Fang?"

    N "By taking him to the nurses office."
    pause .5

    "Ah fuck."

    show dimmer_darker behind anon, naomi:
        alpha 0.0
        linear 2.5 alpha 1
    
    show naomi:
        easein 2 xalign 0.625
    pause .25

    "Naomi looks at me with the biggest,{w=.4} wettest doe eyes possible."

    hide dimmer_darker with Dissolve(.2)

    A "Alright alright.{w=.4} He doesn’t look that heavy anyway."

    N "Only a hundred and sixty pounds."

    A "How do you-{w=.4} nevermind."

    scene black with fade

    "Naomi puts herself under Naser’s left arm,{w=.4} motioning me to take the other one."

    "I sling his arm around my back and-"

    play sound 'audio/effects/slapstickPunch.ogg'
    "GOOD LORD HE’S HEAVY." with vpunch
    pause .5

    N "Alright,{w=.4} the Nurses’ Office is down the main hall on the left side,{w=.4} near the front desk."

    stop music fadeout 1.0

    "I’m clenching my face too much to be able to speak,{w=.4} I can only get a slight nod out."

    "{cps=*.1}...{/cps}"
    pause .5

    # CH 3 SCENE 3 - Steganography

    play ambient 'audio/effects/school loop.ogg' fadein 2
    scene hallway with fade
    pause .5

    "After dropping Naser at the nurse and leaving before Naomi could argue with her about staying,{w=.4} the lunch bell rings."

    "With music at the ass end of the campus I have to sprint through the halls."

    "Fuck today,{w=.4} I avoided gym class for a reason."
    pause .5

    "Halfway to Music class,{w=.4} I slam into somebody and tumble to the floor."

    stop ambient fadeout 2
    play sound 'audio/effects/slapstickBigPunch.ogg' 
    scene black with Fade(.1, 0, .25, color="#fff")
    pause .5
    play sound 'audio/effects/anonHeadbutt.ogg'
    pause 1

    A "Augh{cps=*.1}...{/cps}"
    pause 1

    play music 'audio/OST/Dino Destiny Reader.ogg'

    scene hallway 
    show stella neutral:
        yalign 0.1 xalign 0.25
    with Dissolve(3)
    pause .5

    unknown "{cps=*.2}You...{/cps}"

    play sound 'audio/effects/slapstickPunch.ogg' 
    A "AH!" with vpunch

    "Sorry,{w=.3} sorry sorry!"
    pause .5

    show anon neutral flip:
        alpha 0
        yalign -0.2 xalign 0.75
    show anon:
        easein 0.5 yalign 0.1 alpha 1

    "I get up from the floor and look at the stego who bumped into me.{w=.5} The plates on her back twitch as she looks me up and down."

    unknown "{cps=*.3}Judgement{/cps}{cps=*.1}...{/cps}"

    show anon:
        easein 0.5 xalign 0.8
    pause .75

    "A chill rolls over me."

    show stella:
        easein 1 xalign 0.35
    show stella considering with Dissolve(.25)
    unknown "Karma?{w=.6} No.{w=.6} No,{w=.4} maybe second chance?"

    "She draws closer,{w=.4} a contemplative expression on her face."

    show stella explanatory with Dissolve(.25)
    unknown "Ah,{w=.4} I see now."
    show stella neutral with Dissolve(.25)
    pause .25

    A "What?"

    unknown "You’ve important choices to come."

    A "I do?{w=.5} Wait back up{w=.2} what the fuck are you talking about?"

    unknown "This."
    pause .25

    play sound 'audio/effects/whoosh.ogg'
    show stella:
        easein_cubic 0.35 xalign 0.425
        easein 0.5 xalign 0.35
    pause .75

    "She reaches toward my chest,{w=.4} plucking something off of it.{w=.6} She holds it up for me to see it’s some oversized playing card."
    pause .5

    A "Still lost."
    pause .25

    show stella explanatory with Dissolve(.25)
    unknown "It’s you.{w=.6} Your card.{w=.6} You are on the precipice of a great ordeal.{w=.6} Many difficult points of divergence and contention are coming your way.{w=.6} Reflect on them."
    show stella neutral with Dissolve(.25)

    "I think about asking the green weirdo to make sense,{w=.4} but the bell is about to ring."

    A "Yeah,{w=.3} thanks,{w=.3} sure.{w=.4} Sorry,{w=.1} gotta dash."
    pause .25

    show anon behind stella:
        easeout 1 xalign 0.0
    pause .5
    hide anon with dissolve
    show stella considering with Dissolve(.25)
    pause .5

    # CH 3 SCENE 4 - It's almost Shakespearean

    stop music fadeout 2
    scene bandroom with Fade(1,0,1)

    "I slam into the band room door just as the late bell trills,{w=.4} panting and sweaty."

    show jingo at sleft with Dissolve(1)

    jingo "Good timing,{w=.3} Mr. Mous.{w=.4} Just in time for free period."
    pause .5

    "What{cps=*.1}...{/cps}"

    jingo "Take up anything you like and have fun."
    pause .25

    show jingo:
        easeout 1 xalign -0.5
    pause .25
    hide jingo with dissolve

    "The teacher then took to his extremely lavish loveseat,{w=.4} threw on a pair of headphones and blacked out."
    pause .5

    "I looked at the scattered instruments,{w=.3} left alone for whatever reason."

    "Dent looking brass and cracked woodwinds.{w=.4} Even a bass with a missing string."

    "Wow.{w=.5} I feel like that right about now."
    pause .5

    "I reach for one at random,{w=.4} taking a wooden{cps=*.1}...{/cps}{w=.3} thing{cps=*.1}...{/cps}"

    "It looks like an oak tree made love to an eggplant and this is the aborted monstrosity in Mexico."
    pause .5

    "Whatever,{w=.4} I melt into my chair and pull out my phone.{w=.5} Seems a majority of my classmates have a similar idea."

    "I’ve some shitposting to do."

    "Let’s see{cps=*.1}...{/cps}"
    pause .5

    show anonphone with easeinbottom

    # TODO: phone overlay with Elliot Raptor, and the text ‘he made some valid points :^)’

    "Ah yes,{w=.4} perfect.{w=.6} Click post {cps=*.3}aaaand{/cps} now to wait."
    pause .5
    
    hide anonphone with easeoutbottom

    "Nefarious deed for the day done,{w=.4} I look around the room out of boredom."
    pause .5

    "Oh fuck no."
    
    "Fang has a weapon of mass hearing loss."

    "I’m covering my ears in preparation when the ptero-rist starts strumming and{cps=*.1}...{/cps}"
    pause .5

    play music 'audio/OST/Beach Chill Out.ogg'

    "Oh wow."

    "I still have my hearing."
    pause .5

    "In fact she’s actually playing something pleasant."
    pause .5

    "It’s mellow.{w=.5} Relaxed.{w=.6} A slow rhythm that carries a strange nostalgic hint to it."

    "The difference between this and the performance is night and day."
    pause .5

    "What gives?"
    pause .5

    "Looking a bit closer,{w=.4} she’s swinging her tail a bit to the rhythm."

    "She uses her tail as a metronome?"
    pause .5

    "Suddenly,{w=.3} the phone slips from my hand onto the floor."

    stop music fadeout .25
    play sound 'audio/effects/slapstickPunch.ogg'
    A "SHIT!" with vpunch

    "The sound it makes as it clatters on the ground is a klaxon of pants-shitting terror."

    "It lies face down on the isle."
    pause .5

    "Do I really want to pick it up and potentially face a harsh reality?"

    "Schrodingers’ crack."

    "{cps=*.1}...{/cps}I can’t just leave it there."
    pause .5

    "I pick up the phone and slowly turn it over."

    "It’s the moment of truth."
    pause .5

    "{cps=*.1}...{/cps}No cracks?"
    pause .5

    play music 'audio/OST/Fuck You I Like This Chick.ogg'
    "Thank the Lord."

    show fang happy at scenter with Dissolve(1)

    F "Yeah,{w=.3} you got lucky."
    pause .5

    "Fang has stopped playing and is throwing a small smirk my way."
    pause .5

    "I should probably say something{cps=*.1}...{/cps}"

    "Her playing is pretty good,{w=.4} I'll compliment that."
    pause .5

    A "That sounded way better than in the video Reed took."

    show fang unimpressed with Dissolve(.25)

    "{cps=*.1}...{/cps}"

    "Wrong choice of words."

    show fang angry
    F "You’re still not off my shit list,{w=.4} watch it."

    "Quick Anon,{w=.3} think."
    pause .5

    A "Why didn’t you play guitar back then,{w=.4} you’re obviously a lot better with it."

    show fang considering with Dissolve(.25)
    F "Would’ve if I could’ve."
    pause .5

    A "What do you mean?"
    pause .5

    "There’s an empty seat next to Fang."

    "Finders’ keepers,{w=.4} I guess."

    show anon neutral flip:
        alpha 0
        yalign 0.1 xalign 1.2
    show anon:
        easein 1.5 xalign 0.775 alpha 1
    show fang:
        easein 1.5 xalign 0.1
    pause 1

    show fang neutral with Dissolve(.25)
    F "The band is just Reed,{w=.2} Trish,{w=.2} and I."

    F "So we all have to decide by majority what happens."

    F "Reed says using a bass is more unique,{w=.4} and Trish always says how it’s a ‘promising business model’."

    A "But it sounds like you play the guitar much easier than a bass."

    show fang considering with Dissolve(.25)
    F "I play the bass just fine."

    show fang neutral with Dissolve(.25)
    F "I think the problem is more that if you want to make an unconventional band layout,{w=.5} you damn well better know what you’re doing."

    F "If you’re anything short of masterful it won’t sound good."

    F "And when it comes to music,{w=.4} it either sounds good or it doesn’t."

    F "Simple as."

    "She continues strumming."
    pause .5

    A "But it’s just a high school band,{w=.4} right?"

    A "Shouldn’t it just be fun?"

    F "It is,{w=.4} yeah."

    A "Even though you’re just doing what they want without getting a say in it?"
    
    play sound 'audio/effects/badA.ogg'
    show fang angry with Dissolve(.25)
    "Fang flinches and misses a note."
    pause .5

    F "{cps=*.1}...{/cps}"

    show fang neutral with Dissolve(.25)
    F "It’s not like that{cps=*.1}...{/cps}"

    F "It’s just{cps=*.1}...{/cps}{w=.3} Trish says{cps=*.1}...{/cps}{w=.3} {nw}"
    show fang considering
    extend "I mean{cps=*.1}...{/cps}{w=.2} God damn it."
    pause .5

    show fang neutral with Dissolve(.25)
    F "Look,{w=.4} we’re better with two basses.{w=.6} Trish and Reed say so."
    pause .5

    A "The au--"

    stop music fadeout 0.1

    "Uhp"

    "Fuck"
    pause .5

    "I almost said 'the audience at the concert' to her out loud."

    show fang unimpressed with Dissolve(.25)
    F "What was that?"
    pause .5

    play music 'audio/OST/fighter.ogg' fadein 1.0
    A "{cps=*.2}Nuthin’{/cps}"

    show fang angry with Dissolve(.25)
    "Fang growls at that."
    pause .5

    show fang considering with Dissolve(.25)
    F "You know what,{w=.4} we’re having band practice after school today."

    show fang neutral
    F "Just show up and see for yourself."
    pause .5

    A "And what if I don’t?"

    show fang happy with Dissolve(.25)
    F "You’ll be a little bitch that’s wrong."
    pause .5

    "Oh."

    "In that case."

    A "Fuck you,{w=.4} I’m right,{w=.4} your band sucks with two basses,{w=.6} {nw}"
    show fang unimpressed
    extend "and you shoulda been on guitar!"

    "I lock eyes with her."
    pause .5

    show fang:
        easein_cubic 0.5 xalign 0.0025
    F "Fuck you!"
    pause .5

    show anon behind fang:
        easein_quart 0.5 xalign 0.725
    A "Fuck you!"

    show fang:
        easein_quart 0.5 xalign 0.1
    show fang angry
    F "Fuck!{w=.4} {nw}"
    show fang:
        easein_quart 0.5 xalign 0.2
    extend "You!"

    show anon:
        easein_back 0.5 xalign 1.1
    pause .15
    play sound 'audio/effects/slapstickPunch.ogg'
    show anon angry flip
    A "FUCK YOU!" with vpunch

    show jingo at sleft with dissolve
    stop music fadeout 3

    jingo "{cps=*.2}Aaaaand{/cps} we’re {cps=*.15}caaaaaalm{/cps} now."

    show anon neutral flip
    show fang unimpressed
    with Dissolve(1)
    pause .5

    "Fuck me."

    "{cps=*.1}...{/cps}"

    # CH3 SCENE 5 -

    play music 'audio/OST/Appreciating the Atmosphere.ogg' fadein 2
    scene hallway with Fade(1, 0, 1)
    pause .5

    F "Hurry up, dweeb. If I can keep ahead of you while carrying two instruments, you can speedwalk."

    A "You sure you don’t want me to carry one?"

    F "Pfeh."

    "Fang is leading me back to the auditorium with both the acoustic guitar ‘borrowed’ from the music room and her bass in hand, one over each shoulder."

    # TODO: SCENE auditorium doors

    "When we eventually get to the auditorium, Fang stops."

    "Is something wrong?"

    A "Uh, is everything-"

    F "The doors, moron."

    "She swings the guitar cases on her shoulders around a bit."

    "Oh."

    "I step around her and grab the handle, pulling the door wide open."

    A "Ladies first."

    "Fang growls and stomps on my foot as she walks past."

    "..."

    A "FUCK!"

    F "Hurry up already."

    scene auditorium
    show reed neutral flip at rright
    show trish neutral at tcenter
    "Inside, Reed and Trish already have everything set up onstage."
    show fang neutral with moveinleft:
        xalign 0.2 yalign 0.1
    show anon neutral with moveinleft:
        xalign -0.1 yalign 0.0
    "Where does Reed keep that huge drumset during the day?"
    show trish very happy flip with dissolve
    "Trish waves her arms from the stage."
    T "HEY, FANG! WHAT TOOK SO LONG?"
    F "HAD TO GRAB SOMETHING."
    show trish unimpressed
    "Trish squints in the spotlight, then finally notices me."
    show trish indignant

    # TODO: Punk revamp?

    T "What-"
    T "What’s he doing here?!"
    "Fang slings both cases onto the stage, then climbs on herself."
    F "Proving a dumbass bigot wrong."
    A "So you admit there’s smart ones?"
    show fang angry
    show jewlcase at truecenter:
       xalign 0.5 yalign 0.5 zoom 0.3
       rotate 0.6
       linear 0.3 xalign 0.05 yalign 0.12
       linear 1.5 yalign 5.0
    "Fang then ripped something from Trish’s hands and threw it at me."
    show trish angry
    T "What the fuck?!"
    "It strikes against my head with a dull *tonk* and lands on the ground in front of me."
    show jewlcase at truecenter:
       xalign 0.5 yalign 0.5 zoom 1.0
    "Looking down at the makeshift shuriken, it was a copy of 'VVORM DRAMA’s new hit single Indragon Onslaught'"
    hide jewlcase
    show trish indignant
    T "Fang! I just made that in art class!"
    A "It looks like picasso had a seizure."
    show fang considering
    F "He was being an ass!"
    A "I was."
    show reed explanatory flip
    Re "Like… are we on break now?"
    T "We haven’t even started!"
    show reed neutral flip
    T "Fang! Why is Anon here?!"
    show fang neutral
    F "Like I said, proving him wrong."
    A "More like proving me right."
    T "Proving him wrong how?"
    Re "Like… Playing guitar, right? Ya wanted to play your guitar…"
    T "What?"
    F "Yes! I mean-"
    A "Ha!"
    F "No, I mean Anon thinks that if I used a guitar instead of bass the music would sound better."
    show trish neutral
    T "What? No wayyyy."
    F "I know, right?"
    Re "Woooow… Way to try throwing everything off, Anon..."
    F "Mm. Let’s just go through ‘I Need Meth Money By Tuesday Night And If I Don’t Get It I Will Stomp On Your Child’."
    "Don’t say ayy lmao."
    F "Three… Two... One.."

    #half life flash bang
    # TODO: stop music
    # TODO: flash, black and tinnitus?

    scene black
    pause 5
    "My mind went blank."
    "I don’t know what happened during the time when it was blank"
    scene bandroom
    show trish neutral at tleft


    play music 'audio/OST/The Hunt for more (You)s.ogg'

    "I look to the stage and see Fang, panting, looking distressed."
    F "S-see? Totally awesome, r-right?"
    "Not the word I would use."
    show trish explanatory with moveinright:
        xalign -0.2 yalign 0.1
    show anon neutral with dissolve:
        xalign 0.3 yalign 0.1
    show reed neutral flip with dissolve:
        xalign 0.9 yalign 0.1
    show fang neutral flip with dissolve:
        xalign 1.6 yalign 0.1
    A "...I think you should give the guitar a try."
    show trish angry
    T "Oh shut up, you don’t know anything about music."
    F "Might as well. That’s what I brought him for, after all."
    T "You’re really siding with him on this?"
    T "We already decided VVURM DRAMA is better with only drum and bass, remember?"
    show reed explanatory flip
    Re "Yeah man… WAY more unique that way."
    A "Aren’t there like two bands in existence that pulled it off?"
    Re "That means there’s a chance then, yeah…?"
    A "It can’t hurt to try, right?"
    show reed neutral flip
    show trish angry
    T "You don’t get a say in this, it’s a band decision and we already made our choice."
    F "Maybe he’s right, Trish. What’s the big deal?"
    T "The ‘deal’ is we’re wasting enough time as it is when we should be practicing!"
    T "Especially wasting time on playing guitar when it doesn’t match any of our stuff."
    show fang angry flip
    "That clearly struck a nerve."
    F "‘Wasting time’ playing guitar? What’s THAT supposed to mean?"
    "Fang rounds on Trish, jabbing an accusing finger into the little triceratop’s surprisingly voluminous chest."
    F "Every time I want to make changes you guys always overrule me!"
    F "Even when it’s something like playing my favorite instrument in my own band!"
    "Yikes."
    show trish indignant
    T "Come on Fang, you know I didn’t mean it that way!"
    T "We decided that democratically, right Reed?"
    Re "Yeah, but… like, there are only three of us, y’know?"
    "I’ll hate myself for this…"
    "...this is already getting too intimate for me..."
    "...but maybe I should say something."
    "It’s only going to get worse if I don’t"
    "But this seems like a personal argument between them."

    menu:
        "Speak Up":
            jump GuitarQuestionSpeakUp
        "Stay Silent":
            jump GuitarQuestionStaySilent

    label GuitarQuestionSpeakUp:
    $ fangscore += 1
    "Fang does seem very passionate about playing guitar."
    "It could only help their music, right?"
    show trish unimpressed
    show fang surprised
    A "Just give Fang a chance, have you ever even let them play guitar with the band?"
    "That seemed to stop Trish in her presidential yeezys."
    show trish neutral
    T "I- uh, well… not really. We voted on it in our first jam session together."
    "Fang made a weird face, like she couldn’t believe I was standing up for her."
    "Honestly I couldn’t believe I stood up for her either."
    "But god dammit I’m winning this challenge!"
    A "If you’re really Fang’s friend, you should at least let them try."
    "..."
    "Trish’s mouth opened and closed, as if she was trying to find the right words."
    "She threw up her hands and let out a frustrated sigh."
    show trish unimpressed
    T "Fine, I guess we can try it with the guitar…"
    jump postguitarscene

    label GuitarQuestionStaySilent:
    "Can’t guarantee their style won’t be better than dogshit if I lose this challenge."
    "Certainly can’t get worse."
    "This is between the members of the band."
    T "In the end, majority still rules."
    T "I’m sorry, Fang, but we can’t get into creative squabbles like this all the time."
    T "And you already agreed to it, right?"
    "How controlling."
    show fang sad flip with dissolve
    "Fang hangs her head in defeat."
    F "I guess so…"
    Re "Hey man, Fang… Don’t let it get to you so hard…"
    show reed explanatory:
        xalign 0.7 yalign 0.1
    Re "We just gotta get it out of your system’s all, right...?"
    Re "Like, y’know, get it all out now so you don’t have to later, yeah…?"
    Re "Like Trish said…"
    T "I never said that."
    Re "Cuz’, that’s how these things work, right? You know until you don’t, and then all the rest is wack."
    T "I… Guess?"
    T "What?"
    Re "It’s like the bigger picture, you got Fang playin’ bass with all us…"
    Re "And they’re all ‘ohh yeah good thing I’m not thinking about playing other instruments, yeah yeah,’"
    Re "And you’re all like ‘see, I told you so’..."
    T "Yeah, so we should let them play now to get it all out for later!"
    T "Wait…"
    "If there were any cameras rolling, they’d be zooming in on Trish’s face."
    F "Thanks, Reed."
    show trish unimpressed
    T "Yeah, thanks a lot."
    jump postguitarscene


    label postguitarscene:

    F "Alright, this time we’re doing I Gave The Special Kids The Jonestown Special And Now I’m Going To Jail!"
    "...I’m gonna need Raptor Jesus after this one..."
    F "And a three, two, and…"


    play music 'audio/OST/That Almost Sounded Good.ogg'

    "Opposed to the nostalgic tune earlier, Fang rapidly strums on her borrowed guitar."
    "It’s fast and rough but the tone carried doesn’t melt my eardrums."
    "Watching and listening now I can see and hear the difference clear as day."
    "They’re actually not bad."
    "Not good, not by any metric worth it’s weight."
    "But at least I don’t cringe so hard my spleen erupts from my side and creates a splash zone."
    "I find myself bobbing to the song, in fact."
    stop music fadeout 1.0
    "And just as I consider the song ‘gittin’ gud’ it ends."
    "I feel a little disappointed that the show ended so soon."
    "Then I remember it’s not a show at all."

    # TODO: play bayside revamp?
    play music 'audio/OST/Bayside Bumming it.ogg'

    "And that I definitely won."
    "There’s sweat dripping from Fang’s brow, and her black clothes are clinging to her a bit more tightly."
    "The grin on her face stands out the most though."
    F "See! Totally better with a guitar Trish!"
    A "Ha! I win!"
    "Trish, Reed, and Fang turn to look at me."
    F "Oh… OH! OH GOD DAMN IT!"
    A "So you’re now a normal band?"
    F "I mean…"
    "Trish scowls."
    T "A vote then. Who votes if we stick to drum and bass?"
    "She’s the only one to raise her hand."
    T "fff… And against?"
    "Even I raise my hands along with Reed and Fang."
    T "You stay out of this Skinnie!"
    A "Skinnie?"
    F "Yessss!"
    Re "So like… do we gotta redo all the songs?"
    F "It’s only one instrument line."
    F "Shouldn’t take too long."
    T "Ugh…"
    T "There goes our main marketing strategy."
    "Marketing strategy? I thought she was a triceratops, not a rhinorex."
    "I’m abusing my good luck here so I probably should leave."
    A "That was very fun you guys, I hope I can see you all play more...again...better now than it was before...uuuhhhh…."
    A "We’re cool right? Bye!"
    A "So uh… I guess I should go now?"
    "As I move to the door Fang calls out."
    F "Wait!"
    F "We uh…"

    # TODO: play appreciating the moment?
    play music 'audio/OST/Appreciating the Atmosphere.ogg'

    "I look to see her fidgeting onstage."
    F "We couuuld uh… OH! Feedback! We could use your feedback!"
    T "We what?! Fang, from him!"
    Re "Like... He’s alright but… like, for real?"
    A "Wha-"
    F "He’s been helpful! So why not? Reed, back me up here."
    Re "mmmm… Kay… Anon should stay…"
    show trish indignant
    T "REALLY?! BUT-"
    show trish unimpressed
    show fang happy flip
    F "Anon, you’ll stick around a while, right?"

    A "If you guys’ll order some Dino-moe’s, sure."

    "The three of them just stare blankly."

    "Wait. Auditorium. Pizza."

    "Fuck."

    # TODO: play fighter?

    "Ohfuckohshitfortheloveofallthatisholywhynow."

    A "I-I mean, uhh…"

    A "Actually, I have to go. Like, right now. So... Bye."

    F "Why? I can spring for pizza if you’re too broke."

    A "Nah nah nah, no need."

    A "Plus I just remembered, I have to do uh...important things."

    F "More important than our music?"

    A "Err, yeah. See I have to go return a blu- a book!"

    "Fucking hell mouth, don’t go slipping weebtalk now!"

    A "See it’s WAAAAY overdue and I can NOT afford the late fee."

    Re "Wait a minute…"

    "?"

    "I almost didn’t recognize Reed’s voice, he said that way too sharply"

    Re "...the late date is like...two weeks...Are you up to something, Anon?"

    "He sounds completely lucid and didn’t slur any words…"

    "Oh no."

    "SHUT IT DOWN"

    "SHUT IT DOWN"

    "THE PINK CUBONE KNOWS"

    A "It’s from the library near my place. Suuuper strict. Y’know how public libraries are like."

    Re "riiiiiight."

    T "WILL YOU JUST FUCKING LEAVE ALREADY?"

    "I love you, Trish."

    A "sure, bye."

    "I scramble away to the exit. I turn to make my way out of there, on the stage I hear…"

    T "THANK YOU."

    "I uh….hear them chattering…"
    F "Okay now how about ‘I’m Not Sure Why But The Burglar Joined My Threesome."
    "Don’t think about a Threesome with Trish and Fang, Don’t think about a threesome with Trish and Fang, they’re meteor dodgers for crying out loud!"
    "..."
    "Ok, just for one second"
    if persistent.lewd == True:
       scene lesbo with fade
       pause 20.00
       scene black with fade

    "Fuck."
    "..."

    return