# Chicxulub Gutterlane

label chapter_x1:

    stop music fadeout(3)
    scene black with Dissolve(2)
    pause 1
    play music 'audio/ost/prized bowling shoes.ogg' fadein 0.2

    "It’s a cool autumn’s evening and for some reason I’m squeezed in a car against Moe and Naser."

    "Fang’s dad was driving, and the passenger seat was taken up by a tote bag holding the family's ancient bowling balls."
    pause .5

    "Every time he looked in the rear view mirror I swear his gaze lingered on me for just a second before returning to the road."

    "The only consolation is that if I don’t live to see the next day, it wouldn’t be because he didn’t have his priorities straight while on the road."
    pause .5

    "The drive couldn’t have lasted for more than fifteen minutes, but it felt like a good couple of hours."
    window hide
    window auto
    pause .5

    scene parkinglot with Fade(1, 0, 1)
    pause .5

    "When we finally pulled into the parking lot, I step out to stretch my legs while Moe and Naser continued to catch up."
    window hide
    window auto
    pause .5

    show anon neutral:
        yalign 0.1 xalign -0.4
    show anon:
        easein_cubic 1 xalign 0.2
    with dissolve
    pause .5

    "Naser was having a blast listening about how Fang and VVURM DRAMA knocked it out of the park at Moe’s."

    "Moe was even wearing the apron Trish sold him to our little gathering."

    show anon neutral flip with dissolve

    A "Uhh{cps=*.1}...{/cps} Moe, why are you wearing that outside, miles away from the restaurant kitchen?"
    window hide
    window auto
    pause .5

    show moe alt flip:
        yalign 0.0 xalign -1.0
    show moe:
        easein_cubic 1 xalign -0.6
    with dissolve
    pause .5

    Moe "It’sa part o’ ma look, if I ain’ts wearin’ an apron I jus’ don’t feel right."
    window hide
    window auto
    pause .5

    show fangdad neutral behind anon:
        yalign 0.1 xalign -0.1
    show fangdad:
        easein_cubic 1 xalign 0.7
    with dissolve
    pause 1

    FD "Well, folks, we’re here."

    show anon neutral with dissolve

    FD "Black Hole Bowling."
    pause .5

    Moe "It’s been a while, why ole’ Rip n’ me used ta come ’ere err’y weekend when we was your age."

    FD "And with my weekend off I figured I’d take the next generation for a game or two."
    window hide
    window auto
    pause .5

    show naser considering behind fangdad:
        yalign 0.1 xalign 0.5
    show naser:
        easein_cubic 1 xalign 1.7
    with dissolve
    pause .5

    Nas "Surprised you brought Anon along, Dad."

    Nas "That’s pretty unlike you."

    show fangdad unimpressed with Dissolve(.25)
    FD "It {i}was{/i} just going to be the three of us{cps=*.1}...{/cps}"

    FD "But the {i}missus{/i} thought it would be a {i}grand{/i} idea for him to come along."
    pause .5

    "Moe made an odd hand motion with his tiny limbs."

    "It only made sense when he added a whip crack sound with it."
    pause .5

    FD "Quiet you. I’d have your ass in bars before you’d even know it."

    Moe "We both knows ya won’t. C’mon kids, ole Moe needs the extra hands to git on his lucky shoes."
    window hide
    window auto
    pause .5

    show moe:
        easeout 1 xalign 1.0
    pause .5
    hide moe with dissolve
    pause .5

    show fangdad:
        easeout 1 xalign 1.0
    pause .5
    hide fangdad with dissolve
    pause .5

    "I ended up having to carry the tote bag of bowling balls inside."

    show naser happy flip with dissolve
    Nas "You’re not going to make a {i}cripple{/i} carry all those, right?"
    window hide
    window auto

    show naser:
        easeout_cubic 1 xalign 2.5
    pause .5
    hide naser with dissolve
    pause .5

    show anon unimpressed with Dissolve(.25)
    "Struggling to not fall over or snap in half like a skin-colored twig, I lugged the bag over."
    window hide
    window auto
    pause .5

    show anon:
        easeout_cubic 1 xalign 1.0
    pause .5
    hide anon with dissolve
    pause .5

    scene bowlingalley with Fade(1, 0, 1)
    pause .5

    "After we got a lane and I placed the balls on the rack, Fangs’ father and I sat in the benches while Naser and Moe went to get some snacks."

    "I slouch back in my seat and rest my eyes a bit."
    pause .5

    "Man, those bowling balls were heavy."

    "We parked pretty far away, too, so I had to carry them a good quarter mile or so."

    "At least the benches here are clean."
    window hide
    window auto
    pause .5

    show fangdad neutral:
        yalign 0.2 xalign 0.75
    show anon neutral:
        yalign 0.1 xalign 0.2
    with Dissolve(1)
    pause .5

    "Sitting here with{cps=*.1}...{/cps}"

    "Fang’s father{cps=*.1}...{/cps}"
    pause .5

    "Alone."

    show fangdad neutral flip with dissolve
    "My eyes widen as Mister Aaron and I face each other."

    show fangdad happy flip with dissolve
    "I feel my blood turn to ice as a look of malevolent glee spreads across his face."

    FD "So, Anon{cps=*.1}...{/cps}"

    FD "We haven’t had a real heart-to-heart yet, have we?"

    A "Haha, really? We’ve spoken before back at your house, haven’t we sir?"

    FD "True, but here we can really have some good ol’ Man Talk, you know?"

    A "I-I see."
    pause .5

    "Fang’s Mother isn’t here, and Moe’s probably dropped his order twice already."

    "Please come back soon."

    FD "You been getting along well with everyone so far, huh?"

    FD "Dear Lucy, Naser. Even my old buddy Moe."

    FD "Hear you’re a fast learner in his kitchen."

    "I swallow hard as I manage a nod."

    "The inside of my mouth felt like the center of the Sahara while my shirt was practically glued to my back from my sweat."
    pause .5

    FD "You know I do actually know a bit about humans, I do."

    FD "In my line of work you need to deal with all types, you know."

    FD "I read this {cps=*.4}{i}reeeeaaaal{/i}{/cps} interesting thing the other day."
    pause .5

    FD "Apparently, dinosaurs and humans have a different amount of bones."

    FD "Makes sense when you think about it, but I guess it never occurred to me."

    A "Uh, y-y-yeah. It k-k-kinda does, doesn’t it?"

    FD "Anyways, the article goes real in-depth about it."

    FD "Do you know the minimum number of bones a human needs to survive?"
    pause .5

    FD "I do. Real nifty piece of information, right?"
    pause .5

    A "Ye-yeah, pretty cool!"
    pause .5

    "He holds up a hand and points to his wrist."

    FD "So apparently, absolutely none of these are vital to-"

    show naser neutral:
        yalign 0.1 xalign -1.0
    show naser:
        easein_cubic 1 xalign -0.7
    with dissolve

    Nas "Here you go Anon."

    "Naser drops a pair of old shoes into my lap."

    show naser unimpressed with Dissolve(.25)
    Nas "I asked for caveman size, but this was all they had, sorry."

    "Thank you Naser, thank you! If these weren’t rentals I’d enshrine them in my home and pay them respect every day for the rest of my life."

    show naser neutral with Dissolve(.25)
    Nas "What’re you guys up to?"

    show moealt:
        yalign 0.1 xalign 2.3
    show moealt:
        easein_cubic 1 xalign 1.7
    with dissolve

    Moe "Terrorizin’ the poor kid, I bet."

    "Moe sets a tray of fountain drinks and snack foods on the table with his grabby claw hands."

    Moe "Ya know, Rip, jus cause yer in-law made ya piss yer britches don’t means ya gots ta do the same ta the kid."

    show fangdad neutral flip with Dissolve(.25)
    FD "No clue what you’re talking about."

    Moe "Sure, Rip, sure."

    show fangdad unimpressed flip with Dissolve(.25)
    FD "Let’s just play already."
    pause .5

    "Eager to escape his clutches I bolted for the console and started entering our names."
    window hide
    window auto

    show anon:
        easeout_cubic 1 xalign -0.5
    pause .25
    show anon neutral flip with Dissolve(.25)
    hide anon with dissolve
    pause .5

    scene black with Dissolve(1)
    pause .5

    "Fang’s dad was up first, and for some reason his solid flesh-tone ball seemed a lot newer than the others."
    window hide
    window auto
    pause .5

    scene bowlingalley
    show fangdad neutral:
        yalign 0.1 xalign 0.0
    with Dissolve(1)

    "He made a show of inserting his clawed fingers into each of the holes while making sure I had a real good angle."

    "He even oriented the ball so that the holes lined up into a little screaming face."
    window hide
    window auto
    pause .5

    show fangdad:
        easeout_back 0.5 xalign 0.5
        easein_quart 1 xalign 0.8
    pause .25
    play sound 'audio/effects/whoosh.ogg'
    queue sound 'audio/effects/strike.ogg'

    pause 2.5
    show fangdad happy with Dissolve(.25)

    Nas "Wow pops, another strike!"

    FD "S’all in the form, Naser."

    show fangdad neutral flip with dissolve
    FD "If ya picture the pins as something you {i}really{/i} despise{cps=*.1}...{/cps}"

    "His eyes linger on me for a moment."
    pause .5

    FD "You can put some real force into it and {w=.2}{nw}"
    show fangdad:
        easein_back 0.75 xalign 0.7
    extend "{i}BAM{/i}."
    pause .5

    "I think I just made bam in my pants."
    pause .5

    Moe "Sheesh Rip. Give it a break for a bit."

    "Yes. Maybe two bits even."
    window hide
    window auto

    show fangdad:
        easeout_cubic 1 xalign -0.4
    pause .5
    hide fangdad with dissolve
    pause .5

    Moe "Alrights Anon, yer up."

    "I nod and get up from my seat."
    window hide
    window auto
    pause .5

    show anon neutral:
        yalign 0.1 xalign -0.2
    show anon:
        easein_cubic 1 xalign 0.2
    with dissolve
    pause .5

    "The ball I’ve got is borrowed from the bowling lane, it’s logo making creative use of the finger holes."

    "A shame the only one they had left was a size too small and my fingers barely fit."
    pause .5

    "I heft the smaller ball and take my cues from all my best attempts in Ninpebble Stick Bowling."

    "Lining up the shot I look down the lane at the pins."

    show anon pissed
    show dimmer_light behind anon
    with dissolve
    "Using Rip’s advice I picture Naomi’s face on the pins."

    "Sorry not sorry Naser."

    show anon:
        easein_cubic 1 xalign 0.1
        pause .25
        easein_cubic 1 xalign -0.2
    "With a big wind up that threatens to pull my arm from it’s socket I launch the ball."

    stop music fadeout 4
    "Right into the back of my foot."
    window hide
    window auto

    show anon:
        easeout_back 0.5 xalign 0.5
        easein_elastic 1 xalign 0.8
    pause .25
    play sound 'audio/effects/whoosh.ogg'
    pause .2
    play sound 'audio/effects/slapstickbigpunch.ogg'
    show anon fear
    with hpunch
    pause 1

    show anon:
        easein_elastic 1 xalign 0.3
    show anon foot with Dissolve(.25)
    A "SONOFAWHOREFUCKINGCUNT. "

    play sound 'audio/effects/slapstickpunch.ogg'
    extend "GODDAMNMOTHERFUCKINGSHIT. " with vpunch

    play music 'audio/ost/fuck you I like to shitpost.ogg'

    show anon:
        easein_elastic 1 xalign 0.5
    show white:
        alpha 0
        linear 0.1 alpha 1
        linear 0.4 alpha 0
    play sound 'audio/effects/slapsticksuperpunch.ogg'
    extend "FUUUUUUUUUUUUUUUUUUUUUUUUU-{nw}" with vpunch

    A "-UUUUUUUUUUUUUUUUUUUUUUUUUUUUUUUUUUUUUUUUUUUUUUUUUUUUUU-{nw}"

    A "-UUUUUUUUUUUUUUUUUUUUUUUUUUUUCKING SHITCUNTASSHOLEFUCK!"

    show anon:
        easein_cubic 0.25 yalign 0.2
        easeout_cubic 0.4 yalign 0.1
        repeat

    A "OF ALL THE MOTHERFUCKING BULLSHIT TO FUCKING HAPPEN IN MY GOD FORSAKEN LIFE HOW THE FUCK DOES THAT HAPPEN!"

    A "FUCKING LEAF EATER BALL FUCK MY LIFE OW GOD MOTHER FUCK DAMN!"

    A "WHAT THE FUCK IS THIS FUCKING TOM AND JERRY BULLSHIT HOW THE FUCK DOES THIS FUCKING HAPPEN!"

    A "DON’T JUST STAND THERE AND GAWK YOU JACKASSES GET A FUCKING FIRST AID BOX OR SOMETHING FOR FUCKS SAKE! YOU USELESS FUCKING ASSHOLES HOLY SHIT THIS HURTS LIKE HELL!"

    A "AAAAAA FUCK MY FUCKING FOOT I THINK I BROKE MY FUCKING FOOT!"

    show anon:
        easeout_cubic 0.4 yalign 0.1
    A "GOD DAAAAAAAAAAAAAAMN IIIIIIIIIIIIIIIIIIIIIIIT!"
    window hide
    window auto
    pause .5

    show anon:
        easein_cubic 1.5 xalign 0.7 yalign 0.1
    show anon sad
    hide dimmer_light
    with dissolve
    pause 1

    "When I finally stop to catch my breath I realize all eyes in the building are on me."

    "Naser has his phone set on me."

    "Even Fang’s father is staring with a dumbfounded look on his face."

    "I break out into a sweat again, eyes darting to find the nearest bathroom."
    pause .5

    "Moe gestures to Mister Ripley."

    Moe "That beats your record, don’t it?"

    "An attendant throws his hands in the air."

    Attendant "It does! It’s a new record!"
    pause .5

    "All at once all the patrons of the bowling alley burst into cheers and applause."

    show anon:
        easein_cubic 1 xalign 0.95
    show anon concerned flip with dissolve
    A "Wha?"

    show fangdad happy:
        yalign 0.1 xalign -0.1
    show fangdad:
        easein_cubic 1 xalign 0.35
    with dissolve
    pause .5

    FD "That was a full six minutes you were going off."

    show naser happy:
        yalign 0.1 xalign -1.0
    show naser:
        easein_cubic 1 xalign -0.3
    with dissolve

    Nas "The recording is seven minutes and thirty-three seconds, actually."

    show moe alt flip:
        yalign 0.0 xalign -1.0
    show moe:
        easein_cubic 1 xalign -0.7
    with dissolve
    pause .5

    Moe "The last record was only five minutes and some change."

    show anon unimpressed flip with Dissolve(.25)
    A "That’s nice and all but MY FOOT IS STILL FUCKING BROKEN!"

    Nas "Does it even still hurt?"

    A "{cps=*.1}...{/cps}"

    show anon neutral flip with dissolve
    A "{cps=*.1}...{/cps}Huh{cps=*.1}...{/cps}"
    pause .5

    show fangdad neutral with Dissolve(.25)
    FD "I tried to do a trickshot, ended up tripping Moe and{cps=*.1}...{/cps}"

    "He waves a finger around the hole in his crest."

    Moe "I still got the metal plate in my head, too."

    "Moe knocks a fist against the bottom of his skull, a metallic thump echoing out."
    pause .5

    Attendant "The manager’s approved a reward for beating out the twenty-year-old record!"

    A "Oh, cool, a bowling ball of my own?"

    Attendant "Those shoes you’re wearing, they’re yours."
    pause .5

    "Naser stifles a cough."
    pause .5

    A "{cps=*.1}...{/cps}Thanks{cps=*.1}...{/cps}"

    Moe "Either way, we should probably get a first aid kit."

    show naser considering with Dissolve(.25)
    Nas "Think I saw one by the entrance, let’s go get it."
    window hide
    window auto

    show moe:
        easeout_cubic 0.5 xalign -1.0
    hide moe with dissolve

    show naser:
        easeout_cubic 1 xalign -1.0
    show naser neutral flip with dissolve
    hide naser with dissolve
    pause .5

    "The two go hunting for the first aid kit, and I am left alone with Mister Ripley again."

    "I don’t really care anymore right now, I’m just worn out."
    pause .5

    FD "Y’know{cps=*.1}...{/cps}"

    "Here we go."

    FD "I didn’t know you had it in you."
    pause .5

    A "Had what in me?"

    FD "Me."
    pause .5

    A "Pardon?"

    FD "Seven minutes straight, no regrets, no holding back, and with a single breath."

    FD "I can see a young me in you, Anon."
    pause .5

    FD "And I can also see what my daughter sees in you."

    FD "A strong will, and an iron lung."
    pause .5

    A "O-oh, thank you, sir."
    pause 1

    A "Does that mean you’re okay with-"

    FD "You set foot near second base I’ll finish the job that bowling ball couldn’t."

    A "Understood."
    pause .5

    show fangdad happy with Dissolve(.25)
    FD "Good talk."

    FD "Next time, we oughtta go fishing together."

    A "Next time?"

    FD "Yeah{cps=*.1}...{/cps}"

    FD "Next time."

    stop music fadeout 4
    window hide
    window auto
    pause .5

    scene black with Dissolve(2)
    pause 1.5

    return