SnootGameItalian/game/script/12.5C.prom-night-intro.rpy

label chapter_12_5C:

    #Prom intro
    pause 1

    "{cps=*.2}-- One Month Later --{/cps}"
    pause .5

    play music 'audio/OST/Appreciating the Moment.ogg' fadein 0.5
    pause .5

    "It’s prom night."

    "My old man was kind enough to send over his old tuxedo from his time at high school."

    "It took a bit of sewing, but I got it looking pretty good."
    pause .5

    "Judging by the wine stains on the sleeves, Dad’s made a lot of important announcements in this tuxedo."

    "Gives it a bit of history, I guess."
    window hide
    window auto
    pause .5

    scene home fang outside night
    show naomi prom neutral flip:
        yalign 0.1 xalign 0.6
    with Dissolve(1)
    pause .5

    "When I arrive at Fang’s place with a cheap corsage I see the Pomegranate Parasite waiting outside the front door."

    "Great."
    pause .5

    "And dear god, how can she move in that dress."

    "The top half looks like it’s been shrink-wrapped to her body."
    pause .5

    "And I'm one hundred percent certain there's nothing beneath the bottom half."
    window hide
    window auto
    pause .5

    show anon prom neutral flip:
        yalign 0.1 xalign 1.5
    show anon:
        easein_cubic 1 xalign 1.1
    with dissolve
    pause .5

    show naomi prom neutral with dissolve
    N "Oh, I already knocked Anon."

    N "Naser will be out in a moment to invite us in, I’m sure Fang will be getting ready too."

    N "I’ve heard the two of you are going to prom together!"
    pause .5

    "Ladies and gentlemen, the next Sherlock Holmes."
    pause .5

    A "No, I just happen to be here in a suit to go golfing."

    "I ignore her, focusing instead on not stabbing my palm even more on this flower’s thorns."
    pause .5

    "Fuck it, free is free."

    "And nothing more free than a five finger discount from the neighbor’s yard."
    pause .5

    N "You and Fang just make the cutest couple! Did you two sign up for prom king and queen?"

    A "Nah. She said something about the ‘fascist sexist monarchy system’."

    show naomi prom happy with dissolve
    N "Well, Naser and I have entered and we are going to be prom royalty. Ooooh, I can not wait to wear that beautiful tiara, I picked it out and everything and the crown for Naser-"

    "I’ve already tuned her out."

    pause .5
    show naomi prom neutral with dissolve
    pause .5

    "Naser opens the door."
    window hide
    window auto

    show naser prom neutral behind naomi:
        yalign 0.1 xalign -0.3
    with Dissolve(1)
    pause .5

    show naomi prom neutral flip with dissolve

    "Well if that isn’t the fanciest jacket I’ve seen in a while."

    "It’s certainly better than the background of Avatar he always wears."
    pause .5

    Nas "Sorry to keep you waiting, Naomi."

    show naser prom unimpressed with Dissolve(.25)
    Nas "This thing is a nightmare to get over my wings."
    pause .5

    show naser prom happy with Dissolve(.25)
    Nas "Oh, Anon! Come on in, didn’t know you were already here."

    "He waves for the two of us to enter, pecking Naomi on the cheek when she passes."
    window hide
    window auto
    stop music fadeout 4
    pause .5

    scene black with Dissolve(1)
    pause 0.5

    scene home fang night
    show anon prom neutral flip:
        yalign 0.1 xalign 0.5
    show naser prom neutral flip:
        yalign 0.1 xalign 1.3
    show naomi prom neutral flip:
        yalign 0.0 xalign 1.2
    with Dissolve(1)
    pause .5

    "Fang’s Mother speaks up from the kitchen."

    LM "Oh! Oh! Is that Anon?"
    pause .5

    play music 'audio/OST/Dragging on and on....ogg' fadein 0.5

    Nas "Here we go."
    window hide
    window auto
    pause .5

    show fangmom neutral:
        yalign 0.0 xalign -0.5
    show fangmom:
        easein_cubic 1 xalign 0.0
    with dissolve
    pause .5

    "The small pterodactyl comes out, a bowl she’s struggling to stir in her arms."

    LM "My, aren’t you handsome."
    pause .5

    LM "Pictures! I need to get pictures of you and Lucy!"

    "She sets the bowl aside on the coffee table to frantically search for a polaroid camera."

    LM "To think Lucy would have such a wonderful young man to take her to prom!"
    pause .5

    show fangmom:
        easein_back 1 xalign -0.2
    LM "Aha! Found it. Hold still, dear."
    window hide
    window auto
    pause .5

    play sound 'audio/effects/camera.ogg' ## CC0
    pause .275

    show white with Dissolve(.15)
    pause .5

    "ARGH! Like getting slapped in the face by the Sun’s dick!"
    window hide
    window auto
    pause .5

    show anon prom sad flip
    show white:
        linear 2 alpha 0
    pause .5

    "I blink the blindness away. So that’s why Naser has those fucking aviators."
    hide white
    pause .5

    LM "Lucy will be downstairs in a bit, she’s just getting the last of her makeup on!"

    LM "In the meantime, take a seat! I’ve got some cookies in the oven that are almost ready!"

    show anon prom neutral flip with dissolve
    A "Er, yes, thank you ma’am."
    window hide
    window auto

    show fangmom:
        easeout_cubic 1.2 xalign -1.5
    pause .2
    show fangmom neutral flip with dissolve
    hide fangmom with dissolve
    pause .5

    show anon:
        easein_back 1.5 xalign 0.4
    show anon prom neutral with dissolve

    "I take my seat in the usual spot, sinking in and feeling the pillows conform around my spine."
    pause .5

    "This thing must cost a fortune."

    "Fang’s dad is a police commissioner if I recall."

    "That explains the luxurious furnishings."
    pause .5

    "Now that I think about it, I’m surprised I haven’t seen him yet."
    window hide
    window auto
    pause .5

    show fangdad neutral:
        yalign 0.1 xalign -0.1
    with Dissolve(1)
    pause .5

    LD "So{cps=*.1}...{/cps}"

    show anon:
        easein_back 0.75 xalign 0.5
    show anon prom neutral flip with dissolve
    pause .5

    "I hope I didn’t just ruin these slacks."
    pause .5

    A "Good evening, sir."

    A "I didn’t even see you in your chair, sir."

    A "My apologies."
    pause .5

    LD "Don’t sweat it, son."

    LD "Thing about humans, as well as many carnivores, is that their vision is based largely on movement."

    LD "You’d be surprised how effective staying quiet and stationary can be."

    show fangdad happy with dissolve
    LD "How close you can get to someone without them knowing-"

    play sound 'audio/effects/slapstickbigpunch.ogg'
    show fangdad unimpressed:
        easein_elastic 1 xalign -0.05
    LM "Sweetheart." with vpunch
    pause .5

    LM "No.{w=.3} Intimidating.{w=.3} The suitor."
    pause .5

    show fangdad:
        ease_cubic 1 xalign -0.1
    show fangdad neutral with dissolve
    "The big guy deflates a bit in his chair."

    LD "Point is, don’t get any funny ideas."

    A "Yessir."
    pause .5

    show naomi:
        ease 0.25 yalign 0.05
        ease 0.25 yalign 0.0
    N "We’re all taking the NasCar, right?"

    Nas "Yeah, yeah."

    Nas "Once Fang gets down we’ll skedaddle."

    show anon prom neutral with dissolve
    A "So until then we just sit and chill?"
    pause .5

    show naomi prom happy flip with Dissolve(.25)
    N "We could take more pictures!"
    pause .5

    show dimmer_light behind fangdad, anon, naser, naomi with Dissolve(.25)
    "{cps=*.3}Please no.{/cps}"
    pause .5

    show dimmer_light:
        linear 1 alpha 0

    show fangmom neutral:
        yalign 0.0 xalign -0.5
    show fangmom:
        easein_cubic 1 xalign 0.1
    with dissolve
    LM "Oh! I would love to make this a little photo op!"
    window hide
    window auto
    pause .5

    scene black with dissolve
    pause .5

    play sound 'audio/effects/camera.ogg'
    pause .275
    show white with Dissolve(.1)
    scene home fang night
    show naser prom neutral flip:
        yalign 0.1 xalign -0.1
    show anon prom sad flip:
        yalign 0.1 xalign 0.5
    show naomi prom neutral flip:
        yalign 0.0 xalign 0.8
    show white
    hide white with Dissolve(.4)

    pause .25

    play sound 'audio/effects/camera.ogg'
    pause .275
    show white with Dissolve(.1)
    scene home fang night
    show anon prom unimpressed flip:
        yalign 0.1 xalign 0.5
    show naomi prom happy flip:
        yalign 0.0 xalign 0.1
    show white
    hide white with Dissolve(.4)

    pause .25

    play sound 'audio/effects/camera.ogg'
    pause .275
    show white with Dissolve(.1)
    scene home fang night
    show anon prom grin flip:
        yalign 0.1 xalign 0.5
    show naser prom happy flip:
        yalign 0.1 xalign 1.2
    show white
    hide white with Dissolve(.4)

    pause .25

    play sound 'audio/effects/camera.ogg'
    pause .275
    show white with Dissolve(.1)
    scene home fang night
    show fangdad happy flip:
        yalign 0.1 xalign 0.9
    show anon prom shock flip:
        yalign 0.1 xalign 0.5
    show white
    hide white with Dissolve(.4)

    pause .25

    play sound 'audio/effects/camera.ogg'
    pause .275
    show white with Dissolve(.1)
    scene home fang night
    show fangmom unimpressed:
        yalign 0.0 xalign -0.2
    show anon prom neutral flip:
        yalign 0.1 xalign 0.5
    show fangdad neutral flip:
        yalign 0.1 xalign 1.0
    show white
    hide white with Dissolve(.4)

    pause .25

    play sound 'audio/effects/camera.ogg'
    pause .275
    show white with Dissolve(.1)
    scene home fang night
    show anon prom neutral flip:
        yalign 0.1 xalign 0.5
    show fangdad unimpressed flip:
        yalign 0.1 xalign 0.9
    show fangmom neutral flip:
        yalign 0.0 xalign 0.6
    show white
    hide white with Dissolve(.4)

    pause .25

    play sound 'audio/effects/camera.ogg'
    pause .275
    show white with Dissolve(.1)
    scene home fang night
    show fangmom neutral flip:
        yalign 0.0 xalign -0.15
    show fangdad neutral flip:
        yalign 0.1 xalign 0.2
    show anon prom neutral flip:
        yalign 0.1 xalign 0.5
    show naser prom neutral flip:
        yalign 0.1 xalign 1.1
    show naomi prom neutral flip:
        yalign 0.0 xalign 1.05
    show white
    hide white with Dissolve(.4)

    pause .25

    play sound 'audio/effects/cameraMult.ogg'
    pause .275
    show white with Dissolve(.1)
    scene black
    show white
    pause 1
    hide white with Dissolve(2)
    pause .5

    "Thirty photos later and I never want to see another camera again."

    "Fang’s mom decided to take pictures of every possible combination of us."

    "I don’t know which was worse, having to pose with Naomi or Fang’s dad digging his murder claws into my shoulder."

    "I’ve lost nearly all feeling in that arm."

    "Pretty sure that’ll leave a bruise worse than my accelerated hug with the stair bollard last month."
    pause .5

    "At least the pics with Naser were a nice reprieve."

    "We ended up looking like the blues brothers, standing side by side in fuck ugly suits."
    pause .5

    stop music fadeout 4
    "Just as I was about to resign myself to premature blindness from the camera flash, my saviour arrives."
    pause .5

    Lucy "Oh, Anon, you’re already here!"
    window hide
    window auto

    return