SnootGameItalian/game/script/4.anon-needs-help-during-music-period.rpy

label chapter_4:

    # CH 4 SCENE 1 - Anon is just one slice of toast away from living an anime
    pause 1

    play music 'audio/OST/Skinrow Soul.ogg' fadein 2
    scene outside school fog with Fade(1,0,1)
    "{cps=*.3}-- The Following Monday Morning --{/cps}"
    pause .5

    "I haven’t been able to focus much lately."
    pause .5

    "My original plan is in absolute tatters."

    "As opposed to staying silent and not facing any conflict,{w=.4} I’m now all buddy-buddy with the school reject club."

    "And then there’s Naser and Naomi as well,{w=.4} and all their issues{cps=*.1}...{/cps}"
    pause .5

    "At any moment I feel I'm going to get found out."

    "Trish would certainly beat me senseless."

    "Fang might as well{cps=*.1}...{/cps}"

    "Definitely Naser."
    pause .5

    "All this shit happening,{w=.4} I can’t even get into my favorite hobby."

    "I don’t think I’ve made a single forum post in three days."
    pause .5

    "I stare down at my phone screen and see a sea of threads to post in."

    "And yet,{w=.4} I have nothing to say."
    pause .5

    "Wait,{w=.3} it’s already seven?!"

    "Fuck me,{w=.4} I dragged my feet too much!"

    "I sprint the rest of the way to school."

    scene classroom with fade

    "Luckily,{w=.3} I’m able to slink into homeroom without the teacher molesting me for a tardy pass."

    "Classes tick by in the daily slog,{w=.4} and like all things,{w=.4} lunch eventually comes to pass."

    stop music fadeout 3
    play ambient 'audio/effects/teenageCafeteriaLoop.ogg' fadein 2
    scene cafeteria
    show anon neutral at aright
    with fade

    "I grab a packaged lunch from the omnivore line and begin looking for a place to sit."

    "By now it’s a foregone conclusion,{w=.4} I already know what happens next."
    pause .25
    stop ambient fadeout 3
    play music 'audio/ost/west_coast_kicking.ogg' fadein 1
    pause .5

    N "Anon!"
    pause .5

    "Right on cue."

    show anon neutral flip with dissolve

    show naomi neutral:
        yalign 0.0 xalign -0.75
    show naomi:
        easein 1 xalign 0.4
    with dissolve
    show naser neutral:
        yalign 0.1 xalign -1
    show naser:
        easein 1.5 xalign -0.275
    with dissolve
    pause .5
    
    "Naomi rushes over,{w=.4} followed by Naser.{w=.6} I’d really rather not deal with her any more today."

    show naomi explanatory
    N "Come on,{w=.2} Anon,{w=.4} let's continue our conversation from earlier!"

    N "You know,{w=.3} about extracurriculars like the gardening club!"
    show naomi neutral with Dissolve(.25)

    "Urrrrrgh{cps=*.1}...{/cps}"
    
    A "I don’t think I have the time.{w=.4} I’m way behind in some of my classes already."
    
    show naomi sad with Dissolve(.25)
    N "You're talking about Music, aren't you?"

    show naser considering with Dissolve(.25)
    Nas "Naomi,{w=.2} please stop memorizing the schedules of the new students."

    show naomi considering with Dissolve(.25)
    N "Sorry, it's necessary for record keeping."
    pause .5

    "Naomi places a finger on her chin{w=.15}(?){w=.15} for a moment and stares into space.{w=.5} Suddenly,{w=.3} her face lights up."
    
    show naser neutral
    show naomi happy 
    with dissolve
    N "Wait,{w=.2} don't you share that class with Fang?{w=.4} Why not ask her,{w=.2} I'm sure she'd lend a hand!"
    pause .5

    A "I dunno{cps=*.1}...{/cps}{w=.2} she's usually very busy with her own work,{w=.3} and I don't want to bother her more than I already do every day."#

    show naomi neutral with Dissolve(.25)
    N "It can't hurt to ask,{w=.2} though,{w=.3} right?{w=.4} Just a thought."
    pause .5

    N "Anyway,{w=.3} will you be joining us for lunch again?"

    "I need to think of something,{w=.4} and fast."

    A "Err,{w=.3} sorry.{w=.4} I already promised Fang I’d be eating with her."
    pause .5

    "Smooth."
    pause .25

    show naomi considering with Dissolve(.25)
    N "Oh{cps=*.1}...{/cps}"

    show naomi neutral with Dissolve(.15)
    N "Oh!"

    show naomi explanatory
    N "I’m glad to hear you’re trying to be better friends with Fang!"
    show naomi neutral with Dissolve(.25)

    show naser happy
    Nas "Well hey,{w=.4} this is a welcome surprise!"

    A "Right.{w=.4} Actually,{w=.2} she doesn’t eat in the cafeteria,{w=.4} does she?"

    show naser neutral
    Nas "Didn’t she tell you?{w=.4} She hangs out with her band in the auditorium."

    A "She’s allowed to do that?"

    show naser considering
    N "I’ve asked Principal Spears before,{w=.4} he sees no issue with it."

    A "Huh.{w=.4} Anyways,{w=.2} I uh{cps=*.1}...{/cps}{w=.2} don’t want to keep them waiting!"

    show naser happy
    Nas "See you."

    show naomi happy with Dissolve(.25)
    show naomi:
        ease 0.25 yalign 0.05
        ease 0.25 yalign 0.0
    N "Have fun!"
    pause .5

    A "Right.{w=.3} Bye!"

    show anon:
        easeout 1 xalign 1.5
    pause .1
    show anon neutral with Dissolve(.25)
    hide anon with dissolve

    "I turn away from the two and leave them behind."


    # CH 4 SCENE 2 - Trish continues to hate Anon's guts, more at 11
    
    scene door auditorium with fade

    "Now that i’m in front of the auditorium when it isn’t crowded for once,{w=.4} I can get a decent look around the foyer."

    "The walls are as vine-covered as anywhere else in the building,{w=.4} but the ones here have small magenta flowers blooming on them here and there."

    "I suppose there’s different kinds of vines,{w=.4} wouldn’t make much sense otherwise.{w=.5} Never really thought about it until now."
    pause .5

    "I open the door enough to see Fang’s gang lazing about within."

    "Reed is messing with some box on a table,{w=.4} and Fang and Trish are sitting on the first row of seats chattering to each other."

    stop music fadeout 3

    "I put my hand on the doorhandle and hesitate a bit.{w=.4} Then I pull it open."

    scene auditorium with Dissolve(1)

    "The squeak of the door echoes through the near empty auditorium,{w=.4} and immediately all three turn their heads and stare."
    pause .75

    "There’s an awkward pause that goes on for just a bit too long.{w=.5} Eventually Fang calls out from her seat."

    # TODO: sound direction says play 'She Fucks Human Men', resolve this
    # play music 'audio/OST/Fuck You I Like This Chick.ogg'
    play music 'audio/ost/she_fucks_human_men.ogg' fadein 2
    pause .5

    show fang surprised flip with Dissolve(1):
        yalign 0.0 xalign 1.3
    pause 1

    show fang shocked flip with Dissolve(.25)
    F "What the hell are {i}you{/i} doing here,{w=.2} dweeb?"
    show fang considering flip with dissolve

    show anon:
        yalign 0.1 xalign -0.5
    show anon neutral:
        easein 1 xalign -0.15
    with dissolve
    pause 1

    A "Hiding from Naomi."
    pause .25

    show fang:
        easein_cubic 2 yalign -0.1 xalign 1.35
    show fang unimpressed flip with Dissolve(.25)
    "Fang throws her head back and goes limp on the shitty wooden chair."

    show fang angry flip
    F "{cps=*.7}UUUUUUUUUUUUUUUUUUUUUUUUUUUUUUUUGGHHHHHH{/cps},{w=.2} THAT {cps=*.7}BIIIIIIIIIIIIIIIIIIIIIIIIIIIIIIIIIIIIITCH{/cps}."
    show fang considering flip with Dissolve(.25)
    pause .5

    "{cps=*.1}...{/cps}"

    A "{cps=*.1}...{/cps}"

    F "{cps=*.1}...{/cps}"

    A "{cps=*.1}...{/cps}"

    show fang:
        easein_cubic 1 yalign 0.0 xalign 1.3
    "Fang lifts her head back up."

    show fang unimpressed flip with Dissolve(.25)
    F "{cps=*.3}Ffffffffine{/cps},{w=.4} you can stay."
    pause .5

    show anon:
        ease_cubic 1.5 xalign 0.4

    "I go sit a few yards away from Fang and Trish on the theater seat.{w=.5} Reed turns back to that device he was messing with before."

    "Looks like a projector?"
    pause .5

    A "You don’t like Naomi?"

    show fang angry flip with Dissolve(.25)
    F "What was your first fuckin’ clue?{w=.5} That stupid bitch,{w=.4} acting all high and mighty all the time."
    pause .5

    T "Hey,{w=.4} Fang."
    
    show fang considering flip with Dissolve(.25)
    F "Oh look at me I’m super smart and nice to everyone and everyone likes me so if you disagree with me I get the moral high ground no matter what!"

    "Fang lets out some combination of a snort and a sigh."

    F "No different than Naser.{w=.4} What a couple."

    show fang unimpressed flip with Dissolve(.25)
    F "Ugh,{w=.4} whatever.{w=.5} What was she doing to bother you?"

    A "She’s been pestering me about every little thing since school started.{w=.5} Granted,{w=.4} she’s been a big help in some cases,{w=.4} but jeez she’s overbearing sometimes."

    T "Fang?"
    pause .5
    
    show anon:
        easein 1 xalign 0.0 #0.4
    show fang:
        easein 1 xalign 0.65 #1.3
    with None

    show trish neutral flip:
        yalign 0 xalign 1.35
    show trish:
        easein 1 xalign 0.9
    with Dissolve(1)
    pause .5

    show fang neutral flip with Dissolve(.25)
    F "I’ll say.{w=.4} Sometime in the first semester she ended up helping me with a major science project.{w=.4} We only had a day to do the whole thing."
    pause .5

    A "You waited until the last day for a major grade?"

    show fang considering flip with Dissolve(.25)
    F "It{cps=*.1}...{/cps}{w=.3} That doesn’t matter.{w=.4} Shut up."
    pause .5

    show fang neutral flip
    F "Anyways,{w=.4} Naomi insisted on helping me,{w=.3} and I just went along with it."
    
    show fang unimpressed flip
    F "She ended up just bossing me around for eight hours."

    show trish:
        easein 1 xalign 0.95
    show trish indignant flip with Dissolve(.25)
    T "HEY GUYS DID YOU FORGET I’M HERE TOO?!"

    show trish neutral flip with dissolve
    pause .25
    show fang:
        easein 1 xalign 0.6
    show fang happy with Dissolve(.25)
    pause .25

    F "Oh,{w=.2} right.{w=.4} What were you talking about Trish?"

    show trish smug flip with Dissolve(.25)
    "Trish pulls a cardboard tube out of her backpack.{w=.4} She pops the top of the tube open and pulls a rolled up poster out and unfurls it."

    show trish happy flip
    T "This!{w=.4} Tada!{w=.5} Our first poster!"
    
    show fang surprised with Dissolve(.25)
    
    pause .5

    A "VVURM DRAMA?{w=.4} That’s an{cps=*.1}...{/cps}{w=.2} interesting name{cps=*.1}...{/cps}{w=.4} and what’s with the date on it?"

    show fang neutral flip with dissolve
    pause .25
    F "{cps=*.5}Trish wants-{/cps}{w=.4}{nw}"

    show trish smug flip
    T "We need to have an actual show!{w=.4} Not some dumb school show.{w=.5} We need actual people who matter to show our genius to!"
    pause .5

    "Genius?{w=.4} More like retardation."

    show fang sad with Dissolve(.25)
    F "I don’t know Trish."
    pause .5

    A "{cps=*.4}Yeeeaaaaahhhh{/cps}{w=.2} {nw}"
    show trish neutral flip
    extend "I’m with Fang on this one."

    show fang considering
    show trish unimpressed flip
    with Dissolve(.25)
    "The glare Trish levels at me was akin to a very dull knife."

    show trish:
        easein 0.5 xalign 0.9
    T "You don’t even know how good we are!"

    show trish considering flip with Dissolve(.25)
    T "That was simply a practice session!"
    pause .25

    show trish unimpressed flip with Dissolve(.25)
    T "Since you’re Naser’s friend too,{w=.4} just know HE ruined our first concert.{w=.5} Right Fang?"

    show fang unimpressed with Dissolve(.25)
    F "Ugh,{w=.4} yeah.{w=.5} If he hadn’t invited all those cocksuckers{cps=*.1}...{/cps}"
    show fang neutral with Dissolve(.25)
    pause .25

    A "Still {cps=*.4}I think-{/cps}{w=.4}{nw}"

    T "It doesn’t matter what {w=.1}{nw}"
    show trish angry flip
    play sound 'audio/effects/slapstickPunch.ogg'
    show anon:
        easein_cubic .75 xalign -0.05
    extend "YOU{w=.2} think!" with vpunch
    show trish unimpressed flip with dissolve
    pause .25

    "Whoa,{w=.4} where did that come from."

    show fang neutral flip with dissolve
    pause .25
    F "Let’s drop it for now.{w=.4} My tuna sandwich is getting cold."

    show trish smug flip with Dissolve(.25)
    "Trish grins in victory."
    pause .5

    Re "{size=-10}Dude{cps=*.1}...{/cps}{w=.3} ya got told{cps=*.1}...{/cps}{/size}"

    stop music fadeout 2
    pause .25
    show dimmer_light behind anon, trish with dissolve
    pause .25

    "What the fuck am I doing?{w=.5} I’m dead if I out myself whilst outnumbered here"
    pause .5

    "Trish tore at me like she knew I was there."
    pause .5

    "Had to happen EVENTUALLY."

    "I pray that’s not the case."
    pause .5

    play music 'audio/ost/she_fucks_human_men.ogg' fadein 1
    hide dimmer_light 
    show trish neutral flip
    with Dissolve(1)
    pause .5

    "I finally get to opening my omnivore lunch.{w=.5} A BLT,{w=.3} some chicken nuggets,{w=.3} and an orange."

    "I take my first bite of the sandwich and-"

    stop music fadeout 1.0
    play sound 'audio/effects/schoolBell.ogg'
    "{cps=*20}{i}DING-{w=0.7}DONG {w=0.65}BING-{w=0.7}BONG{/i}{/cps}"
    pause 0.5
    stop sound fadeout 1

    "Are you kidding me."

    "I cram as much of the sandwich into my mouth as I can and close the box."

    "Reed puts the projector in the corner of the room,{w=.3} and Trish makes for the exit with Fang."
    
    "I follow after,{w=.4} cheeks still filled with food"


    # CH 4 SCENE 3

    play ambient 'audio/effects/school loop.ogg' fadein 2
    scene hallway with Fade(1, 0, 1)

    pause .5

    "Next class is{cps=*.1}...{/cps}{w=.2} Music,{w=.4} that’s right.{w=.5} I’ll be walking with Fang then."

    "The three all wave each other goodbye and Fang turns towards our shared class."
    pause .5

    stop ambient fadeout 3
    play music 'audio/OST/Appreciating the Moment.ogg'
    "May as well make some small talk."

    show anon neutral:
        yalign 0.1 xalign 0.1
    show fang neutral behind anon:
        yalign 0.0 xalign 0.9
    with Dissolve(1)
    pause .5

    A "So,{w=.2} uh{cps=*.1}...{/cps}{w=.4} What’s your favorite band,{w=.2} Fang?"

    show fang considering flip with dissolve
    F "My favorite band,{w=.3} huh{cps=*.1}...{/cps}"

    show fang neutral flip with Dissolve(.25)
    F "Guess it’d be something like The Skinks{cps=*.1}...{/cps}{w=.4} Maybe the Fossillies?"

    A "‘Oi,{w=.3} tha’ ‘ere’s sum pre’ey bri’ish tayste,{w=.4} yeah?"

    show fang:
        easein_cubic 1 xalign 0.975
    show fang happy with Dissolve(.25)
    F "{cps=*.35}Pffft.{/cps}"

    "She turns away to hide her snickers."

    show fang happy flip with dissolve
    pause .25

    F "Shut it."

    F "I’m sure your favorite is much better."
    pause .5

    A "I’m into{cps=*.1}...{/cps}"
    pause .5

    menu:
        "Boomer rock":
            pass
        "Obscure hipster shit":
            pass
        "Anime openings and video game OSTs":
            pass

    pause .5

    show fang:
        easein 0.5 xalign 1.05
    "Fang holds a hand up to her beak."

    F "{cps=*.4}AHAHAHAHAHAHHA.{/cps} {w=.5}{nw}"
    show fang:
        easein_cubic 1 xalign 0.9
    extend "God you are such a dweeb"

    show anon grin with dissolve
    "I flash her my biggest shit-eating grin."

    A "Least I don’t need a ‘loisence’ to listen to it."
    pause .5

    F "Oi luv,{w=.3} didn’ share me taystes to get rallied on,{w=.5} bit rewd,{w=.2} innit?"
    pause .25

    scene black with fade
    pause .5

    "The two of us banter with each other with increasingly strong british accents all the way to class."
    pause .5

    stop music fadeout 3

    # CH 4 SCENE 4 - Tuning fork

    scene bandroom with Fade(1, 0, 1)
    pause 1

    "{cps=*.1}...{/cps}"
    pause .5

    play music 'audio/OST/Dragging on and on....ogg'

    play sound 'audio/effects/slapstickPunch.ogg'
    "ARGH!!{w=.5} This stupid-" with vpunch
    pause .25

    "\"Define a treble clef\"?{w=.5} I don’t know what a treble clef is!{w=.5} I don’t care about this shit,{w=.3} it won’t ever be useful."

    "Fuck this,{w=.4} who can I cheat off of?"
    pause .5

    "I lean back in my uncomfortable chair hoping to pop my spine back in place."

    N "{i}\"Wait,{w=.2} don't you share that class with Fang?{w=.4} Why not ask her,{w=.2} I'm sure she'd lend a hand!\"{/i}"
    pause .5

    "I crane my head,{w=.3} looking for Fang.{w=.5} She's at her own desk she’s filling out her assignment page easily,{w=.4} drumming her fingers on her desk.{w=.6} Almost looks like she’s strumming honestly."
    pause .5

    "Agh,{w=.3} and that’s another thing.{w=.5} Who the fuck made guitars?!{w=.5} Fuck trying to memorize frets or whatever the fuck."
    pause .5

    "Oh shit,{w=.4} she’s looking at me now."

    "She tilts her head and taps her sheet."
    pause .5

    "OH!"

    "I respond with an eyeroll and finger gun at my temple.{w=.6} My thumb hammer drops and I fake die in my seat."

    "Fang shakes her head,{w=.4} returning to her assignment with a tiny smile gracing her beak."
    pause .5

    "I look at the papers we need to finish.{w=.5} Fuck me,{w=.4} how the hell are we suppose to finish these by the end of class?!"
    pause .5

    N "{i}\"It can’t hurt to ask, though,{w=.3} right?\"{/i}"
    pause .5

    "Maybe the Neon Nero had a good point."

    "Still,{w=.4} interrupting Fang now might piss her off."

    "{cps=*.25}FFFFFf{/cps}uck.{w=.4} I’ll flip a coin."
    pause .5

    menu:
        "Heads, ask Fang for help":
            pause .5
            jump .Heads
        "Tails, leave Fang alone":
            pause .5
            jump .Tails


    label .Heads:

    $ fangscore += 1

    # TODO: sound direction says 'Appreciating the Scenery', old script had 'Appreciating the Atmosphere' resolve this
    stop music fadeout 3
    "Guess that’s that."

    "May as well get it over with."
    pause .5

    play music 'audio/OST/appreciating_the_scenery.ogg' fadein 2

    "I slink out of my chair and go around to Fang’s desk."


    pause .5

    show anon neutral at aleft
    show fang neutral at sright
    with Dissolve(1)
    pause .5

    A "Uh{cps=*.1}....{/cps}"

    show fang:
        easein_cubic 1 xalign 1.1
    pause .1
    show fang shocked flip with Dissolve(.25)
    "She jumps in her chair"

    show fang surprised flip with dissolve
    F "How’d you get-{w=.4} {nw}"
    show fang considering flip
    extend "don’t scare me like that!"

    A "Sorry{cps=*.1}...{/cps}"

    show fang neutral flip with Dissolve(.25)
    "I look at her work and see she’s only a quarter done.{w=.5} Fuck,{w=.3} I hope we have enough time."

    A "{cps=*.2}Sooo...{/cps}{w=.3} you seem to be capable of deciphering dead languages."
    pause .5

    show fang unimpressed flip with Dissolve(.25)
    F "Wha-"

    A "canyouhelpmewiththis?!"
    pause .5

    show fang neutral flip with Dissolve(.25)
    F "Help you with the assignment?"

    A "{cps=*.1}....{/cps}Yes.{w=.5} I don’t get any of this.{w=.4} It’s all moon runes to me."
    pause .5

    F "How’d you even join this class?"

    A "Only elective that had an open spot.{w=.4} Even though it’s mid semester and I’m expected to be at the level of everyone that’s been here all year."

    show fang considering flip with Dissolve(.25)
    "Fang leans her head down and holds her hand on top of her muzzle."

    "I’m guessing that’s supposed to be like pinching the bridge of your nose."
    pause .5

    show fang neutral flip with Dissolve(.25)
    F "Whatever,{w=.4} it’s fine if the teacher gives the green light."
    pause .5

    show anon:
        easein 1 xalign .4 #1.0
    show fang:
        easein 1 xalign 1.35 #1.0
    with None

    show reed king rex behind anon:
        yalign 0.1 xalign -1.9
    show reed:
       easein 1 xalign -1.2
    with Dissolve(1)
    pause 1
    Re "It’ll be fine."

    show anon fear flip:
        easein_back 0.5 xalign 0.6
    show fang shocked flip:
        easein_back 0.5 xalign 1.4
    play sound 'audio/effects/slapstickBigPunch.ogg'
    with vpunch

    pause .5

    "Fang and I jump several inches."
    
    show anon sad flip
    show fang surprised flip
    with Dissolve(.75)
    pause .5

    show fang neutral flip with Dissolve(.25)
    F "What are you doing here?!"

    show anon neutral flip with dissolve
    A "And what’s with the costume?"

    "Reed is in an overly large inflatable T-rex costume."
    pause .5

    Re "Gotta get a signature for this absent note,{w=.2} man{cps=*.1}...{/cps}"

    Re "Anyways{cps=*.1}...{/cps}{w=.3} Mr. Jingo doesn’t care about if you use,{w=.3} like,{w=.4} partners and stuff{cps=*.1}...{/cps}{w=.4} He just wants the work done{cps=*.1}...{/cps}"
    pause .5

    A "I{cps=*.1}...{/cps}{w=.4} I see.{w=.5} I didn’t know you were also the school mascot, Reed."
    pause .5

    Re "There’s,{w=.3} like,{w=.5} pockets in here man{cps=*.1}...{/cps}{w=.4} You get to bring a lot of cool stuff{cps=*.1}...{/cps}{w=.5} As long as you clean it after{cps=*.1}...{/cps}"

    "I’m not even going to bother at this point."

    F "Thanks,{w=.2} Reed."

    Re "S’all good, man{cps=*.1}...{/cps}"

    stop music fadeout 3
    "Reed gets up and goes to the teachers’ desk in the corner of the room."

    show reed:
        easeout 1 xalign -2.0
    pause .2
    hide reed king rex with dissolve
    pause .5

    show anon:
        ease 1 xalign 0.5
    show anon neutral with dissolve
    "I turn back to Fang expectantly."
    pause .5

    F "I’m not getting up.{w=.4} Get your crap and sit down already."
    pause .5

    A "Thanks."

    "{cps=*.1}...{/cps}"

    play music 'audio/OST/Fuck You I Like this chick.ogg'
    pause .5

    scene bandroom
    show fang happy flip at sright
    show anon neutral:
        yalign 0.1 xalign 0.15
    with Fade(1, 0, 1)

    jump .PostFlip


    label .Tails:

    stop music fadeout 3

    "Guess that settles it."

    "Fang wouldn’t want to be bothered right now anyways."
    pause .5

    "Looking back to my paper,{w=.4} I try once again to make sense of the questions and music notes."

    "\"Write the following notes in both Treble and Bass clef\"."

    play music 'audio/OST/Those Other Two Weirdos.ogg' volume 0.8 fadein 3
    "{cps=*.1}...{/cps}What?"
    pause .5
    
    show reed king rex:
        yalign 0.1 xalign -0.2
    show dimmer_light behind reed
    with Dissolve(1)
    pause .5

    Re "Yo,{w=.4} you should have like{cps=*.1}...{/cps}{w=.3} asked Fang for help, man{cps=*.1}...{/cps}"

    hide dimmer_light
    play sound 'audio/effects/slapstickPunch.ogg' 
    with vpunch
    pause .5

    "I have to grab the desk to keep myself from falling out of my chair."

    A "Reed,{w=.4} what the fuck are you doing here?!"

    Re "Just getting an absent note signed by teach,{w=.2} man{cps=*.1}...{/cps}"
    pause .5

    A "And what’s with the outfit?!"

    "Reed is in an overly large inflatable T-rex costume."
    pause .5

    Re "School mascots are pretty cool{cps=*.1}...{/cps}{w=.3} You wouldn’t believe the things they let you do with these{cps=*.1}...{/cps}"
    pause .5

    "I’m not going to ask for clarification."
    pause .5

    Re "But,{w=.2} uhh{cps=*.1}...{/cps}{w=.3} You should get some help or something{cps=*.1}...{/cps}"

    Re "I’ll ask the teacher for you{cps=*.1}...{/cps}"
    pause .5

    A "No,{w=.4} Reed,{w=.4} {cps=*.4}you don’t have to-{/cps}{w=.4}{nw}"

    play sound 'audio/effects/slapstickBigPunch.ogg' 
    stop music fadeout 3
    play ambient 'audio/effects/classroomLoop.ogg'
    Re "YO,{w=.1} TEACH!{w=.4} THIS GUY NEEDS SOME EXTRA HELP!" with vpunch
    pause .5

    "All eyes turn to us.{w=.6} The desk makes a nice ‘conk’ sound when my head hits it."

    show jingo at sleft with dissolve
    pause .25

    jingo "Does he really?"
    pause .5

    jingo "Err{cps=*.1}...{/cps}{w=.3} someone{cps=*.1}...{/cps}{w=.3} {i}Fang!{/i}{w=.5} You help him with the packet."

    "Fang glares daggers at the two of us."
    pause .5

    A "{cps=*.3}Thanks,{/cps}{w=.4} Reed."

    Re "Hey,{w=.3} no problem man!{w=.5} I gotta go{cps=*.1}...{/cps}"

    hide reed
    hide jingo
    with dissolve
    pause .25

    "Reed shuffles over to the teachers’ desk in the corner to get his signature."
    stop ambient fadeout 5
    pause .5

    "Fang calls out from her chair."

    F "I’m not getting up.{w=.4} If you need help grab your stuff and get over here."
    pause .5

    "The damage is done.{w=.4} May as well at this point."

    play music 'audio/OST/Fuck You I Like this chick.ogg'
    "{cps=*.1}...{/cps}"
    pause .5

    scene bandroom
    show fang unimpressed flip at sright
    show anon neutral:
        yalign 0.1 xalign 0.15
    with Fade(1, 0, 1)
    
    jump .PostFlip


    label .PostFlip:

    pause .5
    # TODO: Fuck You I Like This Chick
    F "Jesus{cps=*.1}...{/cps}{w=.3} you suck at this."

    A "No shit,{w=.4} I don’t know what half this shit is!"

    F "God,{w=.3} they tell you about treble notes in Elementary,{w=.5} it’s E,{w=.15} G,{w=.15} B,{w=.15} D,{w=.15} F{w=.15} for treble and G,{w=.15} B,{w=.15} D,{w=.15} F,{w=.15} A{w=.15} for bass!"
    pause .5

    A "How the hell do you know any of this."

    "Anon then realized,{w=.4} he is horrendously fucking stupid."

    show fang neutral flip with Dissolve(.25)
    F "I’ve been into playing music since pre-k"
    pause .5

    "{cps=*.1}...{/cps}Roll with it"
    pause .5

    A "So does it take that long to learn that horrid thing?"

    "I point at the class’ electric guitar."
    pause .25

    F "Nah,{w=.3} I started with piano.{w=.5} I didn’t get my first guitar ‘til freshman year."
    pause .5

    A "The piano?{w=.4} Isn’t that the hardest one?"

    "I have no clue what i'm talking about."
    pause .25

    F "Maybe for some,{w=.4} but I started early and got ahead.{w=.6} My grandma had an old piano she would let me mess around with."

    F "She would try to get me to play all kinds of songs,{w=.4} mostly church stuff because she wanted me to be a little goodie two shoes like she was.{w=.6} It{cps=*.1}...{/cps}{w=.4} {nw}"
    show fang considering flip
    extend "was fun."

    show fang neutral flip with Dissolve(.25)
    F "Then I started taking piano lessons privately because my mom saw that I was interested in it,{w=.6} {nw}"
    show fang happy flip
    extend "and in middle school I joined the band for awhile!"

    F "Only quit because of marching season,{w=.4} I was {i}not{/i} wearing a dumb uniform."
    pause .5

    show fang considering flip with Dissolve(.25)
    "Fang gets a strange expression,{w=.4} a mix between a blush and a scowl as she returns back to her snappy attitude."

    show fang unimpressed flip with Dissolve(.25)
    F "You done with that yet?{w=.5} It's taking you way too long,{w=.4} rather have you out of my way."
    pause .5

    "Cute."
    pause .5

    "I show her the half-finished worksheet."

    A "I still don’t get this fucking part."

    show fang neutral flip with Dissolve(.25)
    F "It’s literally three classifications,{w=.4} it’s really easy."
    pause .25

    A "It doesn’t list them!"
    pause .25

    F "Did you even read the page?"

    "Fang then grabs the paper and points at the top right.{w=.5} In a small box is a list of three types,{w=.5} woodwind,{w=.3} brass,{w=.3} and percussion."
    pause .5

    A "Oh{cps=*.1}...{/cps}"
    pause .5

    F "You still need me to help you with this or do you have it from here?"

    "Of course I have it,{w=.3} I know this shit,{w=.4} it's just 3 categories."

    "Percussion is simple enough.{w=.4} Getting the differences between woodwind and brass is a bit harder."

    stop music fadeout 3

    A "Right.{w=.4} You know your stuff.{w=.5} Band stuff."
    pause .5

    show fang considering flip with Dissolve(.25)
    "I heard a sigh from Fang."
    pause .5

    F "I can’t believe this."
    pause .5

    A "What is it?"

    play music 'audio/OST/Summertime Synth.ogg'
    show fang neutral flip with Dissolve(.25)
    pause 1

    F "Why did you leave your old school?"

    show anon:
        easein 0.5 xalign 0.1
    A "Wh-"

    A "Where did that come from?"
    pause .25

    F "Just wondering,{w=.4} though I think I know the answer."
    pause .5

    A "Why do you care?"
    pause .5

    F "You’re here for just two weeks and already you’ve wedged yourself in with my friends."
    pause .25

    A "I didn’t really have a choice there,{w=.3} Fang."

    A "I just{cps=*.1}...{/cps}{w=.3} wanted to cruise through this year.{w=.5} I’m not good with friends."
    
    show fang considering flip with Dissolve(.25)
    F "Sorry,{w=.4} just had a feeling.{w=.5} I myself haven’t gotten many new friends in a few years{cps=*.1}...{/cps}"

    F "It’s like I make people avoid me{cps=*.1}...{/cps}{w=.4} I don’t like new people{cps=*.1}...{/cps}"

    A "That's weird."

    show fang neutral flip with Dissolve(.25)
    F "Fuck em',{w=.4} you know?"

    A "Sure."
    pause .75

    show fang unimpressed flip with Dissolve(.25)
    F "You act like you have a hard time socializing,{w=.5} I’m not seeing it."

    show fang neutral flip with Dissolve(.25)
    F "Makes me think you didn’t leave your school out of necessity,{w=.4} but because you really must have fucked up royally."

    F "I know your kind."

    show dimmer_light behind anon, fang with dissolve

    "I-{w=.1}I,{w=.4} what did Fang mean by that?{w=.6} It all just came out of nowhere -{w=.4} I mean jeez-"

    "We’re talking about how she can’t get friends and now she wants to know about THAT{cps=*.1}...{/cps}"
    pause .5

    "Oh God.{w=.5} I’m getting hot."
    pause .5

    "It’s Trish.{w=.6} Trish told Fang{w=.3} and now she knows everything."
    pause .5

    "Play dumb?{w=.5} Hopefully that will work."
    
    hide dimmer_light with dissolve

    A "I have no clue what you’re talking about."
    pause .5

    show fang considering flip with Dissolve(.25)
    F "Honestly?{w=.4} Me neither."
    pause .5

    F "You’re just some loser that knows NOTHING about music."

    # F "And yet you come in from your cave where even their parents must’ve wanted you gone."
    F "You come in from your cave where even your parents must’ve wanted you gone."
    
    show fang neutral flip with Dissolve(.25)
    F "And yet,{w=.4} you’re now BOTH{w=.15} my science and music partner,{w=.5} on top of worming your way in with MY band and with MY friends-"

    show fang happy flip with Dissolve(.25)
    F "Anon,{w=.4} what is there TO understand?"

    "She’s laughing."
    pause .5

    A "{cps=*.1}...{/cps}"

    show fang neutral flip with Dissolve(.25)
    F "Hey,{w=.4} you ok?"
    pause .25

    A "{cps=*.1}...{/cps}"

    show fang happy flip with Dissolve(.25)
    F "That’s funny,{w=.4} come on."
    pause .25

    A "{cps=*.1}...{/cps}"

    A "{cps=*.2}Haha.{/cps}"
    pause .25

    show fang neutral flip with dissolve
    F "I'll almost miss you when you leave and start finding your own friends."
    pause .25

    A "Whatever you say,{w=.3} Fang."

    show fang considering flip with Dissolve(.25)
    "With a roll of her eyes she returns to scrolling through her phone again.{w=.6} I seriously wonder now what she meant."

    stop music fadeout 3
    pause .25

    F "I gotta go."
    pause .5

    A "Y-{w=.15}you’re leaving so soon?"

    show fang neutral flip with Dissolve(.25)
    F "I’m going to the bathroom,{w=.4} stupid."
    pause .5
    show fang:
        easeout 1 xalign -0.7
    pause 0.5
    hide fang with dissolve
    pause .5

    "{cps=*.05}...{/cps}"


    show dimmer_darker behind anon with Dissolve(.25)
    play music 'audio/OST/you can_t sage here.ogg'
    pause .25

    "She knows."
    pause .5

    "But how?!"
    pause .5

    show anon:
        easein_cubic 0.75 xalign 0.6
    pause .5

    "She left her phone on the desk."

    "I can see the imprint of the password being illuminated by the room’s lamps"
    pause .5

    show anon neutral flip with dissolve
    "It{cps=*.1}...{/cps}{w=.4} It wouldn’t be right."
    pause .5

    show anon neutral with Dissolve(.25)
    "{cps=*.1}...{/cps}I have to know."

    "I reach over to pick up the phone."
    pause .5

    "Some movement in the corner of my eye solidifies me."

    show reed king rex behind anon:
        yalign 0.1 xalign -1.2
    show dimmer_light behind anon, reed
    with Dissolve(2)
    
    "{i}Why’s Reed still here{/i}?!"
    pause .5

    Re "{cps=*.05}...{/cps}"

    A "{cps=*.05}...{/cps}"

    stop music fadeout 3
    Re "{cps=*.05}...{/cps} {cps=*.2}{i}*snrrrk*{/i}{/cps}"
    pause .5

    "Oh thank Raptor Jesus.{w=.5} He’s asleep."

    play ambient 'audio/effects/classroomLoop.ogg' fadein 3
    hide dimmer_light 
    hide dimmer_darker
    hide reed
    with Dissolve(1)
    pause .5

    "Fang’s password is{cps=*.1}...{/cps}"

    "Wait,{w=.4} only the ‘one’ key is smudged?"

    "I guess it’s worked until now{cps=*.1}...{/cps}"
    pause .5

    "Ah,{w=.4} the messenger app."

    transform cursortransform:
        xalign 0.55
        block:
            yalign 0.2
            pause .25
            easein_cubic 1 yalign 0.75
            pause .5
            repeat

    image cursor = At("pointer", cursortransform)

    screen prompt():
        fixed:
            add "cursor"

    screen mousedetect():
        transform: # thanks based nutbuster
            zoom 0.8
            rotate 12.5
            mousearea:
                ypos -75
                area(0.225, 0, 795, 1100)
                # xalign 0.5 yanchor 0 ypos 0
                hovered Hide("prompt")
                unhovered Show("prompt")

    screen textscroll():
        # kick the player back out in X seconds in case they can't find the 'close' button
        # timer 10.0 action Return() 
        add "white"
        timer 2 action(Show("mousedetect"), Show("prompt"))
        
        transform: # thanks based nutbuster
            zoom 0.8
            rotate 12.5
            viewport:
                xalign 0.51 yanchor 0 ypos -75 xysize(795, 1150)
                child_size(795, 7650)
                draggable True
                arrowkeys True
                # edgescroll(400, 800)

                add "texts"
                yinitial 1.0

                frame:
                    xalign 0.53 ypos 100
                    button:
                        text "CLOSE" style "button_text":
                            xalign 0.5
                        xsize 500
                        action (Hide("mousedetect"), Hide("prompt"), Hide("textscroll", transition=Dissolve(1.0)), Return())
        add "fang phone"

    call screen textscroll with dissolve

    pause 1

    "{cps=*.1}...{/cps}There’s surprisingly not a lot."

    "Seems they interact mostly in person."
    pause .5

    "{cps=*.1}...{/cps}What did I even just accomplish?"

    "I shouldn’t have looked."

    "All because of my paranoia{cps=*.1}...{/cps}{w=.3} I just violated someone’s privacy."
    
    show anon sad with dissolve
    "I can feel a pit open in my stomach."

    "I shouldn't have done it."

    "Trish is Fang’s friend.{w=.5} Not me."
    pause .5

    "God damn it,{w=.2} Anon.{w=.5} The fuck is wrong with you."

    show anon neutral with dissolve
    "I set the phone back where it was."

    "A glance back at Reed and I confirm that he’s still unconscious."
    pause .5

    stop ambient fadeout 2
    play music 'audio/OST/Bayside Bumming it.ogg'

    "What’s another secret to keep?"

    "Each one just building on the last,{w=.5} the growing maw in my gut threatens to make me violently ill."
    pause .5

    show fang neutral:
        yalign 0.0 xalign -0.5
    show fang behind anon:
        easein 1 xalign 0.0
    with Dissolve(1)
    pause .5

    F "Oi!"

    show anon fear:
        easein_cubic 1 xalign 0.1
    show fang:
        easein 1 xalign 1.0
    pause .5
    show anon neutral
    show fang neutral flip
    with dissolve

    "I’m startled as Fang retakes her seat."
    pause .5

    F "Did you manage to do {i}anything{/i} on the sheet?"
    pause .25

    "I simply shake my head as I show her the incomplete worksheet."

    show fang unimpressed flip with Dissolve(.25)
    "Fang sighs frustratedly."
    pause .5

    A "Look if I’m being a bother-"

    show fang neutral flip with Dissolve(.25)
    F "It’s simple you dweeb."

    "Fang began breaking down the questions,{w=.4} her tone less condescending than when we initially started."

    "The way she explained it was infinitely better than how Mr. Jingo did at the start of class."
    pause .5

    "Over time the sheet was slowly filled in,{w=.4} things finally starting to click now."

    show fang happy flip with Dissolve(.25)
    F "Looks like you got the hang of this bit.{w=.5} Good job,{w=.3} dork."

    "Fang smirks a bit."
    pause .5

    "I see a chance to strike."
    pause .5

    A "Helps to have an actual decent teacher."

    show fang:
        easein_cubic 1 xalign 1.05
    show fang surprised flip with dissolve
    "The slight red tint tells me I was right on the mark."

    "There’s also the steady *thump{w=.2} thump{w=.2} thump*{w=.2} of her tail on the back of her seat to clue me in.{w=.6} I can’t help thinking of tugging on the appendage."

    "Wait,{w=.4} the thumping."

    "*Thump thump{cps=*.1}...{/cps} thump thump thump{cps=*.1}...{/cps} thump thump{cps=*.1}...{/cps} thump thump thump*"
    pause .5

    A "Hey uh{cps=*.1}...{/cps}{w=.3} Is{cps=*.1}...{/cps}{w=.3} Is your tail drumming right now?"

    show fang neutral flip with dissolve
    F "Hm?{w=.5} Oh,{w=.2} that.{w=.5} Kinda."

    A "Kinda?"

    F "I’m feeling out a rhythm.{w=.4} Thinking of a new song."

    A "Is that normally part of the creative process?"

    F "Maybe,{w=.3} maybe not.{w=.6} Are you done with the packet yet?"
    pause .5

    "I groan."
    pause .5

    A "Still got half a page left."

    show fang unimpressed flip with Dissolve(.25)
    F "That’s just a crossword puzzle.{w=.4} I’m not helping if you can’t do even that."

    A "I know,{w=.3} I know."
    pause .5

    "I have to resort to good ol’ logic to solve the crossword.{w=.4} The longest and shortest words are easy enough to figure out."
    pause .5

    A "But,{w=.2} uhh{cps=*.1}...{/cps}"

    show fang neutral flip with Dissolve(.25)
    F "Hm?"
    pause .5

    A "Thanks for helping me.{w=.4} With the assignment I mean."

    show fang considering flip with Dissolve(.25)
    F "Uhh yeah.{w=.4} Sure."

    "There’s that red tint again."

    F "I’ll help again{cps=*.1}...{/cps}{w=.4} {nw}"
    show fang unimpressed flip
    extend "I mean,{w=.5} if you need it."
    pause .5

    A "Really?{w=.5} Thanks."

    show fang neutral flip with Dissolve(.25)
    F "Yeah,{w=.3} just-"

    stop music fadeout 1
    play sound 'audio/effects/schoolBell.ogg'
    "{cps=*20}{i}DING-{w=0.7}DONG {w=0.65}BING-{w=0.7}BONG{/i}{/cps}"
    pause 0.5
    play music 'audio/OST/Bayside Bumming it.ogg' fadein 1.0
    stop sound fadeout 1

    "That’s the bell telling us to piss off to the last period.{w=.5} Crap,{w=.3} I still got a few words left."
    pause .5

    scene black with Fade(1, 0, 1)
    "I guess the last few words and rush over to the teachers’ desk to turn it in.{w=.6} When I turn back I catch sight of Fang leaving the room in a hurry,{w=.4} tail between her legs."
    pause .5

    Nas "{i}{cps=*.6}She’s not that bad once you get to know her.{/cps}{/i}"
    stop music fadeout 3
    pause .5

    "Guess he was right after all."
    pause 1

    "God,{w=.4} I feel like a jerk now."

    "{cps=*.1}...{/cps}"
    pause .5

    return