SnootGameItalian/game/script/1.first-two-days-anon-meets-fang.rpy

# Naser and Naomi reacting to Anon landing on his ass
image naser silo = im.Flip(im.MatrixColor("naser/naser neutral.png",im.matrix.brightness(-1)), horizontal=True)
image naomi silo = im.MatrixColor("naomi/naomi neutral.png",im.matrix.brightness(-1))
image naser silo shocked = im.Flip(im.MatrixColor("naser/naser shocked.png",im.matrix.brightness(-1)), horizontal=True)
image naomi silo shocked = im.MatrixColor("naomi/naomi shocked.png",im.matrix.brightness(-1))

# Naser's position when helping Anon get up
transform nmidright:
   xalign 1.5 yalign 0.08

# Naomi's position when handing the brochure to Anon
transform scloserleft:
   xalign 0.1 yalign 0.0

label chapter_1:
    #First Day of School
    I "January sixth."

    I "Year 201M2020 BC."

    I "Volcaldera Bluffs."

    I "Weather conditions;{w=0.5} cold as balls."

    I "It’s my first time living close to water."

    I "The idea of ‘marine layer’ is new to me,{w=0.4} but I do understand morning mist."

    I "This was like it,{w=0.2} except infinitely more shitty."

    I "The heavy fog makes navigating to my new school more difficult as I fail to see anything five feet in front of me."

    I "Like a runt of a tree planted in the sidewalk that I swerve to avoid."

    I "It’s my first time having to walk to school too."

    I "My new apartment is in an awkward spot.{w=0.5} Opposite side of town,{w=0.3} yet no school or public bus to take me from there."

    I "It’s my first day at a new school."

    I "It’s the second half of the first semester of senior year."

    I "I had six months left at my old school."

    I "I can’t even imagine the kind of hell those six months would have been."

    I "But this{cps=*0.05}...{/cps}"

    I "I should take my mind off of it."

    I "I whip out my phone,{w=0.3} and consider the best way to make people upset online."

    menu:
        "Reply to the obvious shill thread":
          I "I replied to the obvious shill thread"

        "Bait the obvious underaged poster":
          I "I baited as underage B&"


    I "The thread goes 404 right as I'm ready to post my well thought-out reply."

    I "Better hide my phone before someone sees fit to take it from me,{w=0.5} the only human around town.{w=0.4} I think."

    play music 'audio/effects/chatter loop.ogg' fadeout 1.0 fadein 1.0

    I "It’s the sounds that reach me first.{w} The chatter of people milling about."

    show rosaSilo at scenter
    show stellaSilo at nright

    unknown "Bro"

    unknown "It’s been too long!"

    unknown "It was only three weeks *Giggle*"

    I "I can make out the building now."

    I "The fog shrouding gives the school an ominous vibe to it."

    I "I look at the name written on the arch over the entrance"

    I "{cps=*0.2}{b}{size=+10}{i}Volcano High{/i}{/size}{/b}{/cps}"

    scene outside school fog with fade

    A "Perfect setting for a horror game.{w=0.5} Or maybe a shitty WAD."

    window hide
    pause 0.75

    I "The attempt at humouring myself just made me feel more alone."

    show anonphone with dissolve

    I "A check of my phone says I’m 30 minutes early."

    I "Wonderful."

    hide anonphone with dissolve

    I "I move to the entrance,{w=0.3} only to see all of the steps occupied by students."

    scene stairs at Pan((6000, 1200),(553, 169), 30.0) with fade

    I "Their eyes turn to me.{w=0.4} Expressions of confusion and contemplation.{w=1} I can feel their judging stares,{w=0.3} the same that had haunted me for four months previous."

    I "I can already picture what they’re thinking."

    I "{i}\"Dude,{w=0.4} check it out!\"{/i}"

    I "{i}\"Is that a skinnie?\"{/i}"

    I "{i}\"Where’s his spear?{w=0.5} Aren’t they all like,{w=0.4} spear chuckers or something?\"{/i}"

    I "{i}\"Bet he eats his own kind.\"{/i}"

    I "They probably see me as some kind of circus attraction and nothing more."

    I "Ha,{w=0.4} I’m the freakshow among this cereal box mascot crowd."

    I "Taking acid is not nearly as colorful as going to Volcano High,{w=0.5} I should write that down."

    I "As I write \"{i}write that down{/i}\" on my phone’s note app,{w=0.3} I noticed the surrounding students stopped looking at me,{w=0.5} which is good."

    I "I can peep around the friend circles without a problem now."

    I "Not like I'll ever be a part of one anyway."

    scene stairs at Pan((553,169), (553, 169), 0) with None  # snap here if the player is advancing the dialogue quickly
    image iris = im.FactorScale(im.MatrixColor("vfx/iris.png",im.matrix.opacity(0.9)), 4.5)
    window hide
    show iris:
      xalign 0.99 yalign 0.75
    stop music fadeout 2.0
    with Dissolve(2.0)

    pause 1.0

    I "?"

    play music "audio/OST/That Monochromatic Weirdo.ogg"

    scene fanglookback at Pan((0, 1080), (0, 0), 10.0) with dissolve

    I "{cps=*0.5}Talk about wanting to stand out,{/cps}{w=0.7} I never thought it was possible to look like you were from a black and white twenties cartoon."

    I "She does differ from the other technicolor students though{cps=*0.1}...{/cps}"

    I "...in the worst way possible."

    I "O-oh yeah.{w=0.5} She's staring at me{cps=*0.1}...{/cps}"

    I "...with that look.{w=0.6} {cps=*0.4}Fucking hell.{/cps}"

    I "Has she never seen a human in her life?"

    I "{cps=*0.4}I fucking hate that look.{/cps}"

    I "Contempt.{w} Judging."

    I "Everyone that has looked at me like that never proved to be anything more than an asshole."

    I "Like I'M the anomaly here.{w=0.6} She's just as dumb and insufferable as the rest of them."

    I "She’s probably no better than me,{w=0.3} miss \"my snout is so big I can land a plane on it\"."

    I "Go back to your friends."

    scene fangtalkingwithtrish with Dissolve(1)

    stop music fadeout 1.0
    pause 1
    play music "audio/OST/Beach Chill Out.ogg" fadein 1.0

    I "Huh.{w} She did.{w} I feel like I should say something."

    pause 1

    I "I notice that all this time my knees were weak and my arms were heavy."

    I "My feet carry me over the soggy grass as I look for somewhere else to be."

    I "On the side of the building is where I find sanctuary"

    stop music fadeout 1.0
    play ambient 'audio/effects/outdoor ambience.ogg' fadein 0.5 # public domain
    scene garden
    show anon neutral flip at scenter
    with fade

    I "It’s a small alcove of sorts."

    I "The pavement is cracked to bits and the shrubs surrounding it are overgrown."

    I "Even the bench,{w=0.3} cracked paint on rotted wood held between two concrete legs,{w=0.3} matched the ‘abandoned’ vibe of the place."

    I "It was perfect."

    I "I flop down on the wet bench and the violent crack from it makes my heart drop."

    I "Almost perfect but good enough."

    I "I feel a tightness in my chest,{w=0.4} and my lungs fight to draw air in."

    show anon sad flip with dissolve

    pause 0.5

    I "Head in my hands I can fully understand what I’ve done now."

    I "Six months in a new school."

    I "A year on my own in some rundown apartment in a town I know nothing about."

    I "All on my own."

    pause 1

    I "Three weeks."

    I "It took a day for me to want to change schools,{w=0.5} and three weeks to make it happen."

    I "And this is my life now for the next year.{w=0.8} I think back to my old man’s ultimatum."

    I "{i}Once the lease is done,{w=0.4} Anon,{w=0.4} either college or the service.{/i}"

    I "{i}{cps=*0.3}I don’t care which.{/cps}{/i}"

    pause 1

    show naomi silo at sleft
    show naser silo:
        yalign 0.1 xalign 0.9
    with Dissolve(2.5)

    unknown "{cps=*0.5}Would you happen to be Anon?{/cps}" #Naomi

    play sound "audio/effects/WoodSnap.ogg"
    hide anon with Dissolve(0.2)
    show naomi silo shocked
    with vpunch

    I "I look up.{w} The bench broke down."

    I "I lay on the ground,{w=0.4} ass hurt from hitting jagged concrete and splintered wood."

    I "Thank god for jeans."

    stop ambient fadeout 0.5
    pause 0.5

    #TODO: does the audio work with the new ambience?
    scene pathetic at Pan((0, 1031), (0, 0), 10.0) with dissolve

    play music 'audio/OST/Dragging on and on....ogg'

    unknown "Oh my goodness!{w=0.75} Are you okay?"

    I "I groan"

    A "{cps=*0.35}Never better{/cps}"

    I "I instinctively apply my ‘chill guy’ facade in the presence of strangers to hide how uneasy I am today."

    I "A hand is held over my face.{w=0.5} In my pain addled confusion I shake it."

    unknown "Naser!"

    Nas "Right,{w=0.3} right"

    scene garden
    show naser neutral flip:
            yalign 0.1 xalign 0.9
    show naomi neutral at sleft
    with dissolve

    I "The hand tightens around my own and pulls roughly."

    #Documentation on MoveTransition : https://git.snootgame.xyz/Cavemanon/SnootGame/wiki/Tips#MoveTransition
    show naser neutral flip at nmidright with MoveTransition(0.5, time_warp=_ease_in_time_warp)

    show anon neutral at acenter with dissolve

    I "The force is enough for my feet to get under me,{w=0.4} stumbling back up to stand before the pair of strangers."

    I "It also felt like enough force to pull my arm out of its socket."

    show anon neutral at acenter

    A "Uh{cps=*0.1}...{/cps}{w=0.4} 'Sup?"

    Nas "You're Anon,{w=0.4} yeah?"

    unknown "I'm glad we found you!"

    A "...Who are you guys?{w} Why do you know my name?"

    show anon neutral flip at acenter behind naser with dissolve

    unknown "Where are my manners!{w=0.6} My name is Naomi,{w=0.4} student council president and your guide.{w=0.6} It’s my sincere pleasure to make your acquaintance Anon!"

    show naomi neutral at sleft
    hide naomiSilo
    with dissolve

    show anon neutral with dissolve

    Nas "We’re your welcoming committee."

    A "O{w=0.3}-kay then."

    I "{cps=*0.5}Is that really necessary?{/cps}"

    show naomi explanatory

    N "I had this prepared just for you!"

    show anon neutral flip with dissolve
    show naomi neutral at scloserleft with MoveTransition(0.4, time_warp=_ease_in_time_warp)
    show naomi neutral at sleft with MoveTransition(0.4, time_warp=_ease_in_time_warp)

    I "The orange one,{w=0.3} Naomi hands me a brochure."

    I "{i}\"Volcano High and You:{w=0.5} A New Beginning to Adulthood.\"{/i}"

    I "The title alone makes me gag.{w=0.7} The pink one,{w=0.4} Naomi,{w=0.4} looks at me expectantly."

    I "The brochure is full of the typical trivialities."

    I "College prep,{w=0.5} financial assistance,{w=0.5} after school programs."

    I "None of it matters."

    show naser considering flip:
        xalign 1.0 yalign 0.1
    with ease

    Nas "Babe,{w=0.4} I’ve got some things to take care of."

    I "Naser looks back to the school entrance.{w=0.5} I follow his eyes and see some people trying to lift a large speaker up the stairs of the school."

    show naomi sad

    N "O-oh."

    N "I’ll see you at lunch,{w=0.4} right Naser?"

    I "She looks dejected."

    show naser happy flip

    Nas "*chuckles*{w=0.4} Of course."

    show anon at aright
    show naser happy flip:
        xalign 0.05 yalign 0.1
    with MoveTransition(0.75, time_warp=_ease_in_time_warp)

    show naomi:
        easein 0.5 xalign 0.02

    I "Naser pulls her into a hug and nudges his muzzle against hers.{w=0.6} Is that how dinos kiss?"

    hide naser
    show anon neutral
    with Dissolve(0.75)

    I "He leaves,{w=0.3} running quickly to assist with the heavy sound equipment."

    pause 1

    N "ahem"

    show naomi neutral
    show anon neutral flip
    with dissolve

    I "I turn back to Naomi.{w=0.6} She smiles again,{w=0.4} though there is a plasticity to it."

    #TODO: extra scene content goes here

    show naomi explanatory

    N "How about I show you the campus,{w=0.3} Anon?{w=0.6} We wouldn’t want you getting lost on your first day, now would we?"

    show naomi neutral

    A "Mm,{w=0.5} sounds good."

    scene hallway
    show naomi neutral at sleft
    show anon neutral flip at aright
    with fade

    # play music 'audio/OST/Dragging on and on....ogg' # already playing
    play ambient 'audio/effects/school loop.ogg' fadein 0.2

    I "Instead of using the main entrance Naomi led me to a side entrance.{w=0.7} Inside, the school looked like your stereotypical school hallway."

    I "Lockers and posters along the walls.{w=0.5} Doors interspersed equally all the way down.{w=0.5} More students milling about before class."

    N "Anon,{w=0.3} may I see your class schedule?"

    I "I pull the folded up sheet from my pocket and hand it to her.{w=0.6} She unfolds it delicately and scans the page thoroughly."

    show naomi happy with Dissolve(.2)

    N "Oh my gosh!{w=0.6} We share a home room Anon!"

    show naomi neutral with Dissolve(.25)
    pause 0.5

    I "{cps=*0.4}Oh wonderful.{/cps}"

    show naomi explanatory

    N "Speaking of,{w=0.3} class will be starting shortly.{w=0.5} Follow me.{w=0.5} Mr. Tsuki’s classroom is this way."

    show naomi neutral
    # play music 'audio/OST/Dragging on and on....ogg' # already playing, was it supposed to be silent for a bit here?
    scene black with fade

    #TODO: extra scene content ends here

    I "I follow after her to a classroom on the 2nd floor.{w=0.5} The seats were being filled with students.{w=0.5} I take one near the front,{w=0.3} knowing I’ll have to introduce myself.{w=0.5} I’ll probably be doing that for all my classes."

    I "{cps=*0.4}Fuck my life.{/cps}"

    scene classroom with fade

    stop ambient
    play sound "audio/effects/bell.ogg"
    pause 3.0

    show anon neutral flip at aright with dissolve

    I "The artificial ring of a bell blares from a speaker on the wall.{w=0.5} With it everyone waits as the teacher finally enters the room and shuts the door."

    show jinflip at sleft with dissolve

    Tsuki "{cps=*0.6}Ohayo gozaimasu curassu.{w=0.7} Tudei yu habu e niu curassu-meito tsu Borukeino Hai{/cps}"
    pause 0.6

    I "What"

    Tsuki "{cps=*0.6}Anon-kun{w=0.25} puriizu camu appu zen intorudiusu yooru serfu{/cps}"
    pause 0.5

    I "Naomi coughs and makes a subtle nod up."

    stop music fadeout 1.0
    pause 0.8

    I "OH!"

    I "I stood from my seat and faced the class.{w=0.5} Once again all eyes on me and the tightness in my chest returns.{w} I inhale deep,{w=0.3} willing my erratic heart to slow."

    show anon neutral flip at acenter
    show jinflip behind anon:
        xalign -0.2 yalign 0.0
    with ease
    show anon neutral at acenter with dissolve

    A "Hey{cps=*0.1}...{/cps}"

    I "Again those eyes,{w=0.4} just like three weeks ago."

    A "My name is Anon.{w=0.6} I uh{cps=*0.1}...{/cps}"

    I "Just like every day for the past four months."

    A "I don’t really have any hobbies."

    I "I wanted to flee.{w} Hide away.{w} Anything to avoid those judging eyes."
    pause .5

    N "{cps=*0.4}Why did you transfer here?{/cps}"

    show dimmer_darker behind anon with Dissolve(1)

    I "My throat clenches.{w} It’s an innocent question.{w=0.5} But I think back again to it all."

    A "uh{cps=*0.2}...{/cps}{w=0.4} I{cps=*0.2}...{/cps}"

    #TODO: suitable menacing ambience or music

    I "There’s whispers now.{w} The hushed tones,{w=0.4} silenced snickers,{w=0.4} blending with the everpresent stares.{w} My heart hammers at my chest and I am sure that they all can hear it.{w=0.5} See the cold chill racing over me."

    show dimmer_darker behind anon, jinflip with dissolve

    Tsuki "{cps=*0.6}Anon-kun,{w=0.5} yuu du natto habu tsu ansaa zattu{/cps}"

    hide dimmer_darker with Dissolve(0.25)
    pause 0.5

    I "His words snap me out of my trance.{w=0.5} Only Naomi was looking at me.{w=0.4} The rest were preoccupied."

    I "Either talking about their winter break.{w=0.4} Or catching up on sleep."

    I "They’ve all been ignoring me the entire time."

    show jinflip:
        xalign -0.1 yalign 0.0
    with ease

    Tsuki "{cps=*0.6}Puriizu retaano tsu yo shiito,{w=0.3} Anon-kun.{w=0.5} {i}Hai{/i},{w=0.3} nao curassu-{/cps}"
    pause 0.5

    I "{cps=*0.5}That was nothing like my Japanese animes.{/cps}"
    pause 0.5

    hide anon neutral with dissolve

    I "Mr. Tsuki continued on,{w=0.3} drawing what little attention there was to himself.{w} I sat down,{w=0.4} finally feeling the blood that had caught in my legs rush up,{w=0.2} leaving me lightheaded."

    hide jinflip with dissolve

    I "And I probably have to do this for each class today?"

    I "Double fuck my life."

    scene black with fade

    I "Awkward introduction after awkward introduction to classmates that couldn’t care less kept me anxious the whole morning."

    I "And there’s still the rest of the day to go."

    scene cafeteria
    show anon neutral at aleft
    with dissolve

    play ambient 'audio/effects/chatter loop.ogg' fadein 1.0

    I "Eventually,{w=0.4} lunch comes around."

    I "I don’t have a lunch card yet,{w=0.3} so I settle for the pseudopizza."

    I "The kind that becomes a viable weapon if you leave it alone for ten minutes."

    I "No time to waste after exiting the line,{w=0.2} I scan the lunchroom for an open seat."

    I "I thought I had found a decent spot in the corner when disaster struck."

    #TODO: confirm if 2D flipping is OK when done for comedy occasionally
    #TODO: SFX of some kind
    show naser neutral behind anon with easeinleft:
        xalign -0.6 yalign 0.1
    stop ambient fadeout 0.25
    show anon fear:
        xalign 0.6 yalign 0.1
        easein 0.5 xzoom -1
    show naser neutral:
        easein 0.5 xalign -0.2
    with MoveTransition(0.5, time_warp=_ease_in_time_warp)
    show anon fear flip:
        xzoom 1

    I "Said disaster was a hand grabbing my shoulder and turning me about."

    I "My plate of pizza shaped cardboard threatened to smear across my shirt."

    I "I fought the momentum of the tray until the hand that had spun me stabilized it and me."

    play ambient 'audio/effects/chatter loop.ogg' fadein 0.5

    show anon sad flip behind naser with Dissolve(0.25)
    pause 0.8
    show naser explanatory
    with Dissolve(0.25)

    Nas "Whoa there!{w=0.6} Nearly dropped your food Anon."

    show naser happy
    show anon neutral flip
    with dissolve

    A "Yeah,{w=0.4} whose fault is that?"

    show naser considering with Dissolve(0.25)

    pause 1.5

    show naser explanatory with Dissolve(0.2)

    Nas "...Yours?{fast}"
    pause 0.5

    I "I swear to all that is good and holy."

    show naser happy with Dissolve(.25)
    pause 0.5

    Nas "Wanna sit with us?"

    A "What?"

    Nas "Wanna sit with Naomi and me?{w=0.7} Since you’re new and all."

    I "He points to a table where the living pink sugar rush is waving."

    I "God damn it."

    I "I don’t want to make a scene."

    A "{cps=*0.25}Suuuure{/cps}{cps=*0.1}..{/cps}"

    #TODO: music variation
    stop ambient fadeout 0.25
    play music 'audio/OST/Dragging on and on....ogg'

    scene cafeteria
    show anon neutral at aleft
    show naomi neutral flip at sright
    show naser neutral flip behind naomi:
      xalign 0.7 yalign 0.1
    with fade

    I "Before I even sit down the barrage of questions begins."

    show naomi explanatory flip:
        ease 0.18 yalign 0.05
        ease 0.35 yalign 0.0
        repeat

    N "SO!{w=0.5} What do you think of Volcano High!{w=0.3} How about your classes?{w=0.3} You seem-"

    I "I just nod along,{w=0.3} starting to not pay attention."

    show naomi neutral flip at sright with ease

    Nas "You looking forward to the rest of the day?"

    A "Not really."

    A "All these introductions,{w=0.2} you know?"

    Nas "I get you,{w=0.5} hard to talk to people you don’t know,{w=0.2} right?"

    A "Something like that,{w=0.4} yeah."

    A "Hell,{w=0.4} last period I tripped in front of everyone.{w=0.6} Talk about a first impression."

    show naser happy flip

    Nas "I don’t think they’d care too much."

    show naomi explanatory flip

    show naomi explanatory flip:
        ease 0.18 yalign 0.04
        ease 0.35 yalign 0.0
        repeat

    N "Have you had any trouble since then?{w=0.5} Do you have enough money for food today?"

    show naomi neutral flip at sright with ease

    show naomi neutral flip
    show naser neutral flip
    with Dissolve(0.25)

    Nas "Oh,{w=0.25} you’re short on food money man?"

    # TODO: temporarily commented out as this seems to be repeated with different wording a moment later. Intentional?
    # show naser flip unimpressed
    # show naomi flip sad
    # with dissolve

    # "I perk up at Naser’s interjection. Naomi looks disappointed for a second."

    # A "Not really,{w=0.4} just had to sign up for some handouts."
    A "Not really,{w=0.4} just had to sign up for some handouts."

    show naomi sad flip with dissolve

    I "Naomi is starting to look disappointed I’m only picking up on Naser’s interjections"

    Nas "If you need a bit more extra chow,{w=0.3} there’s going to be free refreshments at my si--{w=0.4} uh{cps=*0.1}...{/cps}"

    show naser considering flip with Dissolve(0.25)
    pause 0.75
    show naser neutral flip with Dissolve(0.25)
    pause 0.5

    Nas "At Fang’s concert after school today"

    A "Your what?"

    Nas "Fang"

    A "Your brother or{cps=*0.2}...?{/cps}"
    pause 0.5

    Nas "{cps=*0.1}...{/cps}{cps=*0.3}Sibling.{/cps}"

    I "What."

    show naomi neutral flip with dissolve

    Nas "Fang’s gonna have some extra pizzas for the show.{w=0.5} You could take some home."

    A "I uh{cps=*0.1}...{/cps} dunno about concerts.{w=0.6} Not really one for public events like that."

    show naser unimpressed flip

    Nas "Alright man,{w=0.4} just thought you could use a few opportunities to make friends."

    I "What was that?"

    I "I’ll pretend that wasn’t meant to be malicious."

    show naser neutral flip

    A "{cps=*0.5}I’ll consider it.{/cps}"

    show naomi explanatory flip:
        easein 0.4 xalign 0.9
    
    N "Hey!{w=0.4} Don’t leave me out of the conversation!"

    show naomi happy flip with dissolve

    N "How about I help you pick out some cheap food after school?"

    N "I know some great vegan shops in the area!"

    I "My stomach roils at the V-word."

    A "{cps=*0.25}Maaaaybe{/cps} another time,{w=0.2} sorry.{w=0.6} So about that concert Naser?"

    show naomi sad flip with dissolve
    pause 0.5

    I "Dinner and a show?{w=0.5} Sign me the fuck up." #TODO: Anon "signs the fuck up" twice

    show naomi neutral flip with Dissolve(.25)

    A "So what do they play?"

    Nas "Music."

    A "Music?"

    Nas "Yes."

    A "What kind?"

    Nas "The kind you listen to."

    A "Wh-{w=0.3} Well what genre?"

    show naser considering flip with dissolve
    Nas "The good kind?"

    A "You don’t know,{w=0.3} do you."

    show naser neutral flip
    Nas "Nope."

    I "Well,{w=0.3} free food is free food.{w=0.5} Sign me the fuck up"

    I "I look at my pizza,{w=0.3} noticing something is wrong."

    I "I test it with my plastic spork and watch the cheap utensil shatter to bits."

    I "I curse life for a third time today."

    I "The dreaded ten-minute mark has passed,{w=0.35} rendering my ‘pizza’ only useful as building material."

    show naomi happy flip with Dissolve(0.25)

    N "{cps=*0.3}Oh dear.{/cps}{w=0.6} Naser why don’t you split your sandwich with him?"

    show naser annoyed flip with Dissolve(0.25)

    Nas "But it’s my sandwich!"

    N "It’s fine,{w=0.3} we can split my vegan TLT!"

    show naser sad flip with dissolve

    I "Naser shudders and looks at his own footlong philly sub longingly."

    Nas "S{w=0.2}-sure thing,{w=0.3} babe."

    window hide

    show naomi neutral flip with dissolve
    show naser:
      easein 0.2 xalign 0.62
      pause 0.75
      ease 0.75 xalign 0.4
    pause 2

    I "He tears the sandwich in two and hands me the larger half."

    Nas "Here,{w=0.35} Anon."

    show naser sad flip behind naomi:
        easein 1 xalign 0.7
    pause 1.2

    I "I will never forget your brave sacrifice."
    pause 0.5

    I "With that we all dig into our meal."

    I "..."

    scene black with fade

    I "{cps=*0.2}--After school--{/cps}"
    pause 0.8

    I "My classes after lunch were the same as before it."

    I "By now I had a rehearsed introduction that only the teacher cared about."

    I "My classmates were disinterested and I would sit down to be forgotten."

    I "I hope the rest of the year is just like that."

    I "I just want to skate through it all."

    I "All that’s left for today is the concert.{w=0.5} And dinner."

    scene door auditorium
    show naser neutral:
        xalign 0.0 yalign 0.1
    show anon neutral flip at aright
    with fade

    I "I wait outside the auditorium entrance with Naser,{w=0.3} who was checking his phone for messages."

    Nas "Right,{w=0.3} Fang says the show is starting in a bit.{w=0.5} See?"

    show naser:
        easein_quad 0.5 xalign 0.4

    I "Naser turns the screen to me."

    window hide
    show fuckedwingretard with dissolve
    pause 2.0

    I "Fang:{fast} Piss off."

    I "Fang:{fast} Is the pizza here?"

    I "Fang:{fast} You can have a slice"
    pause 0.75

    I "Fang:{fast} But after that you{w=0.1} {cps=*0.15}GTFO{w=0.3} FWR{/cps}"

    window hide
    pause 1

    hide fuckedwingretard with dissolve

    show naser:
        xalign 0
    with ease
    pause 0.5

    A "{cps=*0.15}FWR?{/cps}{w=0.6} Like,{w=0.4} Franklin W. Roosevelt?"

    Nas "Nah.{w=0.6} Fucked wing retard.{w=0.7} Fang’s words,{w=0.3} not mine."

    A "Is your uh{cps=*0.1}...{/cps}{w=0.3} sibling{w=0.4} always like this?"

    Nas "{cps=*0.4}Fang’s{/cps}{cps=*0.1}....{/cps}"

    show naser considering with Dissolve(0.25)

    I "I wait for him to continue."

    Nas "Well um{cps=*0.1}...{/cps}"

    Nas "I mean,{w=0.4} kinda?"
    pause 0.8

    A "Glad I’m an only child."

    show naser angry with dissolve

    I "Naser glares at me."
    pause .5

    Nas "Fang’s still family.{fast}"

    A "Ah,{w=0.4} sorry.{w=0.7} Just saying is all."

    show naser sad with dissolve

    I "Naser deflates."

    Nas "You’re good,{w=0.3} Anon.{w=0.8} And yeah,{w=0.4} they’re family{w=0.3} but Fang’s just so{cps=*0.15}...{/cps}{w=0.5} so{cps=*0.15}...{/cps}"

    A "Difficult?"

    show naser explanatory with Dissolve(0.25)

    Nas "YES!{w=0.4} Difficult!{w=0.6} And I don’t know why."

    A "Sounds rough."

    show naser considering with dissolve

    Nas "It is.{w=0.7} Like,{w=0.3} I know sh-{w=0.6} THEY care{w=0.7} but Fang doesn’t even wanna be around me."

    A "{cps=*0.25}Hmmm.{/cps}"

    I "Finally the doors open and I smell the cheesy,{w=0.3} heart clogging goodness within."

    show naser happy with dissolve

    Nas "Sweet.{w=0.6} Come on, Anon."

    hide naser with dissolve

    stop music fadeout 1.0

    I "{cps=*0.6}A caveman of a man holds open the door for everyone.{/cps}"

    show anon:
        easeout_quart 1.0 xalign 0.5

    pause 1

    play music 'audio/OST/we just turned on the microphone in our programmers_ house.ogg'

    unknown "Wait.{fast}"

    I "His massive hand stops me."

    A "A{w=0.2}-ah.{w=0.5} Y-yes?"

    I "I’m guided to the side,{w=0.4} away from the crowd that’s filtering into the auditorium."

    show spears neutral at sleft with Dissolve(1.5)

    unknown "So how are you feeling about our lovely school,{w=0.3} Anon?"

    show anon:
        xalign 0.55
    with ease

    A "{cps=*0.1}Uh...{/cps}"

    I "It’s the spear-shaped pin on his lapel that reads ‘principal’ that informs me of who this giant is."

    A "O{w=0.1}-oh!{w=0.4} It’s uh{cps=*0.2}...{/cps}{w=0.3} nice?{w=0.5} Cleaner than my old school."

    I "He guffaws and slaps his chest."

    show spears happy

    Sp "You can thank your classmates for that."

    I "What?"

    show spears neutral

    Sp "Now,{w=0.3} go enjoy the show."

    A "Yes sir."

    Sp "Oh,{w=0.4} I do need you to come by my office tomorrow for some paperwork."

    I "I nod and go back to the door where Naser is standing,{w=0.3} holding it open for the last of the audience to go inside."

    stop music fadeout 1.0

    scene auditorium
    show anon neutral flip at aright
    show naser neutral at nleft
    with fade

    play ambient 'audio/effects/chatter loop.ogg' fadein 1.0

    I "Naser leads me and the large crowd into the shitty school theater."

    I "The foyer has tables with boxes of pizzas stacked taller than me."

    show naser happy

    Nas "You can take a couple boxes after,{w=0.1} Anon.{w=0.6} That should help ya out."

    A "Who the hell got all these anyway?"

    Nas "I did."

    I "I take a box down from the stack.{w=0.3} Others have already started stacking their plates."

    I "I check the logo on the box."

    A "And to get so many larges from{cps=*0.2}...{/cps}{w=0.4} \"Dino-moe’s Pizza\"?"

    A "That’s a couple hundred bucks though."

    show naser unimpressed

    Nas "Meh,{w=0.4} ‘bout a month’s allowance."

    show naser neutral

    I "A month?{w=0.6} That explains that disaster of a jacket."

    A "So about the actual show-"

    Nas "I’ll check on them.{w=0.5} Be right back."

    hide naser with dissolve

    I "Left on my own I stack my plate up with some quality grease topped delight."

    show anon:
        easein_quart 1.0 xalign 1.15 yalign 0.01
    pause 1.0
    # show anon neutral flip at sleft with move
    # show anon neutral at aleft with dissolve

    I "I lean against the wall,{w=0.2} chewing bits of supreme and observing the rest of the crowd."

    show dimmer_light behind anon with dissolve

    unknown "{cps=*0.6}-nother shitshow-{/cps}"

    unknown "{cps=*0.6}She’s so stupid-{/cps}"

    unknown "{cps=*0.6}-they even bother?{/cps}"

    unknown "{cps=*0.6}Bunch of losers-{/cps}"

    hide dimmer_light with dissolve

    I "Everyone seems to share the same sentiment."

    I "So why the hell did they even show up for this?"

    I "Naser finally comes back and opens the door to the main hall."

    stop ambient fadeout 3.0

    I "The crowd moves in,{w=0.3} though I hang back so I can talk with Naser."

    show naser neutral at ncenter with dissolve

    A "What’s with them,{w=0.1} Naser?"

    Nas "What do you mean?"

    A "The crowd.{w=0.4} They were talking mad shit."

    show naser angry flip with Dissolve(0.25)

    Nas "{i}What?!{/i}{fast}"

    # VERY angry dinosaur vibrating at incredible high speed
    show naser angry flip:
        linear 0.05 xalign 0.595
        linear 0.05 xalign 0.605
        repeat

    I "Naser grasps at the air unsure what to think or do at the moment.{w=0.5} I think he’s angry"
    pause .5

    show naser at nleft with MoveTransition(0.4, time_warp=_ease_in_time_warp)
    play sound "<from 0.2 to 2.0>audio/effects/Slam.ogg" volume 2.2
    show naser table hit behind anon with vpunch
    pause 0.5

    show anon at aright with MoveTransition(0.25, time_warp=_ease_in_time_warp)

    A "Whoa{w=0.2} whoa."

    show naser angry flip with Dissolve(1)

    Nas "Ugh,{w=0.5} I should’ve known."

    show anon:
        easein_quart 1 xalign 0.75

    A "I don’t,{w=0.4} what are you talking about man?"

    show naser annoyed at nleft with dissolve

    window hide
    pause 1.0

    show naser angry with Dissolve(0.25)

    Nas "{cps=*0.5}I brought them here so Fang has an audience.{/cps}"

    stop music
    pause 1

    A "Oh."

    pause 1

    show naser considering with dissolve

    #TODO: find generic (or joke) cellphone ringtone
    play sound 'audio/OST/ringtone.ogg'

    I "Naser’s phone rings.{w=0.4} He moves aside to answer it."

    show naser flip neutral with Dissolve(0.25)

    hide naser with easeoutleft

    pause 0.5

    Nas "Fa-{w=0.6}{nw}"

    window hide
    with hpunch # TODO: some slapstick SFX would punctuate these interruptions

    pause 0.7

    I "The voice on the other end is loud and shrill."

    Nas "Yeah{w=0.2} I-{w=0.5}{nw}"

    window hide
    with hpunch

    pause 0.7

    I "He holds the phone away from his ear to save his eardrum."

    Nas "Okay okay I-"

    I "The call ends and Naser sags."

    show naser sad at nleft with easeinleft
    pause 0.5

    Nas "I’ve gotta leave."

    A "Seriously?"

    Nas "Yeah,{w=0.3} Fang doesn’t want me here.{w=0.6} Said I’ll ruin the show."

    I "Harsh."

    show naser neutral with Dissolve(0.25)

    Nas "Look,{w=0.5} whatever happens{w=0.3} promise you won’t hold this against them."

    Nas "They're actually a really a nice person once you get to know them"

    A "Naser why did you just murder the english language in cold blood?"

    I "Within I see the rest of the audience,{w=0.3} huddled in groups around tiny snack tables."

    show naser sad with Dissolve(0.25)

    Nas "Even went to the trouble of switching out the seats for them.{w=0.5} Naomi said it’d help."

    I "With a huff Naser turns away,{w=0.4} begrudgingly leaving the auditorium."

    hide naser with Dissolve(1.5)

    I "I enter the hall and take a seat in the back,{w=0.3} away from the rest of the crowd."

    scene black with fade
    play ambient 'audio/effects/chatter loop.ogg' fadein 2.0

    I "The lights dim and the curtains are drawn open."

    stop music fadeout 1.0  # TODO: was there meant to be music playing before this?

    scene fang band playing with Dissolve(2.0)

    I "Onstage is a trio of people my age."

    I "I think Fang is the drummer?{w=0.5} He doesn’t look related to Naser,{w=0.4} maybe it is the main front-woman?"

    I "That must be Naser’s sister."

    A "Wh-"

    I "Then why the whole confusion over her sex?{w=0.4} For fuck’s sake."

    I "I’m just getting thrown around today.{w=0.5} I don’t know."

    I "She looks familiar."
    
    stop ambient fadeout 1
    pause 1.0

    I "The band doesn’t bother introducing themselves."

    #also im convinced link related is the inspiration of song related
    #https://www.youtube.com/watch?v=Pbe9DkMyL8k

    I "Instead the purple one begins plucking her bass."

    I "It all went tumbling down from there."

    pause 0.5
    play music 'audio/OST/its_the_piece_of_shit_you_asked_for.ogg' volume 1
    with hpunch
    pause 2 

    I "What I thought was a guitar sounded horrifically wrong,{w=0.5} far too heavy."

    I "The lead guitarist was using a fucking bass."

    I "And then the vocals kicked in."

    I "It’s horrific screeching,{w=0.3} combined with the amelodious shredding on a bass created a cacophony equal to hundreds of cats ritualistically sacrificed."

    I "I fight the urge to cover my ears."

    I "I don’t know too much about music,{w=0.4} but even I know that you don’t use two basses in one band unless you know exactly what you’re doing."
    pause 0.7

    I "{cps=*0.3}Ooooooh nooooooo.{/cps}"

    I "{cps=*0.3}Ooooooooh{/cps} God."
    pause 0.5

    I "What were they thinking?!{fast}" with vpunch

    I "I looked back to the crowd to gauge their interest."

    I "Surely I’m not alone in thinking this is an absolute travesty."
    pause 0.7

    stop ambient fadeout 1
    stop music fadeout 2
    unknown "{cps=*0.5}PFFFT AHAHAHA{/cps}{w=0.5} THEY STILL FUCKING SUCK!!"

    play music 'audio/ost/Many Such Cases Of Being So True.ogg'
    # TODO: find suitable jeering loop
    # play ambient 'audio/effects/chatter loop.ogg' volume 2.5 fadein 1.0

    #(In-CG insult layers)
    window hide
    $ i = 0
    while i < 20:
      $ showCG()
      pause 1
      $ i = i + 1

    I "The crowd was standing,{w=0.3} jeering and laughing with whoever said that."

    I "More words were said but the laughter eclipsed them and the music."

    I "Wait,{w=0.4} what happened to the music?"

    I "On-stage,{w=0.3} the trio looked panicked."

    I "The drummer was inching off stage,{w=0.4} while the purple bassist was about to break down into tears."

    I "But the frontwoman stood there.{w=0.7} Stood her ground."
    pause 1

    #(In-CG insult layers)
    window hide
    $ showCG()
    #(In-CG insult layers)

    scene fang band screaming with vpunch

    unknown "{b}FUCK YOU!{/b}{fast}"

    I "She tossed her bass aside,{w=0.3} raising both hands and proudly displaying a finger on each of them."

    unknown "FUCK ALL OF YOU!"

    window hide
    pause 0.5

    unknown "NO ONE WOULD WANT TO FUCK YOU,{w=0.2} BITCH!"

    I "Pffft{cps=*0.2}...{/cps}{w=0.2} That struck a chord with her."

    #(In-CG insult layers)
    window hide
    $ i = 0
    while i < 5:
        $ showCG()
        pause 1
        $ i = i + 1
    
    I "I watch as she grabs her bass and takes the arm of the purple one,{w=0.3} rushing off stage with the pink drummer."

    scene black with fade

    window hide
    $ i = 0
    while i < 3:
        $ showCG()
        pause 1
        $ i = i + 1

    I "Oh God I can’t take this,{w=0.3} I’m gonna grow a 6 pack from laughing so much,{w=0.5} I’m just gonna grab my pizza and leave"

    play ambient 'audio/effects/chatter loop.ogg' fadeout 1.0 fadein 0.25
    scene auditorium
    show anon neutral flip at aright
    show spears neutral at sleft
    show dimmer_darker behind anon, spears
    with fade

    stop music fadeout 1
    play music1 'audio/ost/you can_t sage here.ogg' fadein 1

    I "I turn towards the door and see Principal Spears,{w=0.4} a fierce glare freezing me in place."

    pause 0.5

    Sp "Anon.{fast}"

    pause 0.5

    I "{cps=*0.2}Oh fuck{/cps}"

    I "His voice is even more stern than this morning."

    A "Yes sir?"

    I "He looks to the crowd and then to me."

    Sp "I don’t want to hear about any of this come tomorrow."

    Sp "I expect some goddamned maturity from you,{w=0.3} Anon."

    Sp "You’ll be an adult once you graduate."

    A "Uh{cps=*0.1}...{/cps}{w=0.3} Why me though?"

    Sp "I’ve taught many students,{w=0.4} and I can tell these things."

    show spears:
        easein_quad .8 xalign 0.5
    pause 1.0
    show anon fear flip:
        easein_quart 0.25 yalign 0.05
        pause 0.1
        easein 0.5 yalign 0.1
    pause 1

    I "His hand lands on my shoulder."

    I "It’s grip was firm as it weighed on me."

    show anon neutral flip with Dissolve(1)

    Sp "Listen here,{w=0.3} Anon.{w} {cps=*0.6}You are not the only person in the world.{/cps}"

    Sp "Everyone’s fighting their own battles."

    I "The hand squeezes before pushing me towards the door."

    show anon neutral at aright with Dissolve(0.25)

    show spears:
        xalign 0.6
    show anon:
        xalign 1.1
    with MoveTransition(0.5, time_warp=_ease_in_time_warp)

    Sp "I want to see you in my office first thing tomorrow."

    Sp "Now get out of here,{w=0.4} this is the only warning that you’ll get from me."

    Sp "Next time it will be campus clean-up."

    stop music1 fadeout 0.5
    hide anon with Dissolve(1)

    show spears neutral flip with Dissolve(0.25)

    I "Behind me the principal’s voice shakes the room."

    stop ambient fadeout 0.2
    show spears angry flip with Fade(.1, 0, .25, color="#fff")
    play sound "audio/effects/spearYellVoice.ogg"
    with vpunch

    Sp "{b}{cps=*0.5}WHOSE SORRY ASS AM I GOING TO HAVE TO SUPLEX!{/cps}{/b}" # TODO: volume boost, renpy volume multiplier sucks and makes this clip

    pause 0.5

    play ambient 'audio/effects/school loop.ogg' fadein 0.5

    scene hallway
    show anon neutral at acenter
    with fade

    I "Back in the foyer I see some boxes of partially finished pizza left."

    I "I consolidate them all into a pair of boxes and make my exit."

    stop ambient fadeout 1.0

    scene outside school
    show anon neutral at acenter
    with fade

    I "The sun is starting to set now as I make my way home."

    play music 'audio/OST/Skinrow Soul.ogg' fadein 1.0

    pause 1

    Sp "{i}{cps=*0.6}You are not the only person in the world.{/cps}{/i}"

    I "Pfft.{w=0.5} Like I don’t already know that.{w=0.4} There’s like{cps=*0.2}...{/cps}"

    I "The classmates that all ignored me today."

    I "Naomi’s annoying ass."

    I "That fucking caveman of a principal."

    I "Naser,{w=0.4} whose been a bro."

    I "Naser’s Sis-"

    stop music fadeout 1
    pause 0.5

    I "Oh."

    I "Shit."

    I "{cps=*0.1}...{/cps}"

    scene black with fade

    #Meeting the Band
    I "{cps=*0.2}--The Next Day--{/cps}"

    pause 0.5

    play sound "audio/effects/digital_alarm.ogg" # CC0

    I "{cps=*20}{w=0.4}*BLEEP*{w=0.5} *BLEEP*{w=0.5} *BLEEP*{w=0.5} *BLEEP*{w=0.5} *BLEEP*{w=0.5} *BLEEP*{/cps}"

    stop sound fadeout 0.2

    scene room anon dark with Dissolve(2.5)
    play music "audio/OST/Beach Chill Out.ogg"

    I "The bane of all sleep echoes violently by my head,{w=0.3} swiftly erasing any traces of slumber."

    I "Still without the energy to turn the alarm off,{w=0.3} I stare at the ceiling for a bit,{w=0.4} recalling the events of the last few days as an exercise."

    I "The school,{w=0.3} if you could call it one."

    I "My new friends,{w=0.3} if you could call them that."

    I "That band,{w=0.3} if you could call it such."

    I "Great idea Anon,{w=0.4} start the day by dissing everything you've done so far in your new life."

    I "No wonder you're so damn popular."

    I "Finally,{w=0.4} I lean out of bed and turn the alarm clock off."

    I "I have a good forty-five minutes before I need to be at school,{w=0.4} and it takes twenty to walk."

    I "That leaves twenty-five minutes to get ready."

    I "With practiced movements I execute a proper combat roll from bed,{w=0.4} tackling the floor and headbutting it into submission."

    play sound "<from 0.2 to 2.0>audio/effects/Slam.ogg" volume 1.8

    I "With practiced movements I execute a proper combat roll from bed, tackling the floor and headbutting it into submission.{fast}{w=0.6} My foe defeated,{w=0.3} I groan in victory." with vpunch

    pause 0.8

    I "My new bed is half the size of what I’m used to."

    I "The hardwood{w=0.2} (or is it vinyl?){w=0.2} floor is cold as hell."

    I "From the purview of the floor,{w=0.4} I look around my room again."

    window hide
    pause 1.5

    I "A tiny one room apartment with only a computer,{w=0.3} bed,{w=0.3} television,{w=0.3} and fridge."

    I "A whole year in this shithole."

    I "{cps=*0.2}...{/cps}{w=0.2} Guess I gotta take it one day at a time."

    show anon neutral at acenter with dissolve

    I "Picking myself up, I slide into todays’ (and everydays’) clothes and pour myself a bowl of off-brand cereal I picked up the day before."

    I "My eyes scan over my phone while I shovel my sugary breakfast into my mouth."

    I "*Scroll*{fast}"

    I "*Crunch*{fast}"

    I "*Scroll*{fast}"

    I "*Crunch*{fast}"

    I "Like a poorly oiled machine until it runs out of fuel with a noisy slurp."

    I "Soon enough it's time to leave for school.{w=0.5} I grab my backpack and slide it over my shoulders.{w} I take my jacket off the hanger and"

    show anon unimpressed with dissolve

    I "{cps=*0.1}...{/cps}"

    I "I take off the backpack and put the jacket on.{fast}"

    stop music fadeout 1
    pause 1
    scene black with fade

    # TODO: resolve accidental time warp? Anon has only been at school for a day here
    # "Opening the door blows the cool morning air in my face, and I stop to take a deep breath."
    # scene skinrow
    # show anon neutral at aleft
    # "Day four out of however many days are left in the year. So far so good."
    # scene outside school
    # show anon neutral at aleft

    play music 'audio/OST/Appreciating the Atmosphere.ogg'
    show outside school fog with fade

    I "I approach the grand building,{w=0.3} looking to find a place in line between the other students trundling into the front doors."

    I "The halls before class are as crowded as always,{w=0.4} hundreds of students filing in unison towards their homerooms."

    I "By now I was starting to be able to make my way around on autopilot,{w=0.5} I've walked the same path twice already after all."

    I "Even after the longest sleep of my life,{w=0.4} I still feel miserably tired and ready to crash once again."

    I "I found another entrance at the side of the school that has less students on it.{w=0.4} The less the merrier."

    I "I check my clock once again -{w=0.3} I’m early.{w=0.5} Fucking hell.{w} Should have shitposted a bit more."

    stop music fadeout 1
    pause 1

    I "Why am I here so early again?"

    I "Think I had to do something."

    play music 'audio/OST/The Hunt for more (You)s.ogg' fadein 0.1

    I "Oh yeah."

    I "I should talk to Naser.{w=0.5} Give him my version of events."

    I "That way he won’t kick {i}my{/i} ass."

    I "Wait."

    I "Oh goddamn it."

    I "The principal also wanted to see me.{w=0.5} Shit,{w=0.3} probably gonna get some demerit or whatever rich schools do as punishment."

    I "I had almost forgotten."

    I "Please Raptor Jesus just let this be the last time I need to deal with stuff like this."

    I "Get it over with so I can finally just slip my way through this year."

    menu:
        "Naser's a bro":
            # affects dialogue with Spears when entering his office
            $ late_to_spears = True
            jump .naserBro
        "I don't wanna piss off the caveman.":
            $ late_to_spears = False
            jump .pissOffCaveman

    # Anon tries to find Naser before heading to Spear's office
    label .naserBro:

    I "Principal caveman can wait.{w=0.4} I want to apologize to Naser about yesterday{cps=*0.1}...{/cps}"

    I "I hope I can be nice to him this time."

    I "Great job,{w=0.3} Anon!"

    I "He saves you from soy poisoning by sacrificing his footlong,{w=0.4} and how do you repay him?{w=0.6} By laughing at his sister."

    I "There he is,{w=0.4} I hope he’s not too busy."

    I "..."

    I "I just realized I don’t know what to say to him"

    I "\"I wasn’t laughing AT your sister,{w=0.4} I was laughing WITH the crowd\""

    I "No,{w=0.3} that sounds bad"

    I "\"Weird sisters,{w=0.2} amirite?\""

    I "I might be retarded.{w=0.5} I just told him I’m an only son yesterday."

    I "\"Can’t help it,{w=0.1} dude.{w=0.5} Some people just won’t amount to anything in life.{w=0.5} Sorry.\""

    I "This isn’t time to be edgy,{w=0.2} Anon."

    I "As I try and fail to find some way to explain myself to Naser I also fail at actually finding Naser."

    I "How the fuck did I even end up in the tard yard?"

    window hide

    pause 0.5

    stop music fadeout 1.0
    scene hallway with fade

    I "After what feels like a space decade of walking,{w=0.4} or really just half an hour,{w=0.4} I find the crippled pteradon being accosted by a {cps=*0.1}VERY{/cps} pissed off purple midget."

    play music 'audio/OST/That Monochromatic Weirdo.ogg' fadein 0.5

    # show trish angry at tleft
    show trish angry:
        yalign 0.0
        linear 0.05 xalign 0.005
        linear 0.05 xalign 0
        repeat
    show naser neutral flip:
        yalign 0.1
        xalign 1.3
    with Dissolve(1.5)

    unknown "{cps=*0.4}-SAID YOU INVITED ALL THOSE ASSHOLES!{/cps}" #trish

    show naser explanatory flip

    Nas "Wait,{w=0.3} Trish,{w=0.4} you don’t understand-!"

    show naser

    show trish at sleft

    T "DON’T CUT ME OFF YOU GRAY PIECE OF SHIT!" with vpunch

    show naser unimpressed flip with dissolve

    I "Students are clearing out of the way,{w=0.4} just trying to get to their classes."

    I "This must be a common occurrence."

    show trish:
        easein_quart 0.5 xalign -0.05
        pause 0.5
        easein_quart 0.5 xalign -0.175

    pause 1.5

    I "The diminutive triceratops,{w=0.4} Trish,{w=0.4} bows her head and charges Naser."

    show trish fury with Dissolve(0.25):
        yanchor 0
        ypos 0.35
        easeout_quart 0.6 xalign 0.4

    pause 0.3

    show naser handout flip behind trish:
        easein_quart 0.2 xalign 1.45
    show trish:
        easein_quart 0.2 xalign 0.45
    with hpunch

    pause 1

    I "He just holds a hand out to her forehead."

    # 0.5
    show trish:
        easeout_quart 0.2 xalign 0.46
        pause 0.3
        easeout_quart 0.2 xalign 0.48
        pause 0.2
        linear 0.5 xalign 0.45
        pause 0.4
        repeat
    # 1.45
    show naser:
        easeout_quart 0.2 xalign 1.475
        pause 0.3
        easeout_quart 0.2 xalign 1.5
        pause 0.2
        linear 0.5 xalign 1.45
        pause 0.4
        repeat

    T "GET YOUR HANDS OFF ME!!" with vpunch

    Nas "Trish,{w=0.2} I’m not going to fight you again."

    Nas "The principal’s already gotten onto me about the lockers from last time."

    Nas "Believe me,{w=0.3} I had no idea the concert would have turned out like that."

    T "{b}LIAR!!{/b}" with vpunch

    Nas "I just wanted to make sure you guys had an actual audience-"

    T "WHAT ARE YOU SAYING?!?"

    Nas "You know what I mean,{w=0.4} come on{cps=*0.1}...{/cps}"

    T "Argh!"

    show trish angry at scenter with Dissolve(.25)
    show naser:
        xalign 1.6
    with ease
    show naser neutral flip with dissolve

    I "She stops trying to gore Naser and throws her arms to her sides."

    pause 0.5

    show trish:
        easein_quart 0.6 xalign 0.4

    T "Screw you!"

    show naser unimpressed flip with dissolve

    T "Even if you weren’t trying to mess with Fang!"

    T "Screw!{w=0.4} You!"

    I "She stomps off."

    stop music fadeout 1.5
    play ambient 'audio/effects/school loop.ogg' fadein 1.5
    hide trish with Dissolve(1.5)

    show naser annoyed flip with dissolve

    Nas "{i}*Sigh.*{/i}"

    show anon neutral at aleft with dissolve
    A "What was that all about?"

    show naomi considering flip behind naser with easeinright:
         xalign 0.6

    N "Oh,{w=0.3} Anon."

    show naomi neutral flip

    N "Don’t worry about it,{w=0.4} it’s nothing."

    show naser explanatory flip with Dissolve(0.25)

    Nas "Y’know,{w=0.5} girl issues,{w=0.2} right?{w=0.5} {cps=*0.15}Haha...{/cps}"

    pause 0.5

    A "{cps=*0.4}Sure...{/cps}"

    A "Sounds like she was grilling you about the concert."

    show naser sad flip with dissolve

    Nas "{cps=*0.1}...{/cps}"

    show naomi explanatory flip

    N "Some concert,{w=0.3} right?"

    show naomi neutral flip
    show naser neutral flip
    with dissolve

    A "Actually,{w=0.5} about that{cps=*0.1}...{/cps}"

    A "I,{w=0.3} uhh{cps=*0.1}...{/cps}"

    #TODO: play sound "audio/PANoise.ogg"
    pause 1

    show naomi shocked flip

    Sp "ANON MOUS,{w=0.4} IF YOU ARE NOT IN MY OFFICE WITHIN TEN MINUTES I SWEAR ON MY DEAR FAMILY I WILL PERSONALLY MOUNT YOU ON MY WALL." with vpunch
    #TODO: play sound "audio/PANoise.ogg"

    pause 1

    show naomi neutral flip with dissolve

    A "{cps=*0.1}...{/cps}"

    I "A layer of cold sweat makes its presence known."

    show naser considering
    with dissolve

    Nas "It can wait,{w=0.5} the office is down this hall on the right."

    A "I know the way,{w=0.3} but thanks."

    I "Naser waves and heads off."

    hide naser
    hide naomi
    with Dissolve(1.0)

    I "Guess it’s to the principal’s office with me.{w=0.3} Again."

    I "And thinking about him makes me think about last night."

    Sp "{cps=*0.6}{i}You are not the only person in the world.{/i}{/cps}"

    I "Poor Naser,{w=0.3} man.{w=0.5} Just wanted to help his sister."

    I "But it’s not like he did anything wrong."
    pause 0.5

    play music 'audio/OST/Those Other Two Weirdos.ogg' volume 0.8 fadein 3
    scene hallway
    show naomi unimpressed at sleft
    show reed neutral flip behind naomi:
        yalign 0.1 xalign 1.2
    with fade

    I "Just as I reach the office the sound of clinking glass draws my attention to the apricot asspain and some pink raptor."

    # TODO: music here for Reed's intro?
    show naomi angry with Dissolve(0.25)

    N "Is that contraband,{w=0.3} Reed?"

    show naomi unimpressed with Dissolve(.25)
    show reed explanatory flip

    Re "Bro,{w=0.4} you’ve known I’m in a band for like,{w=0.4} a year now."
    
    pause 0.6
    show reed neutral flip
    show naomi angry:
        easein 0.25 xalign 0.1
    pause 0.25

    N "No!{w=0.5} {cps=*.4}{i}Contra{/i}band!{/cps}{w=0.5} In your backpack!"

    Re "{cps=*0.2}Hmmm...{/cps}{w=0.4}{nw}"
    show reed explanatory flip
    Re "Hmmm...{fast} nah, I left my games at home."

    show reed neutral flip
    show naomi unimpressed with dissolve

    I "Naomi facepalms,{w=0.4} or whatever counts as a facepalm with a snout."

    show naomi angry:
        easein .25 xalign 0.45

    N "Reed!{fast}{w=0.7} You have a bong in your backpack!" with vpunch

    Re "{cps=*0.1}...{/cps}But we aren’t in Britain?"

    show naomi unimpressed with Dissolve(.75)

    N "Ugh,{w=0.3} you’re impossible{cps=*0.1}...{/cps}"

    show naomi unimpressed with Dissolve(.25)
    # hide naomi with easeoutright
    hide naomi with Dissolve(1)

    I "Naomi huffs and returns her focus to a stack of papers on the desk,{w=0.4} leaving a satisfied raptor in her wake."

    show reed happy flip with Dissolve(.25)

    Re "Heh,{w=0.4} {cps=*.5}works every time{/cps}{cps=*.1}...{/cps}"

    I "I need to learn how to do that."

    show reed neutral flip with dissolve

    Re "S’all ‘bout misdirection{cps=*.1}...{/cps}"

    I "What."

    show reed happy flip with Dissolve(.25)

    Re "Deuces."

    hide reed with easeoutright

    stop music fadeout 1.5
    pause 1.5

    I "The fuck just happened?"

    window hide
    pause 0.5

    show naomi neutral flip at scenter
    with Dissolve(1.0)

    show naomi explanatory flip

    N "Oh!{w=0.5} Anon,{w=0.3} I didn’t see you there!"

    show naomi happy flip with Dissolve(.25)

    N "Just in time to finish your paperwork!"

    show naomi neutral flip with Dissolve(.25)

    A "Paperwhatsit now?"

    show naomi explanatory flip

    N "Go inside,{w=0.4} Principal Spears will finalize it with you now."

    show naomi neutral flip

    I "Paperwork?{w=0.5} What fucking paperwork?{w=0.5} I’m pretty sure all that stuff was finished before I even came here."

    I "Whatever.{w=0.6} Probably a detention slip or whatever the principal has planned."

    stop ambient fadeout 1

    # Branch joins up again at Spear's office, with some small dialogue differences
    jump .spears_office


    label .pissOffCaveman:
    I "Probably best I try and not make the principal pissed at me."

    I "Campus beautification sounds like slave labor.{w=.4} And my arms are strictly for shitposting and gaming."

    I "I try to recall the way that the pomelo primadonna showed me to the office."

    I "I somehow found myself in the potato ranch at the back of the school."

    I "Fuck am I tired already."

    stop music fadeout 1

    scene hallway with fade
    play ambient 'audio/effects/school loop.ogg' fadein 0.5
    pause 0.5

    A "How the fuck did I end up here?"

    pause 0.75
    play music 'audio/ost/That Monochromatic Weirdo.ogg' fadein 0.5
    show reed neutral:
        yalign 0.1 xalign 0.3
    with Dissolve(1)
    pause 0.5

    show reed explanatory

    unknown "Don’t worry man,{w=0.3} it happens to new students all the time{cps=*.1}...{/cps}"

    show reed neutral

    A "Wha-?"

    I "Some pink raptor smelling of very heavily burnt grass surprises me."

    unknown "If you’re looking for the office you’re gonna wanna go thataway."

    A "Oh-{w=0.3} thanks."

    show reed explanatory

    unknown "Yeah,{w=0.3} no problem, man{cps=*0.1}...{/cps}"

    unknown "I’m about to go myself,{w=0.2} but I forgot something in my locker."

    show reed neutral

    unknown "See ya."

    show reed:
        easeout 0.75 xalign 0.75
    pause 0.25
    hide reed with dissolve

    I "He walks off down another hallway."

    I "I should follow the directions he gave me."

    I "Oh wait{cps=*0.1}...{/cps}"

    I "Was that the drummer from last night?"

    I "Huh."

    pause 1

    I "As I near the office I can feel a heavy tension suffusing the air."

    I "In front of the principals’ office is Naomi and some other chick,{w=0.3} engaged in a heated conversation."

    show naomi unimpressed at scenter
    show trish unimpressed flip at sright
    with Dissolve(1)
    pause 0.5

    show trish indignant flip with Dissolve(.25)

    unknown "Come on,{w=0.2} Naomi,{w=0.5} there’s no reason at all for you to keep us from selling merchandise at school!"

    show trish unimpressed flip with Dissolve(.25)

    N "Very sorry,{w=0.2} Trish,{w=0.5} but we’ve already told you before that due to your friends’{cps=*.1}...{/cps}{w=0.4} record{cps=*.1}...{/cps}{w=0.3} we can’t allow you to sell on school grounds."

    N "Seven times,{w=0.3} in fact."

    I "The purple one,{w=0.3} Trish,{w=0.3} throws up her hands in frustration."

    show trish angry flip with Dissolve(.25)

    T "Six!{w=0.5} {i}This{/i} is the seventh!"

    N "Go ahead and fill out a form{w=0.2}{nw}"
    show naomi:
        ease 0.25 yalign 0.05
        ease 0.25 yalign 0.0
    N "Go ahead and fill out a form{fast} if you really want to try again."

    T "I saw last time you just threw it in the trash without reading it!"

    show naomi angry with Dissolve(.25)

    N "It was illegible,{w=0.2} Trish.{w=0.5} You should work on your handwriting a bit."

    T "{b}ARGH!{/b}" with vpunch

    show trish:
        easein 0.5 xalign 1.05

    T "I don’t have time for this,{w=0.3} I need to go track someone down."

    show trish angry with Dissolve(.25)
    hide trish with easeoutright
    pause 0.5

    stop music fadeout 1

    I "She stomps away,{w=0.3} leaving Naomi to deflate a bit."

    pause 0.5

    A "That anything important?"

    show naomi flip at scenter with Dissolve(.25)
    pause 0.75

    show naomi considering flip with Dissolve(1)
    pause 0.5

    N "Sorry you had to see that,{w=0.2} Anon."

    N "Oh,{w=0.4} I didn’t notice we were blocking the door from you,{w=0.4} my apologies."

    A "The principal asked to see me early,{w=0.4} I’m not really in any rush."

    show naomi neutral flip

    N "Very commendable of you,{w=.1} though!"

    N "Go right ahead on in."

    A "Sure,{w=.3} thanks."

    stop ambient fadeout 1


    label .spears_office:
    scene office spears with Fade(1, 0, 1, color="#000")

    play music 'audio/OST/we just turned on the microphone in our programmers_ house.ogg'

    I "I open the door to the cramped office,{w=0.2} expecting to see a gruff cave of a workspace."

    I "Instead,{w=0.35} it was a fairly well furnished space complete with armchairs and cabinets of old photos."

    show spears neutral flip at sright with dissolve

    Sp "You going to stand there forever?{w=0.4} What are you waiting for?{w=0.5} Sit."

    show anon neutral at aleft with dissolve

    I "I plant myself in one of the armchairs and sink a bit lower into the cushion than expected."

    I "Perks of being a human,{w=0.2} I guess."

    if late_to_spears:

        Sp "I believe I told you last night to be here first thing this morning."

        I "Shit!"

        Sp "Tell me,{w=0.4} do I have a stutter?"

        A "{cps=*0.1}...{/cps}"

        Sp "Speak.{fast}"

        A "N{w=0.1}-no,{w=0.2} sir."

        Sp "{i}*sigh…*{/i}"

        Sp "Take this as a learning experience,{w=0.2} Anon."

        Sp "Punctuality gets you far in life."

        A "Yes,{w=0.1} sir."

        Sp "I let you off the hook last night because you’re a new student."

        Sp "I meant what I said last night."

    else:
        Sp "Punctual like I asked.{w=0.5} I like that,{w=0.2} Anon."

        Sp "I trust that what happened last night won’t become a recurring problem with you?"

        A "No,{w=0.1} sir."

        Sp "Good.{w=0.4} I meant what I said last night."

    I "Hopefully not about the whole pile driving thing."

    Sp "Still,{w=.4} I didn’t bring you in here to lecture you."

    I "He didn’t?"

    Sp "Not many people have to use the school’s financial services."

    A "What?"

    A "Financial services?"

    Sp "All the paperwork’s done to get you a special lunch card for the semester."

    Sp "You don’t have to worry about paying until after graduation.{w=0.5} No interest,{w=0.3} no down payments,{w=0.3} none of that."

    A "I uh{cps=*0.1}...{/cps}{w=0.4} What’s happening,{w=0.2} sir?"

    Sp "You signed up for the financial services,{w=0.3} correct?"

    Sp "Naomi told me you needed help with food and even had the papers filed out."

    I "Naomi?!"

    Sp "Allow me to double-check real fast."

    pause 0.75

    stop music
    play sound 'audio/effects/spearYellRumbleTinnitusProlongVoice.ogg' # TODO: volume boost, renpy volume controls cause this to clip horribly for values over 1.0

    Sp "{b}NAOMI!!{/b}" with vpunch

    pause 0.5

    show naomi neutral zorder 1:
        yalign 0 xalign -0.25
    with easeinleft

    pause 1.25

    I "Hello tinnitus my old friend{cps=*0.1}...{/cps}"

    pause 0.5

    show naomi explanatory

    N "{cps=*0.2}...{/cps}"

    show naomi neutral

    Sp "{cps=*0.2}......{/cps}"

    show naomi considering

    N "{cps=*0.2}....{/cps}"

    show naomi neutral

    Sp "{cps=*0.2}.....{/cps}"

    pause 0.75

    I "Oh god am I stuck like this?"

    pause 0.5

    stop sound fadeout 1
    play music 'audio/OST/we just turned on the microphone in our programmers_ house.ogg' fadein 2

    Sp "-dismissed Naomi.{w=0.5} And just to be absolutely clear,{w=0.3} Anon did ask you for this,{w=0.4} correct?"

    show naomi explanatory

    N "Well,{w=0.4} he {i}is{/i} in need of assistance,{w=0.2} right?"

    N "Otherwise he’s stuck with the budget meals."

    show naomi neutral

    pause 0.5

    Sp "Anon?"

    I "I glance between the two."

    I "It probably wasn’t malicious,{w=0.3} but still{cps=*0.1}...{/cps}"

    I "I’m not getting involved in office politics today."

    A "{cps=*0.1}...{/cps} {cps=*0.2}Yes.{/cps}"

    show naomi happy with Dissolve(.25)

    N "Oh,{w=0.2} lovely!"

    show naomi:
        ease 0.25 yalign 0.05
        ease 0.25 yalign 0.0

    N "{cps=*0.5}Don’t hesitate to ask if you have any other prob-{/cps}{nw}"

    Sp "You may leave now,{w=0.2} Naomi."

    show naomi neutral with Dissolve(.25)

    N "Oh!{w=0.2} Yes sir!"

    hide naomi with Dissolve(1)
    I "She leaves the office and Spears clicks the papers on his desk into a stack."

    Sp "Hate to do that,{w=0.4} but she goes on for ages."

    Sp "Anyways,{w=0.3} go ahead and sign here.{w=0.4} Here.{w=0.4} Here.{w=0.4} Initial here.{w=0.4} Date here.{w=0.4} Print your name here."

    I "I didn’t catch any of that."

    A "W{w=0.1}-what?"

    Sp "Just kidding.{w=0.4} You’re good to go,{w=0.2} Anon,{w=0.4} and don’t forget this."

    show spears:
        easein 0.5 xalign 0.9

    I "He holds out the poorly laminated lunch card for me to take."

    Sp "Just keep in mind,"

    Sp "As a senior,{w=0.3} this semester is your last,{w=0.4} your biggest chance to figure your future out."

    Sp "Even if you’re new to all of us here at Volcano High,{w=0.4} we’re here to help you make the most of it."

    I "Huh{cps=*.1}...{/cps}"

    A "Thank you,{w=0.2} Mister Spears."

    show spears happy flip

    I "Mr. Spears nods and gives a small smile."

    Sp "You can come in anytime.{w=0.5} I’m always here to listen."

    show spears neutral flip

    Sp "You can come in anytime. I’m always here to listen.{fast} Except for topics relating to estrus season."

    I "I sense great exhaustion in that last bit."

    if late_to_spears:
        I "I thank Mr. Spears one last time and head to homeroom."

        I "..."

        stop music fadeout 1

        scene black with fade

        # Anon has already spoken with Naser and seen Trish
        jump .postCavemanConference
    else:
        I "I thank Mr. Spears one last time and head out."

        stop music fadeout 1

        scene black with fade


    label .finding_naser:

    scene hallway with Dissolve(1.5)
    play ambient 'audio/effects/school loop.ogg' fadein 0.5

    I "Naser should be around here somewhere,{w=0.4} I wanted to talk to him before class."

    I "There’s still a bit of time before the bell."

    I "But where would Naser be hanging out about now?"

    I "Maybe near the cafeteria?{w=0.5} {cps=*0.5}This place serves breakfa-{/cps}{nw}"

    play music 'audio/ost/Fuck You I Like To Ignore Problems.ogg'
    unknown "{cps=*0.25}WAOOOH!!{/cps}" with vpunch

    I "With the screech of a banshee,{w=0.3} a blur of purple launches itself onto an unsuspecting student."

    I "Everyone in the hallway pauses to watch as a midget of a triceratops attempts to bring down the taller raptor student."

    unknown "{b}{cps=*2}IMMAKILLYOUTRIGGA!{/cps}{/b}" with vpunch

    I "The student body collectively rolls their eyes and continues on,{w=0.3} choosing to ignore the pissed off trigga as she finally forces the helpless guy to the floor and sits triumphantly on his chest."

    I "I’m pretty sure some would pay good money for this treatment."

    I "The ineffectual pummel-slapping included as she flails at the raptor’s face."

    T "You were there last night weren’t you?!"

    unknown "YES,{w=0.2} ALRIGHT,{w=0.2} I WAS!{w=0.5} GET OFF ME YOU PSYCHO BITCH!"

    T "You owe my band an apology!"

    unknown "WILL IT GET YOU OFF OF ME?!"

    T "If it’s good enough."

    unknown "ALRIGHT,{w=.2} ALRIGHT,{w=.2} I’M SORRY,{w=.4} JUST GET OFF!!"

    I "Wait,{w=0.3} she’s in the band that played yesterday?"

    stop music fadeout 1
    I "I{cps=*.1}...{/cps}{w=0.2} Should get out of here."

    I "Last thing I need is whatever’s going on here."

    I "I discreetly slip away,{w=0.2} down the nearest hall."

    scene black with fade
    scene hallway
    show anon neutral flip at acenter
    with fade

    A "That happen often{cps=*0.1}...?{/cps}"

    play music 'audio/ost/west_coast_kicking.ogg' fadein 1
    show naser neutral flip:
        yalign 0.1 xalign 1.9
    show reed neutral flip behind naser:
        yalign 0.1 xalign 1.3
    with Dissolve(1)
    pause .25

    Nas "Does what happen often?"

    show anon fear:
        easein_quart 0.5 xalign 0.3

    A "WAH!"

    show anon neutral with dissolve


    I "Naser’s leaning against a set of lockers,{w=0.3} along with that guy from before."

    I "The other one’s making a throat-slashing gesture,{w=0.3} waving a palm across his neck."

    pause 0.5

    A "Uhh{cps=*.1}...{/cps}{w=0.3} nothing important."

    pause 0.5

    show reed neutral:
        xalign 1
    show reed:
        easein_quart 0.8 xalign 0.7
    pause 0.35
    # show reed neutral:
    #     xalign 0.7
    # with dissolve

    show reed explanatory

    unknown "So as I was saying,{w=0.1} bro{cps=*.1}...{/cps}"

    unknown "BXR,{w=0.4} best tactic in the game,{w=0.2} y’know?"

    show reed neutral
    show naser considering flip
    with Dissolve(.25)

    Nas "Erm,{w=0.3} yeah{cps=*.1}...{/cps}{w=0.3} Makes sense,{w=0.2} I guess?"

    show naser unimpressed flip

    Nas "Anyways,{w=0.1} Reed.{w=0.5} I’m sorry for how things went last night,{w=0.4} {cps=*.7}I didn’t think those assholes would laugh at you.{/cps}"

    stop ambient fadeout 0.5
    show dimmer_light behind anon, naser, reed with dissolve

    I "Oh."

    play ambient 'audio/effects/school loop.ogg' fadein 0.5
    hide dimmer_light with dissolve

    show naser neutral flip
    show reed unimpressed
    with Dissolve(.25)

    Re "Nah man,{w=0.3} s’cool."

    Re "They called me because they wanted me to kill bugs crawling on the drums with a couple sticks,{w=0.4} I don't know why a bunch of people came there to watch it"

    Nas "Right{cps=*.1}...{/cps}{w=0.4} And you’re absolutely sure Trish is taking it okay?"

    show reed neutral

    Re "Hell yeah,{w=0.2} man.{w=0.5} Nothin’ goin’ on in the Trish department at all."

    I "Reed suddenly reaches into his pocket and retrieves his phone,{w=0.3} tapping away at a shockingly long password."

    show reed shocked:
        easein 0.2 xalign 0.65

    Re "Oh,{w=0.2} sick!{w=0.6} Right,{w=0.1} gotta go.{w=0.5} Catch you later,{w=0.1} amigo."

    show naser considering flip behind reed
    show reed neutral
    hide reed with easeoutright

    pause 0.5

    I "The raptor bolts before Naser can respond,{w=0.4} undoubtedly related to the triceratops."

    pause 0.75

    show naser neutral flip with dissolve
    Nas "Weird guy."

    A "Uh,{w=0.3} Naser,{w=0.4} {cps=*.4}I actually wanted to talk to-{/cps}{nw}"

    window hide
    stop ambient fadeout 0.5
    pause 0.5

    stop music fadeout 0.1
    pause 0.1

    # TODO: ogg conversion
    play sound 'audio/effects/ding_dong.ogg' volume 2 # CC0
    I "{cps=*20}{i}DING-{w=0.75}DONG{/i}{/cps}{w=1.5}{nw}"
    play sound 'audio/effects/ding_dong.ogg' volume 2
    I "{i}DING-DONG{fast} {cps=*20}BING-{w=0.75}BONG{/cps}{/i}"
    pause .25

    show naser neutral flip:
        easein_quad 0.5 xalign 1.7
    pause .5

    play ambient 'audio/effects/school loop.ogg' fadein 0.5
    play music 'audio/ost/west_coast_kicking.ogg' fadein 0.5

    Nas "Crap,{w=0.3} can’t miss my homeroom today."

    Nas "Sorry,{w=0.4} it’ll have to wait a bit."

    A "It{cps=*.1}...{/cps}{w=0.5} no,{w=0.3} that’s fine."

    A "See you later."
    show naser behind anon:
        easeout_quad 1.0 xalign 0.2
    pause 0.5
    hide naser with dissolve

    I "Naser heads off down the hall and I go to my own homeroom."

    I "{cps=*.1}...{/cps}"

    stop ambient fadeout 1
    stop music fadeout 1
    scene black with fade


    label .postCavemanConference:
    pause 0.5

    I "The periods pass and eventually it’s lunchtime again."

    I "I’ve been focusing a bit less on class,{w=0.3} and more on getting a routine down to avoid unwanted confrontation."

    I "It’s like it’s only me and the teacher in class,{w=0.3} phasing out everyone else."

    scene hallway
    show anon neutral at acenter
    with fade

    play ambient 'audio/effects/school loop.ogg' fadein 1

    I "I follow the flow of students towards the lunchroom,{w=0.3} mindlessly looking about the halls."

    I "Passing by the athletic awards case,{w=0.3} a decent amount of group photos have Naser front and center."

    I "Apparently this school is pretty well known for their track team."

    I "In a similar vein,{w=0.2} Naomi is present in a good deal of the photos in the academic achievement case."

    I "The last case was reserved for general awards,{w=0.4} I guess trophies that don’t belong anywhere else."

    I "The school has a few commendation awards for their efforts to stop bullying."

    I "Feh,{w=0.4} they pass those around to every school."

    I "Looking around,{w=0.2} there’s several posters on the walls here."

    I "All simple slogans to stop the evil bully menace."

    I "A fat lot of good those did me at my old school{cps=*.1}...{/cps}"

    I "They always went all in with those efforts."

    I "One time they even got the whole student body into the auditorium to watch a short movie."

    I "Some frail,{w=0.3} pasty kid gets pestered by a chubby,{w=0.3} buff bully."

    I "The kid ended up trying to run away and got hit by a car,{w=0.4} with the credits scrolling over a scene in the hospital."

    I "Everyone in class just said things like{w=0.3} \"Man,{w=0.2} good thing I’m not like that bully.\",{w=0.4} \"Yeah,{w=0.4} if I ever see a bully like that I’ll help the kid!\""

    I "Then they went right back to talking about me."

    stop music

    I "{cps=*.1}...{/cps} No use feeling bad about the past."

    scene cafeteria
    show anon neutral at acenter
    with fade

    I "I’m here now."

    I "With the lunch card in my possession I’m able to snag something actually edible."

    I "I should run the math on how much I’ll end up owing,{w=0.4} but I feel more like indulging myself."

    menu:
        "Grab the cookies you fatass":
          I "Why not both?"

        "That sandwich looks good":
          I "Why not both?"

    I "Hence my tray stacked high with desserts and the tastiest looking sandwich from the lunchline."

    I "Looking around for a place to sit I see the aggravating creamsicle waving at me."

    play music 'audio/OST/Summertime Synth.ogg' volume 0.65 fadein 0.05

    I "Next to her is Naser with a complicated expression."

    # A small variation is needed here because Anon only hears the first line if he finds Naser before meeting Spears.
    if late_to_spears:

        Nas "{i}{cps=*.7}I just wanted to make sure you guys had an actual audience-{/cps}{/i}"

    else:

        Nas "{i}{cps=*.7}I brought them here so Fang has an audience.{/cps}{/i}"

    stop ambient fadeout 1

    I "Shit.{w=0.5} I go and sit across from Naser and Naomi."

    scene cafeteria
    show anon neutral at aleft
    show naomi neutral flip at sright
    show naser sad flip behind naomi:
      xalign 0.7 yalign -0.1
    with fade

    pause 0.5

    show naomi explanatory flip

    N "I see you’re making use of the lunch card."

    show naomi neutral flip

    A "{cps=*.4}Yyyyeeeaaaaah...{/cps}"

    show naomi explanatory flip

    N "But all those sugars!{w=0.5} All that is bad for your health,{w=0.2} Anon.{w=0.4} This school’s vegan options-"

    I "I tune her out with the help of a crunchy sugar cookie."

    show naomi neutral flip with dissolve

    I "A glance at Naser and I notice that he’s just poking at his pasta."

    show naomi:
        easein 0.5 xalign 0.95
    pause 0.5

    N "Naser sweetie,{w=0.4} you shouldn’t play with your food."

    show naomi:
        easein 0.5 xalign 1.0
    pause 0.5

    show naser neutral flip
    Nas "Huhwha-{w=0.6}{nw}"
    show naser:
        easein_quad 0.5 yalign 0.1 xalign 0.75
    Nas "Huhwha-{fast} OH!{w} Anon,{w=0.4} what’s up?"

    A "Not much.{w=0.5} And you?"

    show naser happy flip
    Nas "Yeah no,{w=0.3} totally good!"

    I "His following laugh sounds hollow."

    show naomi sad flip with dissolve

    N "Naser{cps=*.1}...{/cps}"

    show naser sad flip with dissolve
    pause 0.5

    Nas "Yeah{w=0.1} yeah.{w=0.5} It’s just{cps=*.1}...{/cps}"

    show naser angry flip with dissolve

    Nas "Fang stayed home today.{w=0.6} The concert was a shitshow and they wanted to avoid everyone.{w=0.7} I knew I shouldn’t have invited all those guys."

    show naser sad flip with dissolve

    show naomi:
        easein 0.5 xalign 0.95
    pause 0.5

    I "Naomi places a comforting hand on his shoulder."

    A "I uh{cps=*.1}...{/cps}{w=0.4} Yeah{cps=*.1}...{/cps}{w=0.4} That crowd was harsh."

    Nas "What happened after I left?"

    I "Naser looks at me pitifully."

    Nas "Trish gave me a general idea,{w=0.3} but I have to know{cps=*.1}...{/cps}"

    pause .5
    Sp "{cps=*.6}{i}You are not the only person in the world.{/i}{/cps}"
    pause .5

    I "Ah,{w=0.4} shit."

    pause 0.75

    A "The band never made it past the first song.{w=0.6} Someone said they ‘still’ sucked."

    show naser angry flip:
        easein_quad 0.5 xalign 0.7
    pause 0.75

    I "Naser grits his teeth."

    show anon:
        easein_quad 0.5 xalign -0.05
    show naomi shocked flip with Dissolve(.25)

    A "Whoa{w=0.1} whoa,{w=0.3} calm down man."

    Nas "What else?{w=0.5} Did they say anything about Fang?!"

    unknown "{cps=*.7}{i}NO ONE WOULD WANT TO FUCK YOU,{w=0.3} BITCH!{/i}{/cps}"

    A "{cps=*.4}...Yeah...{/cps}{w=0.4} I don’t think you’d want to hear it though{cps=*.1}...{/cps}"

    Nas "And?{w=0.5} What happened after?!{w}{nw}"

    show naser angry flip:
        linear 0.05 xalign 0.695
        linear 0.05 xalign 0.705
        repeat

    Nas "And? What happened after?!{fast} I’m gonna kick all their asses!" with vpunch

    show naomi:
        easein 0.5 xalign 0.9
    pause 0.5
    N "Naser!{w=0.4} Please calm yourself!"

    show naser:
        linear 0.2 xalign .7

    I "{i}I realize now that I had been laughing with them.{/i}"

    A "I left after that.{w=0.5} Principal Spears was fucking pissed.{w=0.5} Even threatened to suplex them."

    show naser sad flip
    show naomi unimpressed flip
    with dissolve

    I "Naser sags,{w=0.3} emotionally spent."

    show naser:
        easein_quart 1 yalign 0.05

    Nas "{cps=*.3}Haaaaah....{/cps}{w=0.3} Fuck{cps=*.1}...{/cps}{w=0.5} So that’s why she stayed home{cps=*.1}...{/cps}"

    show naomi considering flip with Dissolve(.25)

    N "If Fang wishes to stay home then that is her prerogative.{w=0.6} You just need to give her some time,{w=0.3} Naser."

    I "While she said that I noticed a strange expression cross over Naomi’s face."

    Nas "I know babe.{w=.5} I just wish I could help them more."
    pause 0.5

    A "Yeah.{w=0.5} If you need any help Naser,{w=0.4} I owe ya for the pizza."

    scene black with fade

    "We finish eating and make small talk until the bell signals us to go to our sixth period."

    "Day two out of however many left is now out of my way."

    "I’m fairly certain that if Naser found out I laughed too I’d need to avoid him."

    "Those cheeto covered claws look like they’d freakin’ hurt,{w=0.3} man."

    "With that drama now past me I can just disappear and cheese through the rest of the year like I’m invisible."

    "Oh when June hits it’s gonna be so sweet."

    "Amen to that."

    "{cps=*0.1}...{/cps}"

    stop music fadeout 1
    pause 2

    return