SnootGame/game/script/x7-naomi-tribulations.rpy

label chapter_x7:
    #Naomi Arc One
    stop music fadeout(3)
    scene black with Dissolve(2)
    pause 1

    "{cps=*0.2}-- April, 201M2021 BC --{/cps}"
    window hide
    window auto
    pause .5

    play music "audio/OST/west_coast_kicking.ogg" fadein 1.0
    scene home fang day with Dissolve(1)
    pause .5

    #show fang nonxmas pendant unimpressed at scenter with dissolve
        # yalign 0.4
        # xalign 0.1

    show fangphonevideocall anonneutral at scenter with easeinbottom:
        yalign -0.4

    #hide fang with dissolve
    pause .5

    F "-I’m just saying is that he shouldn’t have tried-"

    A "Sweet tooth, you shouldn’t just kick your teacher in the nuts."
    pause .5

    # xalign WHY DO YOU NOT WORK
    show fangphonevideocall anonneutral at scenter:
        xanchor 0
        yalign -0.4
        block:
            linear 0.045 xpos 5
            linear 0.045 xpos -5
            repeat 5
        xpos 0

    "I growl at the phone in my hand."

    "He’s lucky he’s in college right now."
    pause .5

    F "I don’t want to hear it."

    A "Yeah, but still. So what’s the punishment?"
    window hide
    window auto
    pause .5

    hide fangphonevideocall with easeoutbottom
    pause .5

    "With a huff I turn my phone around the living room, slowly being rearranged to fit more useless people."
    pause .5

    F "Setting up for baby bro’s going away party."
    pause .5

    A "D’aaawww, such a caring sister."
    pause .5

    "I don’t even have to turn the screen back to see Anon’s shit eating grin."
    pause .5

    F "Dad says I gotta clean up after, too."
    pause .5

    A "If you’d move out Fang-{w=0.5}{nw}"

    #hide fangphonevideocall with easeoutbottom
    #show fang nonxmas pendant angry at scenter with dissolve

    play sound 'audio/effects/slapstickPunch.ogg'
    F "{cps=*2.0}Trying to!{/cps}" with vpunch
    window hide
    window auto
    pause .5

    show fangphonevideocall anonneutral at scenter with easeinbottom:
        yalign -0.4
    #show fang nonxmas pendant sad with dissolve
    #pause 0.5
    #hide fang with dissolve

    #show fangphonevideocall anonneutral with dissolve:
    #    yalign -0.4
    pause .5
    "I finally look back at my screen and I see him giving me his soothing, calming face."

    "Even seeing that look from him stings."
    pause .5

    F "I didn’t mean to shout."

    A "It’s fine Fang. I’m lucky to have a dorm room, I doubt dad would’ve sprung for an apartment again."

    A "He’s still pissed about that security deposit."
    pause .5

    "Ah, right. That was my fault."
    pause .5

    F "Wasn’t my fault. Reed was the one to bring the carfe."
    pause .5

    A "{cps=*0.5}Riiiight.{/cps}{w=0.3} Still, I thought you and Trish would be moving in together."

    # show fang angry with dissolve

    F "{cps=*0.3}Fffffffff{/cps}uck her. She wanted to move in with Reed instead."
    pause .5

    A "Really?"

    F "Really!"
    pause 1.0
    A "It was the late night jam outs, wasn’t it."

    F "No!"

    A "Ha! You owe me ten bucks!"
    show fangphonevideocall anongrin with dissolve

    "Stupid Anon and his stupid bets and his stupid always being right!"

    "Damn it, I know I’m fucking blushing right now. I just fucking know it."
    pause .5

    A "I-{w=.5}{nw}"

    F "Don’t you say it!"

    A "Told-{w=.5}{nw}"

    F "Anon!"

    A "You-{w=.5}{nw}"

    show fangphonevideocall anongrin at scenter:
        xanchor 0
        yalign -0.4
        block:
            linear 0.045 xpos 5
            linear 0.045 xpos -5
            repeat 5
        xpos 0

    F "I’ll hang up!"

    show fangphonevideocall anonconcerned with dissolve
    A "Okay okay. Sorry I asked."

    show fangphonevideocall anonneutral with dissolve
    A "But what’re you gonna do now?"
    pause .5

    # show fang considering with dissolve
    "I exhale deeply and feel all the weight of my current predicament land on my shoulders."
    pause .5

    F "I don’t know. Maybe Stella-{w=0.5} what?"

    show fangphonevideocall anonneutralalt1:
        "fangphonevideocall anonneutral" with Dissolve(.1)
        pause 0.2
        "fangphonevideocall anonneutralalt1" with Dissolve(.1)
        pause 0.2
        repeat
    pause .5

    "Anon’s head is shaking rapidly and his hands are waving like crazy."
    pause .5

    show fangphonevideocall anonneutral with Dissolve(.1):
        yalign -0.4

    F "I don’t see what the problem would be with Stella as a roommate."
    window hide
    window auto
    pause .5

    #hide fangphonevideocall with easeoutbottom

    #show fang nonxmas pendant unimpressed at sleft with dissolve
    show fangdad neutral flip behind fangphonevideocall:
        xalign 1.8 alpha 0
        easein_cubic 1 xalign 1.2 alpha 1

    # why does xalign and yalign crap itself with these phones?
    show fangphonevideocall anonneutral:
        yalign -0.4
        pause 1
        ease_cubic 0.75 yalign -3.0

    pause 1

    FD "Oi! Stop slackin’ Lucy. The living room ain’t gonna clean itself!"

    "Not now! I still want to talk with him!"

    show fangdad:
        easeout_cubic 1 xalign 1.8 alpha 0
    pause .5

    A "Ah man.{w=0.3} I guess I should go?"

    show fangphonevideocall anonneutral:
        yalign -3.0
        ease_cubic 0.75 yalign -0.4

    #hide fang with dissolve

    #show fangphonevideocall anonneutral with easeinbottom:
    #    yalign -0.4

    "No no no! Damn it!"

    pause .5

    F "Urgh.{w=0.3} I need to finish this. I’m sorry Anon."
    pause .5

    A "It’s fine, and I wish I could be there now, but the scholarship and all…"

    A "Plus the whole dorm fumigation thing and having to change rooms."

    A "Fuckin’ roommate got lucky during it in a spare theater room."
    pause .5

    A "The bastard."
    pause .5

    A "We’ll talk later, Fang. Have fun with the party okay?"

    show fangphonevideocall call_ended_bg call_ended with dissolve:
    #    yalign -0.045
    # yalign 0
    pause .5

    "Before I can say I love him the screen fades to my wallpaper."

    "The wallpaper of me and him together on christmas."
    pause .5

    "I sigh one last time and pocket my phone."
    window hide
    window auto
    pause .5
    hide fangphonevideocall with easeoutbottom
    pause .5

    "The cool and smooth texture of polished stone makes me realize I’m holding the necklace again."
    pause .5

    "Anon{cps=*.1}...{/cps}"
    pause .5

    stop music fadeout 3.0

    "{cps=*.1}...{/cps}"
    window hide
    window auto
    pause .5

    scene black with Dissolve(1)
    pause 1

    play music "audio/OST/to_swagger.ogg" fadein 1.0
    play ambient "audio/effects/teenageCrowdInteriorLoop.ogg" fadein 2.0 volume 0.5

    scene livingroomdayalt
    show fang pneutral flip at scenter
    with Dissolve(2)
    pause .5

    "Thirty minutes till Naser gets back now."

    "Everyone that came is just casually chatting, already snacking on all of mom’s better dishes."
    pause .5

    "Shame about dad’s guacamole though."

    "For them, that is. It may be fucking delicious but the aftermath isn’t pretty."
    window hide
    window auto
    pause .5

    show fang psad flip with dissolve
    show fang:
        block:
            linear 0.045 xalign 0.4975
            linear 0.045 xalign 0.5025
            repeat 5

    "I shudder involuntarily at the thought of my last birthday party."

    "No wonder he married mom."

    show fang pneutral flip with dissolve

    "The banners hung up with thumbtacks from under the couch (and abc gum) flying gallantly above the staircase, people start to trickle in to celebrate Naser officially pissing off."

    "He got accepted into a prestigious medical school back last august."
    pause .5

    "Still remember him prancing around like there was ever a chance he’d get rejected."

    "I started going to community college around the same time, he has no idea the grueling experience ahead of him."

    "Then again, he does this kind of shit perfectly."
    window hide
    window auto
    pause 0.5

    show fangmom neutral with dissolve:
        xalign -0.4
        easein_cubic 1 xalign 0.01

    pause 0.25

    FM "Lucy, would you be a dear and dim the lights?"

    show fang psurprised flip with dissolve

    "I snap back to reality."

    "Naser’s close school friends are all ready and perched out of sight of the entryway."
    window hide
    window auto

    show fangmom:
        easeout_cubic 1 xalign -0.2 alpha 0

    show fang:
        ease_cubic 1.75 xalign 1.5
    show fang pneutral with dissolve

    pause 1.25
    hide fangmom
    show dimmer_darker with dissolve
    pause .5

    show chadshark flip behind dimmer_darker:
        xalign 0.75
        easein_cubic 1 xalign 0.35
    show stella happy flip behind dimmer_darker:
        xalign 0.92
        easein_cubic 1 xalign 0.70
    with dissolve

    pause .5

    "I notice one of his old team mates even brought Stella along when I turn the light knob."

    #hide stella
    #hide chadshark
    #with easeoutright

    pause 0.5
    "Maybe Anon was right in his rant a few weeks ago about girls having it easier?"
    pause .5

    "Nah, that’s bullshit."
    window hide
    window auto

    show chadshark flip:
        easeout_cubic 1 xalign -0.05 alpha 0
    show stella:
        easeout_cubic 1 xalign 0.42 alpha 0

    pause 1.5
    hide chadshark flip
    hide stella

    # scene home fang dim with fade

    "Trish comes barreling in through the door like there’s a blizzard outside."
    window hide
    window auto
    pause .5

    play sound 'audio/effects/whoosh.ogg'
    show trish shock flip behind dimmer_darker:
        xalign 2.0
        easein_cubic 1 xalign 0.25
    pause .2
    show fang psurprised flip:
        easein_cubic .5 xalign 1.4

    pause 1

    show trish surprised with dissolve
    pause .5
    show trish happy with dissolve

   #show trish happy behind dimmer_darker at tleft with easeinleft

    T "Fang! It took a while but Reed’s distracted!"

    show fang:
        ease_cubic 1 xalign 0.8
    show fang phappy flip with dissolve

    F "Oh thank fuck."

    F "Definitely don’t need him being arrested today of all days."
    window hide
    window auto
    pause .5

    show fangdad neutral flip behind dimmer_darker with dissolve:
        xalign 1.6
        easein_cubic 1 xalign 1.1

    FD "Arrested for what?"
    window hide
    window auto

    show trish:
        easein_cubic 1 xalign 0.05
    show fang:
        easein_cubic 1 xalign 0.5
    pause 0.001
    show trish surprised
    show fang nonxmas pendant surprised
    with dissolve

    #show fang nonxmas pendant surprised behind dimmer_darker with dissolve:
    #    xzoom 1.0
    pause 1.5

    show trish happy behind dimmer_darker
    show fang nonxmas pendant happy
    with dissolve

    FangAndTrish "For being the most wanted guy in Volcano high."

    "That line doesn’t work anymore, but he hasn’t given me a new one yet."
    pause .5

    F "Do you need anything else, Dad?"

    FD "Don’t think so. Your mother’s got an entire bakery going at once in the kitchen, but she hasn’t needed help before."
    pause .5

    FM "Dear!"
    window hide
    window auto

    show fangdad unimpressed flip with dissolve
    pause 0.5

    show fangdad:
        easeout_cubic 1.0 xalign 1.6 alpha 0
    pause 1.5
    hide fangdad

    "The old man limps back towards the kitchen, shoulders slightly hung about being fucking told by mom in seconds."

    show fang pneutral flip
    show trish neutral
    with dissolve

    F "Okay, spill.{w=0.3} How?"
    show trish explanatory with dissolve

    T "I asked Rosa to clear some time for him. She took it to mean a classic date night."
    show trish neutral with dissolve

    F "Could’ve just told him Stella’s boyfriend would be here, he’d stay miles away."
    pause .5

    T "Figured he’d forgotten by now, you know him."

    F "Right, and what about you? Last time you threw a glass of juice on the old man."

    F "We seriously don’t need any arrests tonight."
    show trish considering with dissolve
    "Trish blows a raspberry and looks away."
    pause .5

    T "Maybe if he wasn’t such a pig."

    show fang nonxmas pendant unimpressed behind dimmer_darker with dissolve:
        xzoom -1.0

    F "*Ahem*"
    show trish explanatory with dissolve
    T "You know what I mean. I’m telling you, him and Moe are-"

    Moe "‘Lucy! Yer ma sayz Nasah is on ‘is ways!"

    show fang nonxmas pendant surprised
    show trish surprised behind dimmer_darker
    with dissolve

    F "Shit, hide!"
    window hide
    window auto

    show trish:
        easeout_cubic 1 xalign -1.0
    show fang:
        easeout_cubic 1 xalign -1.2
    pause 0.2
    hide trish
    hide fang
    with dissolve

    stop music fadeout 1.0
    stop ambient fadeout 2.5
    pause .5

    "Everyone in the room scatters, hiding as best they can in our living room."

    "I even see Stella and the old varsity Football captain dive into the closet."
    pause .5

    "The door creaks open and Naomi leads Naser in slowly."
    window hide
    window auto
    pause .5

    show naser neutral flip behind dimmer_darker:
        xalign 2.8 alpha 0
        easein_cubic 1.5 xalign 1.8 alpha 1
    show naomi neutral flip behind dimmer_darker, naser:
        xalign 1.5 alpha 0
        easein_cubic 1.5 xalign 1.0 alpha 1

    pause 2.25

    show naser considering flip with dissolve
    pause .75
    show naser neutral flip with dissolve
    pause .5

    Nas "-are Mom and Dad dancing again? I can’t see-"
    window hide Dissolve(0.0001)
    window auto

    #remove dimming effect here
    show dimmer_darker:
        linear 0.5 alpha 0
    show white:
        alpha 0
        linear 0.5 alpha 0.7
        pause .5
        ease 5 alpha 0

    pause(0.1)
    show naser shocked flip with Dissolve(0.25)
    pause 0.15
    show naser annoyed flip with Dissolve(0.25)
    pause 0.25

    hide dimmer_darker

    "I twist the dimmer knob to full brightness, making Naser shade his eyes."

    Nas "Wha-"
    window hide
    window auto
    play music "audio/OST/Those Other Two Weirdos.ogg" fadein 1.0

    show chadshark behind white:
        yalign 0.1
        xalign 0.2
    show stella happy behind white:
        xalign 0.1
    show moe neutral behind white:
        xalign -0.6
    show fangdad happy behind white:
        xalign -0.5
    show fangmom neutral behind white:
        xalign -0.3
    show fang nonxmas pendant happy behind white:
        xalign 0.5
    show trish happy behind white:
        xalign 0.25

    with dissolve
    pause .5

    Everyone "SURPRISE!"

    #potentially use fang very happy with a modified pendant cause it looks much better
    show fang:
        easein_cubic 0.25 yalign 0.05
        easeout_cubic 0.5 yalign 0.0
    show fang nonxmas pendant very happy with Dissolve(.25)


    F "Naomi’s pregnant!"

    show chadshark:
        easein_cubic 1 xalign 0.15
    show stella:
        zoom 1.1 yalign 0.325 xalign 0.04
        easein_cubic 1 xalign 0.0
    show moe:
        easein_cubic 1 xalign -0.66
    show fangdad:
        linear 0.045 xalign -0.505
        linear 0.045 xalign -0.495
        linear 0.045 xalign -0.504
        linear 0.045 xalign -0.496
        linear 0.045 xalign -0.503
        linear 0.045 xalign -0.497
        linear 0.045 xalign -0.502
        linear 0.045 xalign -0.498
        linear 0.045 xalign -0.501
        linear 0.045 xalign -0.499
        linear 0.045 xalign -0.5
    show fangmom:
        easein_cubic 1 xalign -0.35
    show trish:
        easein_cubic 1 xalign 0.22
    show naser:
        easein_cubic 1 xalign 1.85
    show naomi:
        easein_cubic 1 xalign 1.035

    show naser flip surprised
    show naomi flip shocked
    show trish surprised
    show stella shock
    show fangdad unimpressed

    play sound 'audio/effects/slapstickPunch.ogg'

    NaserAndNaomi "WHAT!?" with vpunch

    show fangmom:
        easein_cubic 0.25 yalign 0.05
        easeout_cubic 0.5 yalign 0.0

    FM "GRANDBABIES?!?!"
    window hide
    window auto

    show fangdad unimpressed:
        parallel:
            easeout_quad 1 xalign 0.2
        parallel:
            pause 0.6
            ease_quad 0.2 yalign 0.2
            easeout_cubic 0.2 yalign 0.0

    pause 0.9
    play sound 'audio/effects/slapstickBigPunch.ogg'
    pause 0.1

    show trish:
        easein_cubic 1 xalign 0.1
    show fang pear cover:
        linear 0.045 yalign -0.105
        linear 0.045 yalign -0.095
        linear 0.045 yalign -0.104
        linear 0.045 yalign -0.096
        linear 0.045 yalign -0.103
        linear 0.045 yalign -0.097
        linear 0.045 yalign -0.102
        linear 0.045 yalign -0.098
        linear 0.045 yalign -0.101
        linear 0.045 yalign -0.099
        linear 0.045 yalign -0.1

    hide white with vpunch
    pause 0.5

    show trish unimpressed
    show fangmom unimpressed
    with dissolve

    #show fangdad unimpressed flip:
    #    ease_cubic 0.2 yalign 0.0
    #show fang nonxmas pendant surprised with dissolve

    "Dad swats my crest with one hand."
    pause .5

    FD "No, since you’re leaving us for college next week your Mother thought we should throw you a going away party."

    show fangmom neutral with dissolve

    FM "Oh, yes, I invited all your school friends, too."
    window hide
    window auto
    pause .5

    show fang:
        easein_cubic 1 yalign 0.0
    show fangdad:
        ease_cubic 2 xalign -0.5
    show trish:
        ease_cubic 1 xalign 0.25
    pause 0.0001

    show stella neutral:
        zoom 1 yalign 0.0 xalign 0.15
    show fang nonxmas pendant unimpressed
    show fangdad neutral
    show naomi neutral flip
    show naser considering flip
    with dissolve

    show trish considering with dissolve

    "I see the little gerbil on a treadmill in his head spinning aimlessly until comprehension dawns on him that his privacy has been violated."

    show naser neutral flip with dissolve

    Nas "Oh. My yearbook."

    FM "Don’t worry dear, I put it back in your dirty laundry pile where it was left!"
    pause 0.5

    "Aside from the peanut gallery this is fairly standard dinner banter."

    show naser annoyed flip with dissolve

    Nas "{cps=*0.5}Moooooooooomm{/cps}, not in front of my friends."
    pause 0.5

    Chet "Chill man, we know how it is, your Mom is just gonna miss you."

    show naser neutral flip with dissolve

    "The other track members nod in agreement."

    show naomi:
        easein_cubic 1 xalign 0.9
    show naomi happy flip with dissolve

    N "It’s great everyone came! Let’s all enjoy the party!"
    show stella happy:
        xalign 0.1
    show trish smile
    show naser flip happy
    show fangdad happy
    show fang nonxmas pendant neutral
    with dissolve

    "A holler of agreement and the whole thing kicks off as though it had been going on for hours already."
    window hide
    window auto
    pause .5

    stop music fadeout 2.0
    scene black with Dissolve(1)
    pause 1.5

    play ambient "audio/effects/teenageCrowdInteriorLoop.ogg" fadein 2.0 volume 0.5
    play music "audio/OST/west_coast_kicking.ogg" fadein 2.0
    scene livingroomdayalt
    show fang nonxmas pendant neutral:
        xalign 0.3
    show trish neutral:
        xalign 0.1
    with Dissolve(2)

    "I make a beeline for the food table with Trish, stealing enough grub to keep me sated through the whole ordeal."

    "Ordinarily I’d just hole up in my room and annoy everyone by playing ‘Frankly I Did Do a Little Winning’, but…"
    show fang nonxmas pendant considering with dissolve
    "Damn skinnie costing me two hours of my life by resolving blood feuds."
    show fang nonxmas pendant neutral with dissolve

    "Whatever, it’s not like these jocks want to talk with me."
    pause .5

    "But Stella, jeez she’s got the attention of all the boys."
    pause .5

    T "It’s weird, right?"
    show fang nonxmas pendant considering with dissolve
    F "I know.{w=0.3} Like, how?"

    T "I mean, I’ve seen her talking a lot with that hot dog chick that’s near your place."
    pause .5

    show fang:
        easein_cubic 1 xalign 0.5
    show fang pneutral flip with dissolve

    F "What are you implying?"
    pause .5

    T "C’mon, you gotta admit her set up is a little seedy."

    F "She’s chill, Trish. Not some kinda{cps=*.1}...{/cps} multitasking prostitute."
    show trish unimpressed with dissolve

    T "Pffft. Not even."

    "Ah, I know that pout well."
    pause .5

    F "No vegan options?"

    show trish:
        easein_cubic 1 xalign 0.0
    show trish indignant with dissolve

    T "Herbies matter!"
    pause .5

    "Dad’s head whips around at Trish’s shout."
    window hide
    window auto

    stop music fadeout 1.0
    stop ambient fadeout 1.0

    show fangdad neutral flip:
        xalign 1.5
        easein_cubic 1 xalign 1.0
    show fang nonxmas pendant neutral
    with dissolve
    pause .5

    show trish unimpressed with dissolve

    #TODO: Add effect of blue transparent layer appearing slowly with some slow transition
    pause .5

    play ambient1 "audio/effects/hungrybeast.ogg" volume 0.5 fadein 5

    scene livingroomdayalt:
        xalign 0.5
        ease_quad 4 zoom 1.2
    show dimmer_lighter:
        alpha 0
        ease_quad 4 alpha 1
    show fang nonxmas pendant neutral behind dimmer_lighter:
        xalign 0.5
        ease_quad 4 zoom 1.15
    show trish unimpressed:
        ease_quad 4 zoom 1.3 xpos -179 #yalign 0.05
    show fangdad neutral flip:
        xpos 859
        ease_quad 4 zoom 1.3 xpos 810
        

    pause 2.5

    #show lighter_freeze with dissolve:
    #    xalign 0.5
    #    yalign 0.5
    #pause 0.2
    #show light_freeze with dissolve:
    #    xalign 0.5
    #    yalign 0.5
    #pause 0.2
    #show dark_freeze with dissolve:
    #    xalign 0.5
    #    yalign 0.5
    #pause 0.2
    #show darker_freeze with dissolve:
    #    xalign 0.5
    #    yalign 0.5
    "The room’s temperature drops as the two glare at each other."

    show fang nonxmas pendant angry with dissolve
    F "Trish!"

    show fang:
        ease_cubic 0.5 zoom 1.3
        easeout_cubic 0.3 xalign -1.4 zoom 1.3
        easein_cubic 0.3 xalign -0.5
    show trish:
        pause 0.8
        easein_quad 0.3 xpos -200
        ease_quad 0.45 xpos -179
    show dimmer_lighter behind fang with dissolve

    stop ambient1 fadeout 2
    "I give her a quick reality check with my elbow."
    window hide
    window auto
    pause .5

    scene livingroomdayalt:
        xalign 0.5 zoom 1.2 
        ease_cubic 1 zoom 1
    show dimmer_lighter:
        alpha 1
        ease_cubic 1 alpha 0
    show fang nonxmas pendant angry:
        zoom 1.3 xalign -0.5
        parallel:
            ease_cubic 1 zoom 1
        parallel:
            easeout_quad 0.5 xalign 0.0
            easein_cubic 0.5 xalign 0.2
    show trish unimpressed:
        zoom 1.3 xpos -179
        ease_cubic 1 zoom 1 xpos 0 xanchor 0
    show fangdad neutral flip:
        zoom 1.3 xpos 810
        ease_cubic 1 zoom 1 xpos 859 xanchor 0
    show fangmom unimpressed flip:
        zoom 1.3 xpos 1475
        ease_cubic 1 zoom 1 xpos 1200 xanchor 0

    pause 0.0001

    play ambient "audio/effects/teenageCrowdInteriorLoop.ogg" fadein 2.0 volume 0.5
    play music "audio/OST/west_coast_kicking.ogg" fadein 2.0

    show trish considering
    show fang nonxmas pendant unimpressed
    with dissolve

    pause 0.75

    show fangdad unimpressed flip with dissolve
    pause 0.5

    #Need to reset the positions to align commands, they don't play nice with xpos apparently
    show fangdad:
        xalign 1.0
        easein_cubic 1 xalign 1.1
        easeout_cubic 1 xalign 1.5
    show fangmom:
        xalign 1.4
        easein_cubic 1 xalign 1.5
        easeout_cubic 1 xalign 1.9
    show trish:
        xalign 0.0

    pause 1.5
    hide fangmom
    hide fangdad
    with dissolve

    pause 0.5

    "Everyone awkwardly returns to their own tiny dinner talk, Dad getting the patented look from Mom as she pulls him aside."
    show trish explanatory with dissolve

    T "He’s SO a dirty cop."
    show fang nonxmas pendant considering
    show trish neutral
    with dissolve

    F "And you would’ve been in cuffs again."

    show trish surprised with Dissolve(.25)
    pause 0.5
    show trish happy with Dissolve(.25)

    "Trish’s small chuckle is enough to know she won’t actually start another argument tonight."
    window hide
    window auto

    show trish neutral with dissolve
    pause 1
    show fang nonxmas pendant neutral with dissolve

    "I scan the room again as I nibble on some of the tiny sandwiches Mom made."

    "Aside from Stella being swarmed by boys three times her size, Chet and Naser are bro-ing it up with some crazy looking handshake and Naomi is talking with mom."
    pause 0.5

    T "You’re doing it again."

    "Hm?"
    pause 0.5

    "Oh."

    "My thumb circles softly over the surface of polished stone."

    show trish explanatory with dissolve
    T "Anon texted me earlier, y’know."

    show fang:
        easein_cubic 1 xalign 0.5
    pause 0.0001
    show fang phappy flip
    show trish neutral
    with dissolve

    F "Really?"
    show trish smile with dissolve

    T "He said you owe him ten bucks."

    show fang:
        block:
            linear 0.045 xalign 0.4975
            linear 0.045 xalign 0.5025
            repeat
    show fang pangry flip

    "FFFFFFFFFFFF-"

    F "{cps=*0.6}FFFFFFFFFFFFFF{/cps}{nw}"
    show fang punimpressed flip:
        linear 0.045 xalign 0.5
    extend "{cps=*0.6}uuuuuuuuuuuuck.{/cps}"
    pause 0.5

    T "You gonna tell me why?"

    F "No!"
    window hide
    window auto
    pause 0.25

    show trish:
        easein_cubic 1 xalign -0.1
    show trish considering with dissolve
    pause 0.75
    show trish:
        ease_cubic 1 xalign 0.0
    show trish sad notears with Dissolve(.25)
    pause .25

    "Oh no, not the sad eyes."
    pause 0.5
    "Damn it."
    show fang pconsidering flip with dissolve

    F "May have made a bet on the roommate thing."
    window hide
    window auto
    pause 0.25

    show trish surprised
    show fang pneutral flip
    with Dissolve(.25)

    pause 0.75
    show trish:
        linear 0.045 xalign 0.004
        linear 0.045 xalign 0
        repeat 18
    show trish angry with dissolve
    pause 0.5
    show fang:
        ease_quart 0.75 xalign 0.1
    pause 0.05
    show trish:
        easeout_quart 0.3 xalign 0.05
    pause 0.3
    show trish:
        easein_back 0.25 xalign -0.025
    pause 0.25

    "Trish tries to headbutt me, but I already have her at arm’s length with my palm on her face."
    pause 0.5

    F "For your info, I bet in your favor."
    window hide
    window auto
    pause 0.5

    show trish:
        easein_cubic 1 xalign -0.1
    show trish annoyed with dissolve

    "Trish finally relents, leaning back against the wall."

    show trish explanatory with dissolve
    T "I just got out of a loud house, Fang. I’d like to experience having a good night’s sleep for the first time in my life."

    show fang punimpressed flip
    show trish neutral
    with dissolve

    F "Yeah, and leave a sister out in the cold."
    show trish neutral with dissolve

    F "What am I gonna do now?"

    F "It’s not like I can move in with Anon."
    show fang pconsidering flip with dissolve

    F "Unlike Naomi and Naser."
    window hide
    window auto

    show naomi happy:
        alpha 0 xalign 1.0
        parallel:
            easein_cubic 1.5 xalign 0.7
        parallel:
            linear 0.5 alpha 1
    show naser happy flip behind naomi:
        alpha 0 xalign 1.9
        parallel:
            easein_cubic 1.5 xalign 1.4
        parallel:
            linear 0.5 alpha 1
    show fang:
        easein_cubic 1.5 xalign -0.6
    show trish:
        parallel:
            easein_cubic 1.5 xalign -0.5
        parallel:
            linear 0.5 alpha 0

    show fang nonxmas pendant neutral with dissolve
    pause 1

    show naomi:
        pause .0001
        choice:
            "naomi happy" with Dissolve(.5)
            ease_quad 0.5 xalign 0.675
            ease_quad 0.5 xalign 0.725
            ease_quad 0.5 xalign 0.675
            ease_quad 0.5 xalign 0.725
            ease_quad 0.5 xalign 0.7
        choice:
            "naomi explanatory" with Dissolve(.5) #I don't know how to have a chance bias, so I'm created duplicate choices like a codelet
            pause 2.5
        choice:
            "naomi explanatory" with Dissolve(.5)
            pause 2.5
        choice:
            "naomi neutral" with Dissolve(.5)
            pause 2.5
        choice:
            "naomi neutral" with Dissolve(.5)
            pause 2.5
        choice:
            "naomi sad" with Dissolve(.5)
            pause 2.5
        choice:
            "naomi shocked" with Dissolve(.5)
            pause 2.5
        repeat

    show naser:
        pause .0001
        choice:
            "naser happy flip" with Dissolve(.5)
            pause 2.5
        choice:
            "naser happy flip" with Dissolve(.5)
            pause 2.5
        choice:
            "naser explanatory flip" with Dissolve(.5)
            pause 2.5
        choice:
            "naser considering flip" with Dissolve(.5)
            pause 2.5
        choice:
            "naser annoyed flip" with Dissolve(.5)
            pause 2.5
        choice:
            "naser brooding flip" with Dissolve(.5)
            pause 2.5
        choice:
            "naser smug flip" with Dissolve(.5)
            pause 2.5
        choice:
            "naser smug flip" with Dissolve(.5)
            pause 2.5
        choice:
            "naser unimpressed flip" with Dissolve(.5)
            pause 2.5
        repeat

    "I want to be jealous."

    "Thinking about how they get what I want so badly."
    pause 0.5

    "But even with Naser’s scholarship, Dad’s spending so much for him."
    pause 0.5

    "But…"
    pause 0.5

    "Naser deserves it."

    "He deserves the fucking world after putting up with me."
    window hide
    window auto
    pause .5

    #muh renpy hack
    hide naomi
    hide naser
    show naser considering flip:
        xalign 1.4
    show naomi neutral:
        xalign 0.7
    with dissolve

    pause .75

    show naser:
        easein_cubic 1 xalign 1.5
    show naser explanatory with dissolve
    show naomi:
        pause 1.5
        ease_cubic 1 xalign 0.85

    "I glance over to him nervously trying to bridge some conversation with Mom and his teammates."

    "Naomi of course close behind him to direct the whole thing."
    pause .5

    unknown "Hey!"
    show fang nonxmas pendant surprised with dissolve

    "Someone calls to me from across the room."
    window hide
    window auto
    pause .5

    show fang:
        easein_cubic 1.5 xalign 1.5
    show trish behind fang:
        parallel:
            easein_cubic 1.5 xalign 0.75
        parallel:
            linear 0.5 alpha 1
    show naser: 
        parallel:
            easein_cubic 1.5 xalign 3.5
        parallel:
            linear 0.5 alpha 0
    show naomi: 
        parallel:
            easein_cubic 1.5 xalign 2.0
        parallel:
            linear 0.5 alpha 0
    show chadshark:
        alpha 0 xalign -2.5
        parallel:
            easein_cubic 1.5 xalign -0.2
        parallel:
            linear 0.5 alpha 1

    pause 0.0001
    show trish surprised flip
    show fang pneutral flip
    with dissolve

    pause 1

    "Oh, it’s just the ex-captain of the football team."

    "Still wonder how Stella managed to catch this guy."
    pause .5

    Chet "Hey, you’re the chick that played during prom last year, right?"

    Chet "Come on, play somethin’ and liven up the place a bit!"
    pause 0.5

    "The other track team members holler in agreement."

    show trish considering flip with dissolve
    "Trish isn’t facing me but she has an odd look going on there."
    window hide
    window auto

    show chadshark:
        easeout_cubic 1 xalign -1.0
    show fang:
        ease_cubic 1.5 xalign 0.8
    show trish:
        ease_cubic 1.5 xalign 0.25
    pause 0.5

    show fang phappy flip
    show trish neutral flip
    hide chadshark
    with dissolve
    pause 0.5

    F "Well, hey, it happened."
    pause 0.5

    T "Oh boy."
    pause 0.5

    F "Was it just like you always imagined?"

    show trish smug flip with dissolve
    "She smirks and looks at me from the corner of her eye."
    pause 0.5

    T "There was a bit more groveling involved."

    T "I kind of forgot about it, honestly."

    show trish smile with dissolve
    T "You gonna play?"
    pause 0.5

    F "Eh, sure, why the fuck not."

    F "I was getting bored anyway."
    window hide
    window auto
    pause 0.25

    show fang behind trish:
        easeout_cubic 0.75 xalign 0.4
        linear 0.7 xalign -0.7
    show trish:
        pause 0.25
        easein_cubic 0.5 yalign 0.15
        "trish happy" with Dissolve(.25)
        easeout_cubic 0.5 yalign 0.0
    pause 0.25
    play sound 'audio/effects/whoosh.ogg'
    pause 0.35
    play sound 'audio/effects/clap.ogg'
    pause 0.25
    hide fang with dissolve

    "I high five Trish as I pass her by."
    window hide
    window auto
    pause 0.5

    stop ambient fadeout 2
    stop music fadeout 2
    scene black with Dissolve(1)

    pause 1.5

    play music 'audio/OST/The Top of the Social Ladder.ogg' fadein 1
    scene fangroomfuture
    show fang nonxmas pendant considering:
        xalign 0.1
    with Dissolve(2)
    pause .5

    "In my room I take the time to consider which weapon I want to slay it with."

    F "What would he pick? Probably at random."
    window hide
    window auto
    pause 0.5

    show fang nonxmas pendant neutral with dissolve
    pause 0.5
    show fang nonxmas pendant happy with dissolve
    F "Aha! I got it."
    show fang:
        ease_cubic 1 xalign 1.0
    pause 0.5
    "I set down my three favorites at the foot of my bed and sprinkle some cracker crumbs in front of them."

    "Then with a quick tap of my foot I let my most loyal minion decide."
    pause .5

    "RAYmba’s mechanical mouth makes quick work of the crumbs, choosing first my good ole’ artcore hollowbody."
    pause .5

    F "Good boy!"

    "I quickly tune my proffered weapon, watching as RAYmba finishes it’s dinner before returning to it’s dock."

    "I pat my robotic pet for doing an amazing job and head back to my waiting audience."
    window hide
    window auto
    pause .5

    show naomi neutral flip:
        xalign -1.2
        pause 1
        parallel:
            easein_cubic 0.5 xalign -0.775
            ease_quad 0.5 xalign -0.825
        parallel:
            ease_cubic 1 yalign 0.2
    show fang:
        easeout_cubic 1 xalign 0.0
        easein_back 0.5 xalign -0.2

    show fang phappy flip with dissolve
    pause 0.5
    show fang pshocked flip with Dissolve(.25)

    "Only to nearly get kneecapped by Naomi’s stupidly fat tail."

    show fang pangry flip with dissolve

    "Who would even like a girl with such a disgusting, lardy tail."

    "Unlike mine."
    pause .5

    show fang:
        easein_cubic 0.3 yalign 0.05
        easeout_cubic 0.3 yalign 0.0
    F "What the fuck!"
    pause .5

    "She scowls."
    pause .5

    F "Were you trying to bust my knee? You stupid beige bitch."
    window hide
    window auto
    pause .25

    show naomi:
        easeout_cubic 0.5 xalign -1.2
        "naomi unimpressed"
        yalign 0.0 xalign -0.8
        linear 2 xalign -0.5
    pause 3

    N "I didn’t mean to. I was simply heading for the bathroom up here. It seems that Chet and-or Stella are currently using the other bathroom."
    pause .25
    show naomi unimpressed:
        linear 2 xalign -0.8
    pause .75

    "She turns her nose and continues down the hallway."

    "I’m half-tempted to brain her with my beloved guitar."

    show fang punimpressed flip with dissolve

    "Feh."
    pause .5

    "I turn and make my way down the steps."
    window hide
    window auto
    pause .5

    stop music fadeout 1
    scene black with Dissolve(1)
    pause .5
    play ambient 'audio/effects/teenageCrowdInteriorLoop.ogg' fadein 2
    scene livingroomdayalt

    show trish happy:
        xalign 0.0
    show fangdad happy:
        xalign 1.0
    show fangmom neutral:
        xalign 0.5
    show stella explanatory flip behind trish:
        xalign 0.4
    show chadshark flip behind stella,fangmom,fangdad,trish:
        xalign 0.6
    show naomi explanatory flip:
        xalign 0.8
    show moe neutral flip:
        xalign 1.9
    show naser neutral flip:
        xalign 1.6
    with Dissolve(2)

    pause 0.5

    show fang nonxmas pendant happy behind trish with dissolve:
        yalign 0.4
        xalign -0.8
    pause 0.5

    show trish:
        easein_cubic 1 xalign 0.1
    show trish surprised flip with dissolve
    pause 0.5

    show trish:
        ease_cubic 1 xalign 0.4
    show fangdad:
        ease_cubic 1 xalign 1.2
    show fangmom:
        ease_cubic 1 xalign 0.7
    show stella:
        ease_cubic 1 xalign 0.6
    show chadshark flip:
        ease_cubic 1 xalign 1.1
    show naomi:
        ease_cubic 1 xalign 0.9
    show moe:
        ease_cubic 1 xalign 2.0
    show naser:
        ease_cubic 1 xalign 1.85
    show fang:
        pause .4
        parallel:
            easein_cubic 0.7 xalign -0.55
        parallel:
            block:
                easein_cubic 0.2 yalign 0.45
                easeout_cubic 0.3 yalign 0.2
    pause 0.0001

    show trish smile flip
    show fangdad neutral flip
    show fangmom neutral flip
    show stella neutral flip
    show naomi unimpressed flip
    with dissolve

    "Trish scooches to give me enough space on the stairs to set the guitar on my knee to play."
    pause 0.5

    F "What should I start with, do you think?"

    T "Shit, it’s been forever since we heard ‘My Fucking Maw, Man’."

    F "Wasn’t it called ‘I’m Way Too Hungover’?"
    show trish considering flip with dissolve

    T "No, Reed just fell backwards when he told us and didn’t bother correcting himself."
    pause 0.5

    "Sounds like something he’d do, yeah."
    show trish smile flip with dissolve
    stop ambient fadeout 3.0

    "Most of the party-goers are already looking my way in anticipation."

    "I run the first few stanzas in my head a couple of times and begin strumming."
    pause 0.5
    play music "audio/OST/The.ogg" fadein 1.0

    show stella:
        pause 2.46
        easeout_cubic 0.226 yalign 0.0
        easein_cubic 0.226 yalign 0.005
        easeout_cubic 0.226 yalign 0.0
        easein_cubic 0.226 yalign 0.01
        easeout_cubic 0.226 yalign 0.0
        easein_cubic 0.226 yalign 0.02
        block:
            easeout_cubic 0.226 yalign 0.0
            easein_cubic 0.226 yalign 0.03
            repeat
    show chadshark flip:
        pause 3.164
        easeout_cubic 0.226 yalign 0.0
        easein_cubic 0.226 yalign 0.005
        easeout_cubic 0.226 yalign 0.0
        easein_cubic 0.226 yalign 0.01
        easeout_cubic 0.226 yalign 0.0
        easein_cubic 0.226 yalign 0.015
        block:
            easeout_cubic 0.226 yalign 0.0
            easein_cubic 0.226 yalign 0.02
            repeat
    show moe:
        pause 1.908
        easeout_cubic 0.226 yalign 0.0
        easein_cubic 0.226 yalign 0.005
        easeout_cubic 0.226 yalign 0.0
        easein_cubic 0.226 yalign 0.01
        easeout_cubic 0.226 yalign 0.0
        easein_cubic 0.226 yalign 0.015
        block:
            easeout_cubic 0.226 yalign 0.0
            easein_cubic 0.226 yalign 0.02
            repeat
    show fangmom:
        pause .904
        easeout_cubic 0.226 yalign 0.0
        easein_cubic 0.226 yalign 0.005
        easeout_cubic 0.226 yalign 0.0
        easein_cubic 0.226 yalign 0.01
        easeout_cubic 0.226 yalign 0.0
        easein_cubic 0.226 yalign 0.02
        block:
            easeout_cubic 0.226 yalign 0.0
            easein_cubic 0.226 yalign 0.03
            repeat
    show trish:
        pause 2.204
        easeout_cubic 0.226 yalign 0.0
        easein_cubic 0.226 yalign 0.005
        easeout_cubic 0.226 yalign 0.0
        easein_cubic 0.226 yalign 0.01
        easeout_cubic 0.226 yalign 0.0
        easein_cubic 0.226 yalign 0.02
        block:
            easeout_cubic 0.226 yalign 0.0
            easein_cubic 0.226 yalign 0.03
            repeat
    show naser:
        pause 2.46
        easeout_cubic 0.226 yalign 0.0
        easein_cubic 0.226 yalign 0.005
        easeout_cubic 0.226 yalign 0.0
        easein_cubic 0.226 yalign 0.01
        easeout_cubic 0.226 yalign 0.0
        easein_cubic 0.226 yalign 0.02
        block:
            easeout_cubic 0.226 yalign 0.0
            easein_cubic 0.226 yalign 0.03
            repeat

    "My fingers glide along the fretboard easily enough and my pick wildly plucks the cords."
    pause 0.5

    "The party is cheering and stamping out a drum beat for me to play to."

    "Even Trish beside me is joining in on the makeshift metronome."
    pause 0.5

    "I let loose a hard and fast rift, taking the chance to actually feel out the crowd."

    show fangmom:
        parallel:
            ease_cubic 0.452 xalign 0.725
            ease_cubic 0.452 xalign 0.675
        parallel:
            easeout_cubic 0.226 yalign 0.0
            easein_cubic 0.226 yalign 0.03
            easeout_cubic 0.226 yalign 0.0
            easein_cubic 0.226 yalign 0.03
        repeat

    show trish happy flip
    show stella happy flip
    show naser happy flip
    with dissolve

    "All of the jocks and even Stella are loving this."

    show fangdad:
        pause 1
        easeout_cubic 0.226 yalign 0.0
        easein_cubic 0.226 yalign 0.0015
        easeout_cubic 0.226 yalign 0.0
        easein_cubic 0.226 yalign 0.003
        block:
            easeout_cubic 0.226 yalign 0.0
            easein_cubic 0.226 yalign 0.005
            repeat
    show fangdad happy flip with dissolve

    "I can see Dad’s snear slowly vanish as Mom repeatedly steps on his foot."

    show naomi sad flip with dissolve
    "Naomi’s the last one I look at, and I’m expecting one of her vicious sneers."

    "Instead she’s looking like someone took all her hopes and dreams and flushed them down the drain."
    pause 0.5

    "I nearly miss my next note, so I focus back on my guitar."
    pause 0.5

    "With an extra flourish I end the punk song with a fist pump."

    show fang:
        easein_cubic 0.5 yalign 0.1
        easein_back 0.5 yalign 0.2
    pause .5
    show fang very happy with Dissolve(.25)

    show trish:
        ease_cubic 0.5 xalign 0.4
    show fangdad:
        ease_cubic 0.5 xalign 1.2
    show fangmom:
        ease_cubic 0.5 xalign 0.7
    show stella:
        ease_cubic 0.5 xalign 0.6
    show chadshark flip:
        ease_cubic 0.5 xalign 1.1
    show naomi:
        ease_cubic 0.5 xalign 0.9
    show moe:
        ease_cubic 0.5 xalign 2.0
    show naser:
        ease_cubic 0.5 xalign 1.85
    pause 0.0001

    stop music fadeout 3.0
    show trish smile flip
    show stella neutral flip
    with dissolve

    play sound 'audio/effects/crowdCheer.ogg' volume 0.8

    "The room hollers, demanding more amazing music from me."
    show fang nonxmas pendant happy with dissolve

    "But…"
    show fang nonxmas pendant flip off happy with dissolve

    F "Oi! I’m just the ambiance, pricks."

    F "It’s baby bro’s party, after all."
    window hide
    window auto
    pause .25
    stop sound fadeout 2
    play ambient 'audio/effects/teenageCrowdInteriorLoop.ogg' fadein 3

    show fang nonxmas pendant happy
    show naomi neutral behind fangmom
    show fangmom neutral:
        xalign 0.6
    show stella neutral
    with dissolve
    pause .5
    show naser:
        easein_cubic 1 xalign 1.9
        easeout_cubic 1.5 xalign 3.0

    show naser neutral flip with dissolve
    pause .5
    show naser considering flip with dissolve
    
    show chadshark with dissolve
    show chadshark:
        easein_cubic 0.25 yalign 0.03
        easeout_cubic 0.25 yalign 0.0
        pause 0.5
        easeout_cubic 1.5 xalign 2.65
    show naomi:
        easeout_cubic 1.5 xalign 2.5
    show fangmom:
        pause 0.5
        easeout_cubic 1.5 xalign 2.5
    show stella:
        pause 1.5
        parallel:
            easeout_cubic 1.5 xalign 2.5
        parallel:
            easein_cubic 0.4 yalign 0.05
            easeout_cubic 0.4 yalign 0.0
            repeat
    show fangdad:
        pause 0.5
        easein_cubic 1 xalign 1.1
        easeout_quad 2 xalign -2.5
    show moe:
        pause 2
        easeout_quad 2 xalign -1.9
    show fangdad happy with dissolve
    pause 0.75
    show fangdad happy flip with dissolve
    show stella happy with dissolve

    show fang:
        easein_back 1 yalign 0.0 xalign -0.65

    "With the spotlight on Naser now I decide to just sit back on the stairs."
    pause 0.5

    T "Still gonna play?"

    F "Eh… Thinking something slower now."
    show fang nonxmas pendant considering with dissolve

    F "Dad’ll pitch a fit if they start a mosh pit."

    show trish happy flip
    show fang nonxmas pendant happy
    with dissolve

    play music "audio/OST/middle_of_nowhere.ogg" fadein 2.0
    $ renpy.music.set_volume(0.5, 2, 'ambient')

    "We chuckle together, my fingers now lazily strumming a mellow tune for the party."

    "It’s a simple song, one I’ve learned perfectly from granny."

    "So perfectly I can look out as everyone else chats and enjoys the calmer atmosphere."

    hide fangdad
    hide fangmom
    hide chadshark
    hide naomi
    hide stella
    hide naser
    window hide
    window auto
    pause .5

    show fang:
        parallel:
            easein_cubic 1.5 xalign -2.75
        parallel:
            linear 1 alpha 0
    show trish behind fang:
        parallel:
            easein_cubic 1.5 xalign -0.75
        parallel:
            linear 1 alpha 0
    pause 0.0001

    show chadshark:
        yalign -0.3 xalign 2.0
        parallel:
            linear 0.05 yalign -0.305
            linear 0.05 yalign -0.295
            repeat
        parallel:
            easein_cubic 1.5 xalign 0.0
            block:
                easeout_quart 0.2 xalign 0.01
                pause 2
                easeout_quart 0.2 xalign -0.01
                pause 2
                repeat
    show naser tablehit:
        zoom 0.9 yalign -0.4 xalign 3.7
        parallel:
            linear 0.05 yalign -0.407
            linear 0.05 yalign -0.393
            repeat
        parallel:
            easein_cubic 1.5 xalign 1.5
            block:
                easeout_quart 0.2 xalign 1.51
                pause 2
                easeout_quart 0.2 xalign 1.49
                pause 2
                repeat
    show stella neutral:
        xalign 0.9
        easein_cubic 1.5 xalign -0.1
    show naomi neutral flip:
        xalign 2.6
        easein_cubic 1.5 xalign 1.3
    with dissolve
    pause 0.5


    "Naser and Chet have started arm wrestling."

    "Stella and some of Naser’s old teammates are talking like crazy about something."

    show stella explanatory with dissolve
    St "-and it’s like wrestling!"

    unknown "No way, that sounds retarded!"

    unknown "Yeah, spaceships awrasslin’?!"

    St "Yeah way! It’s really cool!"
    show stella neutral with dissolve

    Chet "It really is, bros! We’ve been marathonin’ it er’ry weekend!"
    pause .5

    "The jocks start jeering and tossing their solo cups at him."
    window hide
    window auto

    show naomi considering flip with Dissolve(.4)
    image sodaproj = im.FactorScale("images/other/sodacan.png", 0.2)

    show sodaproj:
        rotate 90
        xalign 1.3
        yalign 0.26
        easeout_cubic 0.35 xalign 0.42
        pause .03
        block:
            parallel:
                easein_cubic 2 xalign 0.8
            parallel:
                easein_quad 0.24 yalign 0.0
                ease_cubic 1.57 yalign 2.0
            parallel:
                linear 0.7 rotate 360
                block:
                    linear 0.3 rotate 540
                    repeat
    pause .1
    show naomi:
        "naomi shocked flip" with Dissolve(0.25)
        easein_quart 0.25 yalign -0.3
        ease_quart 0.5 yalign 0.0
    play audio 'audio/effects/whoosh.ogg'
    pause .25
    show chadshark:
        easein_cubic 0.12 xalign -0.05
        easein_cubic 0.3 xalign 0.0
    show naser:
        linear 0.05 yalign -0.405
        linear 0.05 yalign -0.395
        repeat

    play sound 'audio/effects/anonDink.ogg'
    pause .35
    show naomi angry with Dissolve(0.5)
    pause .4

    show chadshark:
        easein_quad 1.5 yalign -0.15 xalign -0.05
    show naser:
        easein_quad 1.5 yalign -0.07 xalign 1.45
    show stella:
        easein_cubic 1.5 xalign -0.2
    show naomi:
        easein_cubic 1.5 xalign 1.4
    pause 0.0001
    show dimmer_darker behind chadshark, naser
    show naomi shocked flip
    hide stella
    show stella_hack:
        zoom 1.1 yalign 0.325 xalign -0.2
        easein_cubic 1.5 xalign -0.3
    with dissolve
    pause 0.25

    "Giving Naser the chance to finally win."
    window hide
    window auto

    show chadshark:
        easeout_cubic 0.3 yalign -0.4
    show naser:
        easeout_cubic 0.3 yalign -0.5
    pause .3
    show chadshark:
        yalign -0.7
        easein_elastic 1 yalign -0.45
    show naser:
        yalign -0.8
        easein_elastic 1 yalign -0.55
    show dimmer_darker:
        linear 0.5 alpha 0
    play sound 'audio/effects/tableSlamNoBox.ogg'
    with vpunch

    play audio 'audio/effects/crowdCheer.ogg' volume 0.5
    pause 1

    show chadshark:
        easein_cubic 1 yalign 0.0 xalign -0.4
    show naser behind chadshark:
        easein_cubic 1 yalign 0.0 xalign 1.0
    show naomi:
        parallel:
            easein_cubic 1 xalign 1.1
        parallel:
            easein_cubic 0.3 yalign 0.1
            easeout_cubic 0.3 yalign 0.0
            repeat
    pause 0.0001
    show stella sad:
        xalign -0.2
    hide stella_hack
    show naser brooding flip
    show naomi happy flip
    with dissolve
    pause 0.5
    show fangdad happy behind chadshark, stella:
        xalign 0.0
        easein_cubic 1 xalign 0.5
    show fangmom neutral flip:
        xalign 2.0
        easein_cubic 1 xalign 1.5
    with dissolve

    "Both Chet and Naser sheepishly hold a hand behind their heads while Naser gets showered in praise from his parents."

    show naomi:
        ease_cubic 0.5 xalign 1.0 yalign 0.125
        block:
            ease_cubic 0.3 xalign 1.02
            ease_cubic 0.3 xalign 1.0
            repeat

    pause 0.5

    "Naomi ducks under his other arm and embraces him, rubbing muzzles together."

    pause 0.5
    "Wait, no. That didn’t happen."

    "Only Naomi did the nuzzling."
    pause 0.5

    show naomi:
        easein_cubic 1 xalign 1.1 yalign 0.0
    show naomi neutral flip with dissolve

    "Nah, those two are a whole room away, probably didn’t see it right."
    window hide
    window auto
    pause 0.5

    show naomi considering flip with dissolve
    pause 1
    show naser considering flip with dissolve

    pause 0.5

    show naser neutral flip
    show fangdad behind naser
    with dissolve
    pause .25

    show naser:
        easein_cubic 1 xalign 0.7
    show naser explanatory flip with dissolve
    pause .25

    show chadshark behind fangdad:
        easein_cubic 1 xalign -0.3
    show stella:
        easein_cubic 1 xalign -0.1
    show fangdad:
        easein_cubic 1 xalign 0.4
    pause 0.0001
    show stella explanatory
    show fangdad happy flip
    show naomi sad flip
    with dissolve

    "When they separate, Naser follows Chet back to the enthralling conversation on wrestling spaceships or whatever with Stella."
    pause .5

    "A purple hand breaches my line of sight."
    window hide
    window auto

    show stella:
        easein_cubic 1.5 xalign 1.0
    show chadshark:
        easein_cubic 1.5 xalign 1.8
    show fangdad:
        easein_cubic 1.5 xalign 2.0
    show naser:
        easein_cubic 1.5 xalign 2.8
    show naomi:
        easein_cubic 1.5 xalign 2.7
    show fangmom:
        easein_cubic 1.5 xalign 2.8
    show fang nonxmas pendant neutral:
        parallel:
            easein_cubic 1.5 xalign -0.65
        parallel:
            linear 1 alpha 1
    show trish indignant flip:
        parallel:
            easein_cubic 1.5 xalign 0.4
        parallel:
            linear 1 alpha 1
    pause 0.0001
    hide stella
    hide chadshark
    hide fangdad
    hide fangmom
    hide naomi
    hide naser
    with dissolve

    pause .5

    T "Hey, Fang! Hellooo!"

    F "Yeah?"

    show trish explanatory flip with dissolve
    T "You bridged that last song into Mussolini Macho Mystery perfectly, you didn’t even notice?"
    show trish neutral flip with dissolve

    "I just now realize I am, in fact, playing a completely different song than when I started."
    pause .5
    show trish:
        easein_cubic 1 xalign 0.2
    show trish smile with dissolve

    "Trish and I continue making small talk through the rest of the party while I keep the ambience upbeat."
    pause .5

    "One of the track members spills some popcorn on the floor below him."
    show fang nonxmas pendant considering with dissolve

    "I should start thinking of ways to get out of cleanup."
    window hide
    window auto
    pause .5

    stop ambient fadeout 3.0
    stop music fadeout 3.0
    scene black with Dissolve(2)
    pause 2

    return