SnootGame/game/script/7.concert-day.rpy

label chapter_7:
    #Concert Day
    "{cps=*0.2}-- One Week Later --{/cps}"
    window hide
    window auto
    pause .5

    scene moes pizza

    show anon neutral at aright
    with fade

    play music 'audio/OST/Fuck You I Like To Shitpost.ogg' fadein 1.0

    "The week’s been a mix of excitement and trepidation."

    "More excitement from Fang and the band and trepidation on my part around Fang."

    "Having come to terms with how I feel, I just can’t stop noticing all the little things she does."
    pause .5

    "Like her cute tail wagging to a silent tune."
    pause .5

    "Or her weird and funny way of eating."
    pause .5

    "Or how soft and huggable her wings look."
    pause .5

    "Raptor Jesus, if this is what love is I kind of want to sample buckshot."
    pause .5

    "And yet I don’t want it to stop."

    "Even now as Moe and Reed work on clearing the floor of tables and making a noise."

    #Going to kill inhuman, you didn't put a lewd check here!
    if persistent.lewd == True:
        scene fangonamp with Dissolve(2)

    "And I’m drooling like an idiot as I watch Fang bend over a large Amp."
    pause .5

    unknown "Ahem."

    "Even now her tail wags to that mysterious beat in her head."
    pause .5

    unknown "AHEM."

    "Not to mention the way those jeans hug her hips and ass-"
    pause .5

    unknown "AH-{b}HEM!{/b}{w=.3}"

    A "Hm?"
    scene moes pizza
    show anon neutral flip at aright
    show trish unimpressed at sleft
    with dissolve

    T "Aren’t you supposed to be helping?"

    "Hm? {w=.3} OH SHIT RIGHT!"

    A "Y-yeah, right! Just moving this table ahahaha."
    window hide
    window auto

    pause .5
    show trish annoyed with dissolve
    pause .75
    show trish unimpressed flip with Dissolve(.25)
    hide trish with easeoutleft

    stop music fadeout 3
    scene moebackrooms with fade

    "I pick up the last table on the floor and hurriedly move it to the suspiciously large storage room in the back of Dino-Moe’s."

    "I set the table down with the rest, right next to the seemingly out of place buckets of cement mix."

    "Looking out from the closet, the joint is actually pretty big."

    "The area is a good one-hundred and fifty by two-hundred feet, so without the tables there’s enough space for at least a few hundred people."

    show anon neutral flip at aright with easeinright
    window hide
    window auto

    "Impressed, I let out a low whistle."
    play music 'audio/OST/Dino Destiny Reader.ogg' fadein 1.0
   #  show anon neutral at aleft
    St "I’m on time, right?"
    show anon neutral flip at aright with dissolve

   #  show stella neutral alt flip at stright with easeinright
    show stella neutral alt at stleft with easeinleft
    window hide
    window auto

    "Where did she come from?"

    A "Hm? Who are you?"

    St "We’ve met before..."

    A "Wha- wait… Stella, right? From the school gardens."

    "She gleefully nods."

    St "Yes! Rosa should be coming any minute now, too!"

    "I haven’t spoken to either of them since campus beautification."

    "Well, other than Stella through the bathroom door, but that doesn’t really count."

    "But Fang and the rest will be happy they have at least two fans, right?"

    St "You know…"

    St "There’s always room in the gardening club if you still want to join, Anon..."

    "There’s no way I’m going back to that sort of prison labor."

    "I look the pale green, spine covered thing up and down."

    "Including the ‘OPPAI’ t-shirt she’s wearing."

    "What the fuck."

    A "Uh.."

    A "Y-you {i}do{/i} know what your shirt says, right?"

    show stella shock alt with dissolve:
      yalign 0.5

    "Stella gives me a quizzical look and glances down at her shirt, her face turning bright red."

    St "Oh my…{w=.4} th-this was the only clean shirt I had…"

    "If I didn’t feel the way I did about Fang, I’d think Stella’s stammering was kinda cute."

    "Suddenly her face lights up and her eyes return to me."

    show stella happy alt at sleft with dissolve

    St "Wait…{w=.4} You like anime too, don’t you?"

    "Play it cool, Anon. No need to reveal your power level."
    window hide
    window auto
    pause .5

    menu:
      "I used to when I was little.":
          A "I saw some back in elementary school."
      "I’ve seen a bit here and there.":
          A "Yeah, uh… a little bit."

    St "That’s amazing! {w=0.2} I don’t have anyone else I can talk to about it!"

    St "What’s your favorite anime? I {i}loooove{/i} PreCure!"

    "Raptor Jesus on his cross of rock."

    "It takes all my strength not to physically cringe."

    St "Oooh, we should watch it together sometime!"

    St "I have the box set of {i}every{/i} season!"

    St "We could marathon it over a long weekend or something!"

    A "Uh…{w=0.3} maybe some other time..."

    "I’ll just block my calendar for this… maybe for after the heat death of the universe."

    A "Anyway, the show isn’t for another half-hour."

    show stella neutral alt with dissolve

    St "I wanted to ask you before... what did you think of your fortune?"

    A "Uh… I kinda forgot…"

    St "You got the Judgement?"

    A "Doesn’t ring a bell."

    St "O-oh…{w=0.3} well… {w=0.3}Uh… {w=0.3}How would you like another?"

    A "Eh… {w=0.3}I got time to kill, sure."

    "She pulls her deck of tarot cards from… {w=.3}somewhere…"

    "Where the fuck does she hide these things?"

    "Anyway, she fans the deck out."

    St "Alright, take one."

    "I take one at random and show it to her."

    #Decided to take the unholy if/else approach to this, if there is a better, cleaner, or faster way to do it then do point me to it.
    #Values here were decided by writers, not me

    if anonscore >= 3 and fangscore >= 4:
    #>>golden
       St "Upright Strength."
       St "OH! {w=.3} I don’t think you need to worry about what’s to come, Anon."
    elif anonscore >= 3 and fangscore <= 3:
    #>>tradwife
       St "Inverted Hierophant."
       St "You need to be wary of your words and actions, Anon."
    elif anonscore <= 3 and fangscore >= 3:
    #>>doomer
       St "Inverted Hermit."
       St "Anon, if you ever feel lonely you can come to me."
    elif anonscore <= 2 and fangscore <= 2:
    #>>shooter
       St "Oh my, {w=.3} inverted Empress."
       St "You need to be wary about future negligence, Anon."
    else:
    #>>ERROR HANDLING
       St "uh oh..."
       A "What?"
       St "Some dipshit developer made broken code and this is the error handling message and you should report this as a bug"
       A "What?"
       St "Basically the if/else statement that handles this shit has failed at catching the score, and I cannot give you a tarot reading..."

    A "The fuck does that mean?"

    St "Uh… {w=0.4} er… {w=0.2} {cps=*1.4}Gottago,naturecalls,seeyouattheshow{/cps}!"
    window hide
    window auto
    play sound 'audio/effects/whoosh.ogg'
    hide stella with easeoutleft


    "She flees in denim pissing fear."
    stop music fadeout 1.0
    "...Well then…"

    "What was I doing?"
    play music 'audio/OST/Those Other Two Weirdos.ogg' fadein 1.0

    "Oh yeah."

    "I step up to the stage to see the band’s point of view."
    window hide
    window auto
    #show anon neutral flip with move:
    #  ease_cubic 1.0 xalign 0.5
    #show anon neutral flip:
    #  ease_cubic 0.5 rotate -90 yalign -0.5
    #pause 0.5
    #anon fall

    show anon neutral flip with move:
        easeout_quart 1.0 xalign 0.65
    pause 0.1
    show dimmer_darker behind anon with Dissolve(.25)

    #play sound 'audio/effects/anonTheaterFall.ogg'
    #scene moebackrooms at vpunch
    #pause 0.2
    #scene moebackrooms
    #"*FWAP*"

    "And then promptly trip."
    window hide
    window auto

    hide dimmer_darker
    play sound 'audio/effects/whoosh.ogg'
    show anon shocked at rleft with Dissolve(.1):
        yanchor 0.2
        easeout_quad .5 rotate -90 yalign -0.01
    pause .15
    hide anon with Dissolve(.25)
    play sound 'audio/effects/anonTheaterFall.ogg'
    scene moebackrooms at vpunch
    pause .25

    A "Argh!"

    #hide anon

    "What the fuck was that?!"

    "There’s a loose cord over my foot."

    "That’s…"

    "Probably not good for the show."

    #scene moebackrooms
    #show anon neutral at acenter with moveinbottom
    show anon neutral flip:
        alpha 0
        yalign -0.2 xalign 0.5
    show anon:
        easein 0.5 yalign 0.1 alpha 1

    "I stand up and wipe the dust from my pants."

    "Trish is the organizer…"

    "Right now she’s giving Reed a lecture on why it’s probably a bad idea to put carfentanyl in the smoke machine."

    show anon neutral with Dissolve(.25)

    A "Hey, Trish!"

    #show anon at aleft with move

    "Trish looks over her shoulder and Reed’s face lights up."

    A "Can you come here a second?"

    "Trish sighs, points between her eyes and Reed’s, and stomps over to the stage."

    window hide
    window auto

    show anon neutral at aleft with easeinright
    show trish neutral flip at tright with easeinright

    T "Whaddayawant, skinnie?"

    A "I just tripped on one of the wires up here."

    show trish unimpressed flip with dissolve

    T "Sucks to be you."

    "Bitch."

    A "Should I plug them all into a surge protector so you guys don’t fall during the concert?"

    show trish annoyed flip with dissolve

    T "What?"

    T "No, of course not."

    T "We won’t trip, I have that on good authority."

    A "Whose?"

    show trish unimpressed flip with dissolve

    T "...Reed’s."

    A "..."
    pause .5
    T "..."

    A "And you trust his word on something like this?"

    show trish neutral flip with dissolve

    T "Sure."

    T "He’s the expert on this stuff and all."

    "Before I can object, Trish turns away and runs after Reed who is huddled over the smoke machine, pungent fumes wafting from it’s exposed innards."

    window hide
    window auto

    show trish neutral with Dissolve(.25)
    pause .1
    hide trish with easeoutright

    "Well, seems like he’s got that handled."

    "Trish seemed pretty confident that Reed knows what he’s doing with the stage."

    "But Reed obviously doesn’t understand cable management."
    window hide
    window auto
    pause .5

    define LeftStage = False
    menu:
        "Leave the stage as-is":
            jump LeaveStageAsIs
        "Fix the cables":
            jump FixCables


    label LeaveStageAsIs:
    $ anonscore += 1
    pause .5
    "Reed may not understand cable management,{w=.4} but then again neither did I."

    "Probably better to let sleeping fossils lie."

    $ LeftStage = True

    jump PostCableConundrum

    label FixCables:

    "It could be a serious hazard if I leave them like this."

    "Like a fire hazard or something. I think."

    "I’ll just put them all on one of Moe’s surge protectors."

    "{cps=*0.5}Aaaaaand{/cps} done."

    label PostCableConundrum:

    "Now that that’s taken care of, I glance at the pizza-themed clock on the wall."

    "Thirty minutes until the show starts."

    "The band is doing one last sound test, Reed’s bass drum bearing another new logo for VVURM DRAMA that doesn’t look half bad."

    "Trish has a wicked grin on her face and I can practically see the dollar signs in her eyes."

    stop music fadeout 3
    scene moes pizza
    show fang hiding at sright
    with fade
    "And Fang…"

    "Fang looks anxious, hands wringing the strap of her hollowbody electric guitar."

    "I consider what I’m about to do extremely stupid but…"

    play music 'audio/ost/Beach Chill Out.ogg' fadein 1
    A "Hey."

    show anon neutral at aleft with easeinleft

    show fang surprised flip at scenter with dissolve

    "She jumps a little as I step back on stage. Her knuckles are bright white as they strangle the leather strap."

    F "...Hey."

    Moe "{alpha=0.5}{i}The secret is support!{/i}{/alpha}"

    "I offer her my most supportive smile."

    A "You’ve got this, Fang."

    show fang sad flip with dissolve

    F "Don’t feel like I do, though."

    A "You do. You’ve been practicing all month for this."

    A "And you’ve improved immensely since your last gig."

    A "I have complete faith in your ability to play guitar."

    A "Don’t worry so much."

    A "Just don't fret about it, you’ll be fine."

    show fang happy flip with dissolve

    "Trish rolls her eyes, Reed’s vacant stare has a bit of approval."

    show fang neutral flip at sright
    show trish neutral flip at tcenter
    with dissolve
    T "At least it wasn't a dinosaur pun this time."

    A "I'm not that unfunny!"

    T "You are."

    A "Fuck you, I’m hilarious."

    T "No one thinks that, loser."

    A "Don’t you have something to be triggered about?"

    show fang surprised flip
    show trish fury flip:
      xalign 0.5 yalign 10.0
    with dissolve

    T "YOU CAN’T USE THAT WORD, THAT’S {b}OUR{/b} WORD!"

    show trish angry flip at tcenter
    show fang neutral flip
    with dissolve

    A "Just did, wanna see me do it again?"

    F "Ladies, Ladies, please."

    F "Shut the fuck up."
    stop music fadeout 1.0
    F "We’ve got sweet music to play."

    scene moes pizza
    show dimmer_darker
    with fade

    if LeftStage:
      play ambient 'audio/effects/dinomoesLoop.ogg' fadein 1.0
      show trish smile at tleft
      show fang happy at scenter
      show reed neutral flip at rright:
         xalign 1.3
      with dissolve
      "Showtime!"

      F "All right! Next up we got 'The!'"

      "WHAT."

      "They go right into their next song with gusto."
      play music 'audio/OST/The.ogg' fadein 2.0
      stop ambient fadeout 2
      scene black with Dissolve(1)
      "..."

      "An hour later and the band is wrapping up their last song for the night."
      scene moes pizza
      show dimmer_darker
      show trish neutral at tleft
      show fang neutral at scenter
      show reed neutral flip at rright:
         xalign 1.3
      with dissolve
      "I take my eyes off the stage to get a read on the crowd."

      "Easily a good hundred people showed up to see VVURM DRAMA, better than any of us expected."

      "The look on Fang’s face when everyone began filtering into the restaurant was priceless."

      play music1 'audio/OST/The Hitler Song With The Really Long Name.ogg' fadein 4.0
      stop music fadeout 4
      "They were on the last song of the night, the bizarrely long name of which I missed."

      F "I JUST GOTTA ASK:"
      F "WHY IS HITLER,"
      F "RIDING MY BIKE,"
      F "PRETENDING TO BE,"
      F "A MONKEY!"

      "Oh right… Reed definitely wrote this one."

      "The band really has improved, as opposed to booing and pointing at the audience is listening intently."

      F "AT THREEEEEEE AAAAAAAA MMMMM-"
      F "IN THE MORNIIIIIING!"
      F "ON A FUCKIN’ TUESDAAAAY!"

      "After the song ends, VVURM DRAMA hangs onto the pose of their final note."

      stop music1 fadeout 3.0

      "It’s silent."

      "I applaud the band, eventually some other patrons join in."

      window hide
      window auto
      play ambient 'audio/effects/crowdClapLoop.ogg' fadein 2 volume 0.7
      pause 1.5
      play ambient1 'audio/effects/crowdCheerLoop.ogg' fadein 3
      stop ambient fadeout 3

      "The applause turns to cheers, and the cheers turn to uproar."

      "The crowd was cheering."

      "{i}Actually{/i} cheering this time."

      window hide
      window auto

      play music 'audio/OST/punk_revamp.ogg' fadein 1.0 volume 0.8
      $ renpy.music.set_volume(0.7, 1, 'ambient1')
      show trish happy at tleft
      show reed happy at rright:
         xalign 1.1
      show fang happy at scenter
      with dissolve
      pause 0.5
      show reed happy flip:
         xalign 1.35
      show trish happy flip
      with dissolve
      show fang happy flip with dissolve
      pause 0.5
      show trish happy
      show reed happy:
         xalign 1.1
      show fang happy
      with dissolve
      "The bandmates’ faces light up, and they all glance at each other."

      "The hard work has taken its toll on the three, giving them varying degrees of perspiration."

      "The sweat is trickling down Fang’s forehead, Trish has gone from an afro to dreadlocks, and Reed is providing the restaurant with a nice ocean scent."

      "Fang finishes with a furious flurry of strumming on her fretboard."
      show fang very happy with dissolve
      F "Woooooooo! THANK YOU LITTLE TROODON!"

      "The crowd’s approval is obvious, even in the makeshift mosh pit where I see Stella getting fake curb-stomped."

      "At least I think it’s fake."

      "Rosa is on the other side of the room, too entranced by the music to care."

      "Eh, I don’t see any blood so she’s good."

      window hide
      window auto
      $ renpy.music.set_volume(1, 1, 'ambient1')
      stop ambient1 fadeout 1
      stop music fadeout 1

      scene moebackrooms
      play music 'audio/ost/Bayside Bumming it.ogg' fadein 1
      show anon neutral flip at acenter
      with fade
      show fang very happy at rleft with easeinleft:
         yalign 0.2

      F "ANON!"

      "Before I could react I was swept up in a blur of feathers."

      hide anon
      hide fang
      show fang hug at acenter:
         yalign 0.1
      with dissolve

      "Fang wrapped her arms and wings around me and kept rocking back and forth."

      show fang:
        ease 0.75 xalign 0.5
        ease 0.75 xalign 0.45
        repeat

      F "OHMYGOD OHMYGOD WE DID IT WE DID IT!"

      F "THEY ACTUALLY LOVE VVURM DRAMA!"

      "I tune out the alarms screaming in my head and hug her back."

      hide fang hug with dissolve
      show fanganonhug with dissolve:
         yalign 0.0

      "Her wings are just as soft and huggable as they look."

      "Fang’s beak settles against my cheek, the warm scales sliding smoothly up and down against it."

      "This is nice."

      "I become aware of my hands, planted firmly on the small of Fang’s back and pressing her closer to me."

      "Beneath my splayed palms is soft, warm and drenched in sweat. I find that I don’t really mind the slickness."

      T "Fang?"

      "I feel like I could stay like this forever."

      T "Hellooo, Fang?"

      "Fang suddenly flinches, and I get a split second view of a purple hand on her shoulder."

      "Her face is beet red and the warmth in my own cheeks tells me I don’t look far behind."

      "Trish looks like she’s sucked on a lemon with how twisted her face is."

      "The tiny triceratops pulls Fang out of my hands, and I can picture my fist twisting that horn right off her face."
      hide fanganonhug with dissolve

      show fang neutral flip at scenter
      show anon neutral flip at sright
      show trish neutral at tleft
      with dissolve
      T "Hmmm... "

      A "Great show, right?"

      T "I guess. For our first show, anyway."

      show fang happy flip with dissolve

      F "What? {w=0.2} It was great though! Everyone was cheering!"

      show trish indignant with dissolve

      T "But it was a small crowd."

      A "Was it? The place was packed."

      show trish explanatory with dissolve

      T "Small venue. We gotta think bigger now."

      A "Why bigger?"

      show trish happy with dissolve

      T "Because I still have stock!"

      "She motions to the bar, where there is still some hung up shirts with the new mediocre logo lazily spray painted on."

      A "Have you sold much?"

      T "Three buttons, four stickers, {w=.2} and an Apron!"
      stop music fadeout 2
      pause .5

      A "An apron?"

      Moe "AY, KIDS!"
      play music 'audio/ost/Venetian Values.ogg' fadein 1
      window hide
      window auto

      #moe now has vvurm drama apron
      show moealt with easeinright:
         xalign 1.8 yalign 0.0
      Moe "LOOKIT DIS ‘ERE AH-PRON YA LIL TRIGGA FRIEN SOL’ ME!"

      show trish unimpressed with dissolve

      "Trish looks split on whether to be mad about the trigga comment or happy about the successful sale."

      unknown "Hey! Someone took ma apron!"

      Moe "GIT BACK TA WORK JERRY YER ON DA CLOCK!"

      show fang happy flip with dissolve

      F "It uh… looks nice, Uncle Moe."

      Moe "Anyways, youse all gonna be helpin’ wit da clean up, right?"

      "I look at the absolute mess around us."

      "Fuck."
      stop music fadeout 1.0

    else:
      play ambient 'audio/effects/dinomoesLoop.ogg' fadein 1.0
      show trish smile at sleft
      show fang happy at scenter
      show reed neutral flip at rright:
         xalign 1.3
      with dissolve
      "Showtime!"

      "I take my eyes off the stage to get a read on the crowd."

      "Easily a good hundred people showed up to see VVURM DRAMA, better than any of us expected."

      "The look on Fang’s face when everyone began filtering into the restaurant was priceless."

      stop ambient fadeout 1
      play music 'audio/OST/The Hitler Song With The Really Long Name.ogg' fadein 1.0
      "They were on the last song of the night, the bizarrely long name of which I missed."

      F "I JUST GOTTA ASK:"
      F "WHY IS HITLER,"
      F "RIDING MY BIKE,"
      F "PRETENDING TO BE,"
      F "A MONKEY!"

      "Oh right… Reed definitely wrote this one."

      "The band really has improved, as opposed to booing and pointing at the audience is listening intently."

      "And nobody has tripped so far."

      F "AT THREEEEEEE AAAAAAAA MMMMM-"
      F "IN THE MORNIIIIIING!"
      F "ON A-"

      stop music
      window hide Dissolve(0.001)
      window auto
      show black
      play sound 'audio/effects/carKick1.ogg' #Temporary
      pause 1
      "As if right on cue, half of the lights on stage cut out."

      "Trish strummed silently before giving a confused glance at the speakers."

      F "T-tuesday?"

      "Fang fell out of tempo with Reed’s drums, stumbling over the end of the song."
      "It’s silent."

      "I began to clap, followed by several other patrons."

      window hide
      window auto
      play ambient 'audio/effects/crowdClapLoop.ogg' fadein 2 volume 0.7
      pause 1.5

      "Including Stella who looked seconds away from being curb-stomped."

      "Rosa is on the other side of the room, too entranced by the music to care."

      stop ambient fadeout 1
      play music 'audio/OST/Summertime Synth.ogg' fadein 1.0
      scene moebackrooms
      show anon neutral flip at aright
      with fade
      "My eyes scan the room before noticing Trish, the sheer vehement rage radiating from her visibly distorting the air around her."

      "Fuck."


      "My jaw aches as I picture myself in Stella’s place, courtesy of one pissed off womanlet."

      "Before I have the chance to escape I hear my one saving grace."
      window hide
      window auto

      show fang very happy with easeinleft:
          xalign 0.6 yalign 0.1

      F "ANON!"

      "Fang reaches me before Trish leaves the stage, extending her hand for a high-five."
      show fang happy with dissolve

      F "We did it!"
      window hide
      window auto

      show trish unimpressed at tleft with easeinleft
      T "No thanks to that asshole!"

      "Oh no."

      show fang neutral flip behind anon with dissolve

      F "What’s wrong?"

      show trish angry with dissolve

      T "Skinnie sabotaged the show!"

      T "I told him not to touch the wires and look what happened!"

      A "I was only trying to help."

      show trish annoyed with dissolve

      "Trish holds up her hand to my face, waving the other around in grand gestures."

      show trish indignant with dissolve

      T "You ruined the big finale! We missed our chance to make it big!"

      T "Why is it that only my bass cut out anyways?!"

      T "Are you actively trying to ruin us?!"

      T "I told you Reed knew what he was doing!"

      T "Do you not trust him and I?"

      show fang sad flip
      show trish fury point:
          yalign 10.0
      with dissolve

      "Tears trickle down her sweat-glazed face."

      T "Is Fang really the only one here you care about?!"

      T "We exist too, you know!"
      show trish sad at tleft with dissolve
      show anon sad flip with dissolve

      "This hypocritical bitch!"

      "The sharp words cut right through me."

      F "Jeez, Trish. The show went great! Our first good concert!"

      show fang neutral flip
      with dissolve
      F "The crowd actually clapped this time!"

      T "No thanks to him."

      A "I didn’t do it on purpose."

      "Even though you deserved it."

      "Before she could interrogate me further, Fang grabbed Trish on the arm."

      show fang happy flip with dissolve
      F "Trish! Didn’t you say you wanted to set up our merch!"
      show trish unimpressed with dissolve
      show anon neutral flip with dissolve

      "Trish winces, then gives a begrudging sigh, lowering her accusatory finger."

      show trish unimpressed with dissolve

      T "Ugh, you aren’t worth it."
      window hide
      window auto

      hide trish with dissolve
      stop music fadeout 1.0
      show fang neutral flip with dissolve
      "Trish storms off leaving Fang and I alone."

      "And Reed who was listening the entire time."
      window hide
      window auto

      show reed neutral at rleft with easeinleft
      pause 1
      show reed considering with dissolve
      pause 1
      show reed neutral with dissolve
      pause 1
      show reed explanatory with dissolve
      Re "Anon, dude… you really should trust others, y’know?"

      Re "It’s like they say… trust is the building block of our economy, or something."

      "What."

      Re "There are two kinds of people in this world, bro... people who believe and people who trust."

      Re "And you believed in something false, your impulsiveness."
      show reed shocked
      show fang surprised
      show anon neutral
      with dissolve
      "Before I can begin to comprehend Reed’s capitalist sermon, my ears are assaulted by very Italian yelling."

      Moe "AY, KIDS!"
      play music 'audio/ost/Venetian Values.ogg' fadein 1
      window hide
      window auto

      #moe now has vvurm drama apron
      show moealt with easeinright:
          xalign 1.8 yalign 0.0

      Moe "LOOKIT DIS ‘ERE AH-PRON YA LIL TRIGGA FRIEN SOL’ ME!"

      "Reed looks almost jealous of Moe’s new garb."

      show reed neutral

      Re "Nice threads, compadre."

      show fang happy with dissolve

      unknown "Hey! Someone took ma apron!"

      Moe "GIT BACK TA WORK JERRY YER ON DA CLOCK!"

      F "It uh… looks nice, Uncle Moe."

      Moe "Anyways, youse all gonna be helpin’ wit da clean up, right?"

      "I look at the absolute mess around us."

      "Fuck."
      stop music fadeout 1.0

    scene black with fade
    scene moebackrooms
    show anon neutral at acenter
    with fade
    play music 'audio/OST/west_coast_kicking.ogg' fadein 1.0
    "An hour later and I’m stuck mopping up where the mosh pit once stood."

    "As my mop head gains a tinge of red I pray to god this isn’t from Stella."

    "Rosa wanted to stay and help clean buuut…"

    Ro "{i}I am so sorry Stella! Come, I shall nurse you back at my home!{/i}"

    "I’d feel more sorry for Stella but Rosa looked capable of helping her."

    "My god that’s a lot of… Marinara… Yeah…"

    "Fang and Trish are trying to divide and carry out the stage."

    "...The mop really isn’t getting much from the floor."

    "Am I supposed to have a bucket or something?"
    window hide
    window auto

    show reed neutral flip at rright with easeinright:
      xalign 1.3

    Re "Yooo, {w=.3} Anon!"

    "Reed crosses right through the puddles, tracking grimy footprints without a care."

    Re "Hey man… what’d you think of the lyrics?"

    A "What were you on when you wrote that?"

    "Reed rubs his forehead, struggling to remember more than ten minutes ago."

    Re "I dunno man… the floor maybe? But I also distinctly remember floating…"

    Re "Y’know, dude, we’ve been doing this since junior year, right?"

    Re "And this is the first show that anyone’s actually liked."

    Re "Wild."

    A "You’ve only been playing together for a year?"

    Re "You know it man, crazy how time flies."
    pause .3
    Re "Man, back then Trish had these crazy long horns and glasses."

    "Now there’s a thought. How would Trish even look with glasses?"

    "Actually, how would glasses even work on any triceratops?"

    Re "Fang wasn’t Fang."

    A "She- what?"

    Re "Er… {w=0.3}Probably shouldn’t have mentioned that…"

    A "Fang wasn’t herself?"

    Re "Honestly… That’s probably something to be left for Fang and Fang alone to talk about… Sorry."

    A "Er… ri{cps=*0.65}iiiii{/cps}ght."

    Re "Only thing that stayed the same was like... me and my carfe, bro."

    "How long has he been on that stuff?"

    Re "It was almost like a totally different time, man."
    window hide
    window auto

    show anon neutral at aleft with easeinright
    show reed neutral flip with easeinright:
         xalign 1.1
    show trish neutral flip at tright with easeinright

    "Before I even got a moment to picture what it might have been like not even a year ago, Trish appears behind Reed."

    "She looks like she’s about to snap both our necks."

    T "Hey, Reed, what are you two talking about?"

    Re "Just talking about some memories of the band, Trish."

    T "You didn’t tell him anything about me, did you?"

    A "Glasses."

    T "Reed, you absolute ass."

    "Reed just shrugs."
    stop music fadeout 1.0
    "By this point the restaurant has been mostly cleaned up with only a few tables left to put back."

    play music 'audio/OST/you need gopher chucks.ogg' fadein 1.0
    T "So Anon, we showed you ours, now it’s your turn to show us yours."

    A "What, out here in public? Didn’t peg you for the kinky type." #lol sex

    "Trish inhales sharply, visibly trying to master herself."

    T "I meant with your old school."

    A "That’s on a need to know basis, and you don’t need to know."
    window hide
    window auto

    show anon neutral:
        ease_cubic 1 xalign 0.2
    show reed neutral flip:
        ease_cubic 1 xalign 1.2
    show trish neutral flip:
        ease_cubic 1 xalign 1.2

    pause .5
    show fang neutral with easeinleft:
        xalign -0.4
    F "Come on Anon, don’t you have any good memories from your old school?"

    "Oh god no."

    A "I’d really rather not talk about it."

    F "Why not? You’ve told me about your parents."

    "That seems to catch Trish’s attention."

    "Shit. And that look of expectancy from Fang too?"

    "I guess it can’t hurt."

    A "Well… I did try to get into music at one point."

    F "With how much you need my help in music class?"

    A "I didn’t say I was good at it. I was just clicking buttons and seeing what stuck."

    A "And spoiler alert, {w=0.3} nothing did."

    "That got a giggle out of Fang and a look from Trish."

    T "By the way Anon, I saw you talking to that Stella girl before the concert. You have something going on there?"

    "I feel a pit in my stomach as a look of betrayal crosses Fang’s face."

    "Right into Trish’s trap, {w=0.2} hook, {w=0.2}line, {w=0.2}sinker and rod."
    window hide
    window auto
    pause .5

    menu:
      "Nyet.":
         A "I do NOT have a thing for Incontineisha."
      "Nein.":
         A "I do NOT have a thing for Incontineisha."
      "Non.":
         A "I do NOT have a thing for Incontineisha."
      "Nope.":
         A "I do NOT have a thing for Incontineisha."
      "Inai.":
         A "I do NOT have a thing for Incontineisha."
      "Mei yo.":
         A "I do NOT have a thing for Incontineisha."
      "None of that.":
         A "I do NOT have a thing for Incontineisha."
      "No.":
         A "I do NOT have a thing for Incontineisha."

    Re "Who?... Thought like, we were talkin’ bout whatsherface."

    T "The one with the Dino Duel cards."

    Re "...I thought those were Pocket Raptor cards."

    F "Weren’t they handegg cards?"

    A "Uh… moving on..."

    T "Anyone back home you had your eye on then?"

    A "Nobody at Rock Bottom was worth the time."

    "Fang’s face softens, almost in a silent sigh of relief."

    "Is there hope for me yet?"

    T "Rock Bottom, huh? I don’t think you’ve ever told us where you’re from before."

    stop music fadeout 1
    "..."

    play music 'audio/OST/you can_t sage here.ogg' fadein 1.0
    "SHIT."
    pause 0.5
    A "O-oh, I haven’t? Huh."

    F "Who really cares where you went to last?"

    Re "Yeah, man, it’s just a school."

    F "Was it in the sticks?"

    A "Not exactly, it was certainly lower class though."

    A "I used to buy bulk soda and sell them to the stupid kids for lunch money."

    Re "Yooo, my man!"

    "Reed gives me a fist bump."

    A "I’d usually just go places on a crappy dirt bike, leaving donuts in parking lots when I was sure nobody was looking."

    F "Sounds like you were pretty cool at your last school."

    "HA."

    A "I dunno about that…"

    Re "Sure, man… I don’t get why you left in the first place if you had it so good."

    "Oh no."

    A "Oh, uh, actually…"

    "THINK OF SOMETHING THINK OF SOMETHING THINK OF SOMETHING!"

    A "I had to leave because of, uh…"

    "DON’T SAY SOMETHING STUPID YOU ONLY GET ONE SHOT AT THIS."

    A "Family issues."
    stop sound fadeout 0.5
    "Nailed it."

    Re "Bummer man… glad you’re here instead."

    A "Yeah, yeah, thanks man."

    T "Sounds personal, guess we shouldn’t pry."

    stop music fadeout 1.0
    T "We’re all friends here, after all."

    "Guess we are all friends at this point."
    pause .5
    "To varying degrees."

    "I let a content smile creep onto my face." #WHAT THE FUCK ANON CANT SMILE WHAT THEW FUCK WHAT THE FUCK

    window hide
    window auto
    play music 'audio/OST/Venetian Values.ogg' fadein 1.0
    show moealt at sright with easeinright

    Moe "AY YOU STUPID KIDS!"

    "The tyrannosaur stomps over to us from the kitchen."

    Moe "Great job again on da show, punks."

    Moe "I knew my lil Lucy could pull dis shindig off."

    "He clamps one of his tiny hands down on Fang’s shoulder as she reflexively tries to hide her face with a wing."

    Moe "Alas, I’m expecting a late night visita’, so I needs you punks to piss off."

    Moe "Come on by for a slice sometime, yeah?"

    A "Thanks, Moe."

    Re "Yeah man… thanks a bunch…"

    Moe "Now scram youse kids. I’ve got a different kinds a clean-up ta deal wit’."
    stop music fadeout 1.0
    scene black with fade
    "Aaaaaaand repressing that."

    "..."
    window hide
    window auto

    return