SnootGame/game/script/11D.anon-gets-fangs'-pronouns-right-and-she-teases-him-while-carrying-herself-with-more-confidence.rpy

label chapter_11D:
    #Announcing a Show | Golden
    #le inconsistant indention has arrived
    #le wrong move indent slut

    show fang:
        easein_cubic 1 xalign 0.5
    show fang happy flip with dissolve

    "I turn back to Fang and her mischievous grin."
    pause .5

    A "What?"

    "Her grin only grows."
    pause .5

    A "What?! What’s with the look?"

    "She shakes her head and covers her mouth."

    A "Uh{cps=*.1}...{/cps} did I say something funny?"

    F "Anon you ignorant slut."

    F "Notice something about me? Anything at all?"
    pause .5

    A "{cps=*.1}...{/cps}Why do you have feathers on your elbows anyway?"

    F "Gawd! No! I’m not actually enbie, Anon."
    pause .5

    "What? Oh! 'She'."

    A "Oh{cps=*.1}...{/cps} still, why do you have feathers on your elbows?"

    "Fang rolls her eyes and digs her feathered elbow into my side."
    show fang:
        easeout_cubic 0.25 xalign 0.35
        ease_cubic 0.5 xalign 0.4
    show fang happy with Dissolve(.15)
    show anon:
        easein_cubic 1 xalign 0.0
    pause .5

    A "Alright alright, I get it."

    show anon:
        ease_cubic 1 xalign 0.05
    A "Just joking around."

    F "Shame your jokes suck."

    "We chuckle together."
    pause .5

    A "So, like, I can say you’re my girlfriend now?"

    "Fang blushes a little."

    F "You always could. Dummy."

    "The blush becomes contagious and I find myself looking back at the worksheet."

    "{cps=*.1}...{/cps}Girlfriend{cps=*.1}...{/cps}"

    "Suddenly I’m feeling squeamish all over again."
    pause .5

    "I mean, we went on dates before, but she’s never straight up said she’s my girlfriend{cps=*.1}...{/cps}"

    "Now I’m on the spot."
    pause .5

    "It only makes sense that I ask her to prom, right?"

    "Why am I getting so worked up again all of a sudden?"

    "This is ridiculous, I’m just going to ask."

    A "Hey, Fang, you-"

    show fang happy flip with dissolve
    F "We’re going to prom together, right?"
    pause .5

    A "O-oh, yeah. Totally."

    A "I was gonna ask if you wanted to go at all."

    F "Of course I do, but do you want to go?"

    A "I mean, only with you?"

    F "Yes or no, dork."
    pause .5

    A "Yes."

    F "That wasn’t so hard, was it?"

    A "Like plucking feathers."

    show fang:
        easeout_cubic 0.25 xalign 0.35
        ease_cubic 0.5 xalign 0.4
    pause .15
    show anon:
        easein_cubic 1 xalign 0.0
    pause .5

    "She playfully elbows me again."
    pause .5

    show anon:
        ease_cubic 1 xalign 0.05
    "I think I get the feathers on the elbow thing now, because those things fucking dig in. Ow."

    F "Do you even have something to wear?"

    A "I was going to ask my dad for his old clothes."

    F "You sure? I could ask Naser for his old stuff."

    A "Tail and wings."

    F "Right, right."

    A "What about you?"

    A "You actually gonna wear a dress?"

    show fang neutral with dissolve
    F "I’ve got this sick looking dress shirt{cps=*.1}...{/cps}"
    pause .5

    show fang happy with Dissolve(.25)
    F "Naaaah, shirts suck."

    A "Wings again?"

    F "Wings again. At least I can wear a backless dress."

    "I cup my chin and try to picture the dress."
    pause .5

    "The heat creeping up my face tells Fang exactly what I’m thinking."

    show anon grin with dissolve
    "I grin and nod approvingly."

    show fang:
        easeout_cubic 0.25 xalign 0.35
        ease_cubic 0.5 xalign 0.4
    pause .15
    show anon:
        easein_cubic 1 xalign 0.0
    pause .5
    "And earn a third elbow to my side."

    show anon:
        ease_cubic 1 xalign 0.05
    show anon neutral with dissolve
    A "Wait, hold on."

    A "Do you still go by Fang, at least?"

    F "Why wouldn’t I?"

    A "Cool, just checking."

    F "Taking it one step at a time, you know?"

    show fang considering with dissolve
    F "There’s only about ten minutes left of class, are we gonna have enough time to finish the assignment?"

    A "Shit, yeah. Forgot."

    "I flip over the page to reveal the entire second half of the assignment."

    A "It’s gonna be close though."

    show fang:
        easein_back 1 xalign 0.35
    show fang neutral with dissolve

    "Fang scoots her chair closer to me."

    F "No time to waste then, yeah?"

    stop music fadeout 4
    pause .5

    "Splitting the questions between us, Fang and I are able to finish the assignment seconds before the bell."

    "Somehow."
    window hide
    window auto
    pause .5

    play music "audio/OST/to_swagger.ogg" fadein 2
    scene hallway
    with Fade(1, 0, 1)

    show fang happy:
        xalign -1.2
        yalign 0.0
        ease_cubic 3.0 xalign 1.0
    show anon neutral:
        xalign -1.4
        yalign 0.1
        ease_cubic 3.0 xalign 0.4
    with dissolve
#with easeinleft # Fade(1, 0, 1)

    "We walk through the hall together, at least until we have to split to our separate classes."

    show fang:
        xalign 1.0
    show anon:
        xalign 0.4
    show anon shrug with Dissolve(.25)
    A "Hey wait, you did the word search bit this time, right?"

    A "I thought you said you were terrible at those?"
    show anon neutral with dissolve

    F "And you’ve believed me up to this point."
    pause .5

    A "I feel used."

    F "That’s because I used you."
    pause .5

    A "I’ll get you fo-"

    Sp "Ah, Fang! There you are, a moment please."

    window hide
    window auto

    show anon:
        easein_cubic 1 xalign 0.55
    show fang:
        easein 1 xalign 1.2
    show spears:
        yalign 0.0 xalign -0.8
        xalign -0.8
        easein 1.5 xalign 0.0
    with None
    pause 0.0001
    show anon neutral flip behind fang
    show fang surprised flip
    show spears neutral
    with dissolve
    pause 1

    "We turn to see Principal Spears trailing behind us."
    pause .5

    F "Yes?"

    Sp "Fang, I was planning on asking you during your next class, but since I found you here{cps=*.1}...{/cps}"

    show fang neutral flip with dissolve

    Sp "I’m embarrassed to say we’re missing one event slot during prom. Scheduling error."

    Sp "And your teacher, Mr Jingo, recommended you for your musical talents."
    pause .5

    Sp "I’m not asking you to make your decision right now, but if you’d consider helping out by performing a musical number or two that would help monumentally."
    pause .5

    show fang happy flip with dissolve
    F "Oh!"

    A "Fang’s going to play for the school?"

    Sp "If Fang agrees to."

    F "Well, uh{cps=*.1}...{/cps} Sure!"

    F "Yeah, I’d love to do some songs for prom."

    show spears happy with Dissolve(.25)
    Sp "Fantastic news, Fang. When you can, please swing by the office."

    F "Thank you, Principal Spears. I’ll come after school today."

    "Spears nods and heads off."
    window hide
    window auto
    pause .5

    show spears:
        easeout_cubic 1.2 xalign -0.9
    show spears happy flip with dissolve
    pause .2
    hide spears with dissolve
    pause .5

    show fang considering flip with Dissolve(.25)
    F "Shit, now I really need to get a good dress."

    show anon:
        easein_cubic 1 xalign 0.45
    show anon neutral with dissolve
    A "I thought you had one?"

    show fang unimpressed flip with Dissolve(.25)
    F "A party dress isn’t a performance dress!"

    F "It’s like- you know what I mean."

    A "I guess?"
    pause .5

    A "You don’t seem as excited as last time you got somewhere to play."

    show fang sad flip with dissolve
    F "I know, I mean... last time I had a whole band to play with."
    pause .5

    A "You sure you’ll be alright playing solo?"

    show fang considering flip with dissolve
    F "Probably."

    F "I’ll also need to practice a lot more{cps=*.1}...{/cps}"
    pause .5

    show fang neutral flip with dissolve
    F "You’ll help me, right?"

    A "Of course."

    A "As long as you don’t need me up on stage with you."

    show fang happy flip with Dissolve(.25)
    F "I’m trying to keep the crowd from throwing things this time around, actually."
    pause .5

    A "Bite me."

    F "Speaking of. I’ll see you at lunch, right?"

    A "Yeah, of course."
    window hide
    window auto
    pause .5

    show fang behind anon:
        easein_back 1 yalign 0.14 xalign 0.8
        easein_cubic 1 yalign 0.0 xalign 1.2
    pause .5

    "Fang pecks me on the cheek and starts down the hall to her next class."
    window hide
    window auto

    show fang:
        yalign 0.0
        xalign 1.2
        easeout_cubic 1.4 xalign 2.4
    show fang happy with dissolve
    pause .4
    hide fang with dissolve
    pause .25

    show anon grin with dissolve
    "I feel my lips spread into a grin. It’s kind of weird to think of it, but I’m actually excited for prom."
    window hide
    window auto
    pause .5

    stop music fadeout 4
    scene black with Dissolve(1)
    pause .5

    "Man, I hope dad’s suit has actually been to the cleaner, I don’t wanna disappoint."

    "{cps=*.1}...{/cps}"
    window hide
    window auto
    pause .5

    return